push sheeet

nixos/tests/php/default.nix

@@ -0,0 +1,28 @@
+{
+  runTest,
+  php,
+}:
+
+let
+  php' = php.buildEnv {
+    extensions = { enabled, all }: with all; enabled ++ [ apcu ];
+  };
+in
+{
+  fpm = runTest {
+    imports = [ ./fpm.nix ];
+    _module.args.php = php';
+  };
+  fpm-modular = runTest {
+    imports = [ ./fpm-modular.nix ];
+    _module.args.php = php';
+  };
+  httpd = runTest {
+    imports = [ ./httpd.nix ];
+    _module.args.php = php';
+  };
+  pcre = runTest {
+    imports = [ ./pcre.nix ];
+    _module.args.php = php';
+  };
+}

nixos/tests/php/fpm-modular.nix

@@ -0,0 +1,73 @@
+# Run with:
+#   nix-build -A nixosTests.php.fpm-modular
+{ lib, php, ... }:
+{
+  name = "php-${php.version}-fpm-modular-nginx-test";
+  meta.maintainers = with lib.maintainers; [
+    aanderse
+  ];
+
+  nodes.machine =
+    { config, pkgs, ... }:
+    {
+      environment.systemPackages = [ php ];
+
+      services.nginx = {
+        enable = true;
+
+        virtualHosts."phpfpm" =
+          let
+            testdir = pkgs.writeTextDir "web/index.php" "<?php phpinfo();";
+          in
+          {
+            root = "${testdir}/web";
+            locations."~ \\.php$".extraConfig = ''
+              fastcgi_pass unix:${config.system.services.php-fpm.php-fpm.settings.foobar.listen};
+              fastcgi_index index.php;
+              include ${config.services.nginx.package}/conf/fastcgi_params;
+              include ${pkgs.nginx}/conf/fastcgi.conf;
+            '';
+            locations."/" = {
+              tryFiles = "$uri $uri/ index.php";
+              index = "index.php index.html index.htm";
+            };
+          };
+      };
+
+      system.services.php-fpm = {
+        imports = [ php.services.default ];
+        php-fpm = {
+          package = php;
+          settings = {
+            foobar = {
+              "user" = "nginx";
+              "listen.group" = "nginx";
+              "listen.mode" = "0600";
+              "listen.owner" = "nginx";
+              "pm" = "dynamic";
+              "pm.max_children" = 5;
+              "pm.max_requests" = 500;
+              "pm.max_spare_servers" = 3;
+              "pm.min_spare_servers" = 1;
+              "pm.start_servers" = 2;
+            };
+          };
+        };
+      };
+    };
+  testScript =
+    { ... }:
+    ''
+      machine.wait_for_unit("nginx.service")
+      machine.wait_for_unit("php-fpm.service")
+
+      # Check so we get an evaluated PHP back
+      response = machine.succeed("curl -fvvv -s http://127.0.0.1:80/")
+      assert "PHP Version ${php.version}" in response, "PHP version not detected"
+
+      # Check so we have database and some other extensions loaded
+      for ext in ["json", "opcache", "pdo_mysql", "pdo_pgsql", "pdo_sqlite", "apcu"]:
+          assert ext in response, f"Missing {ext} extension"
+          machine.succeed(f'test -n "$(php -m | grep -i {ext})"')
+    '';
+}

nixos/tests/php/fpm.nix

@@ -0,0 +1,64 @@
+{ lib, php, ... }:
+{
+  name = "php-${php.version}-fpm-nginx-test";
+  meta.maintainers = lib.teams.php.members;
+
+  nodes.machine =
+    { config, pkgs, ... }:
+    {
+      environment.systemPackages = [ php ];
+
+      services.nginx = {
+        enable = true;
+
+        virtualHosts."phpfpm" =
+          let
+            testdir = pkgs.writeTextDir "web/index.php" "<?php phpinfo();";
+          in
+          {
+            root = "${testdir}/web";
+            locations."~ \\.php$".extraConfig = ''
+              fastcgi_pass unix:${config.services.phpfpm.pools.foobar.socket};
+              fastcgi_index index.php;
+              include ${config.services.nginx.package}/conf/fastcgi_params;
+              include ${pkgs.nginx}/conf/fastcgi.conf;
+            '';
+            locations."/" = {
+              tryFiles = "$uri $uri/ index.php";
+              index = "index.php index.html index.htm";
+            };
+          };
+      };
+
+      services.phpfpm.pools."foobar" = {
+        user = "nginx";
+        phpPackage = php;
+        settings = {
+          "listen.group" = "nginx";
+          "listen.mode" = "0600";
+          "listen.owner" = "nginx";
+          "pm" = "dynamic";
+          "pm.max_children" = 5;
+          "pm.max_requests" = 500;
+          "pm.max_spare_servers" = 3;
+          "pm.min_spare_servers" = 1;
+          "pm.start_servers" = 2;
+        };
+      };
+    };
+  testScript =
+    { ... }:
+    ''
+      machine.wait_for_unit("nginx.service")
+      machine.wait_for_unit("phpfpm-foobar.service")
+
+      # Check so we get an evaluated PHP back
+      response = machine.succeed("curl -fvvv -s http://127.0.0.1:80/")
+      assert "PHP Version ${php.version}" in response, "PHP version not detected"
+
+      # Check so we have database and some other extensions loaded
+      for ext in ["json", "opcache", "pdo_mysql", "pdo_pgsql", "pdo_sqlite", "apcu"]:
+          assert ext in response, f"Missing {ext} extension"
+          machine.succeed(f'test -n "$(php -m | grep -i {ext})"')
+    '';
+}

nixos/tests/php/httpd.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  php,
+  ...
+}:
+{
+  name = "php-${php.version}-httpd-test";
+  meta.maintainers = lib.teams.php.members;
+
+  nodes.machine =
+    {
+      config,
+      pkgs,
+      ...
+    }:
+    {
+      services.httpd = {
+        enable = true;
+        adminAddr = "admin@phpfpm";
+        virtualHosts."phpfpm" =
+          let
+            testdir = pkgs.writeTextDir "web/index.php" "<?php phpinfo();";
+          in
+          {
+            documentRoot = "${testdir}/web";
+            locations."/" = {
+              index = "index.php index.html";
+            };
+          };
+        phpPackage = php;
+        enablePHP = true;
+      };
+    };
+  testScript =
+    { ... }:
+    ''
+      machine.wait_for_unit("httpd.service")
+
+      # Check so we get an evaluated PHP back
+      response = machine.succeed("curl -fvvv -s http://127.0.0.1:80/")
+      assert "PHP Version ${php.version}" in response, "PHP version not detected"
+
+      # Check so we have database and some other extensions loaded
+      for ext in ["json", "opcache", "pdo_mysql", "pdo_pgsql", "pdo_sqlite"]:
+          assert ext in response, f"Missing {ext} extension"
+    '';
+}

nixos/tests/php/pcre.nix

@@ -0,0 +1,61 @@
+let
+  testString = "can-use-subgroups";
+in
+{
+  pkgs,
+  lib,
+  php,
+  ...
+}:
+{
+  name = "php-${php.version}-httpd-pcre-jit-test";
+  meta.maintainers = lib.teams.php.members;
+
+  nodes.machine =
+    { pkgs, ... }:
+    {
+      time.timeZone = "UTC";
+      services.httpd = {
+        enable = true;
+        adminAddr = "please@dont.contact";
+        phpPackage = php;
+        enablePHP = true;
+        phpOptions = "pcre.jit = true";
+        extraConfig =
+          let
+            testRoot = pkgs.writeText "index.php" ''
+              <?php
+              preg_match('/(${testString})/', '${testString}', $result);
+              var_dump($result);
+            '';
+          in
+          ''
+            Alias / ${testRoot}/
+
+            <Directory ${testRoot}>
+              Require all granted
+            </Directory>
+          '';
+      };
+    };
+  testScript =
+    let
+      # PCRE JIT SEAlloc feature does not play well with fork()
+      # The feature needs to either be disabled or PHP configured correctly
+      # More information in https://bugs.php.net/bug.php?id=78927 and https://bugs.php.net/bug.php?id=78630
+      pcreJitSeallocForkIssue = pkgs.writeText "pcre-jit-sealloc-issue.php" ''
+        <?php
+        preg_match('/nixos/', 'nixos');
+        $pid = pcntl_fork();
+        pcntl_wait($pid);
+      '';
+    in
+    ''
+      machine.wait_for_unit("httpd.service")
+      # Ensure php evaluation by matching on the var_dump syntax
+      response = machine.succeed("curl -fvvv -s http://127.0.0.1:80/index.php")
+      expected = 'string(${toString (builtins.stringLength testString)}) "${testString}"'
+      assert expected in response, "Does not appear to be able to use subgroups."
+      machine.succeed("${php}/bin/php -f ${pcreJitSeallocForkIssue}")
+    '';
+}