push sheeet

pkgs/applications/editors/vscode/extensions/chenglou92.rescript-vscode/default.nix

@@ -0,0 +1,55 @@
+{
+  lib,
+  stdenv,
+  vscode-utils,
+  callPackage,
+}:
+let
+  extVersion = "1.62.0";
+  rescript-editor-analysis = callPackage ./rescript-editor-analysis.nix { };
+
+  # Ensure the versions match
+  version =
+    if rescript-editor-analysis.version == extVersion then
+      rescript-editor-analysis.version
+    else
+      throw "analysis and extension versions must match";
+
+  arch =
+    if stdenv.hostPlatform.isLinux then
+      "linux"
+    else if stdenv.hostPlatform.isDarwin then
+      "darwin"
+    else
+      throw "Unsupported system: ${stdenv.system}";
+  analysisDir = "server/analysis_binaries/${arch}";
+in
+
+vscode-utils.buildVscodeMarketplaceExtension {
+  mktplcRef = {
+    name = "rescript-vscode";
+    publisher = "chenglou92";
+    inherit version;
+    hash = "sha256-yUAhysTM9FXo9ZAzrto+tnjnofIUEQAGBg3tjIainrY=";
+  };
+
+  # For rescript-language-server
+  passthru.rescript-editor-analysis = rescript-editor-analysis;
+
+  strictDeps = true;
+  postPatch = ''
+    rm -r ${analysisDir}
+    ln -s ${rescript-editor-analysis}/bin ${analysisDir}
+  '';
+
+  meta = {
+    description = "Official VSCode plugin for ReScript";
+    homepage = "https://github.com/rescript-lang/rescript-vscode";
+    maintainers = [
+      lib.maintainers.dlip
+      lib.maintainers.jayesh-bhoot
+    ];
+    platforms = lib.platforms.linux ++ lib.platforms.darwin;
+    license = lib.licenses.mit;
+  };
+}

pkgs/applications/editors/vscode/extensions/chenglou92.rescript-vscode/rescript-editor-analysis.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  fetchFromGitHub,
+  nix-update-script,
+  ocamlPackages,
+}:
+
+ocamlPackages.buildDunePackage rec {
+  pname = "analysis";
+  version = "1.62.0";
+
+  minimalOCamlVersion = "4.10";
+
+  src = fetchFromGitHub {
+    owner = "rescript-lang";
+    repo = "rescript-vscode";
+    tag = version;
+    hash = "sha256-Tox5Qq0Kpqikac90sQww2cGr9RHlXnVy7GMnRA18CoA=";
+  };
+
+  strictDeps = true;
+  nativeBuildInputs = [
+    ocamlPackages.cppo
+  ];
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [
+      "--version-regex"
+      "([0-9]+\.[0-9]+\.[0-9]+)"
+    ];
+  };
+
+  meta = {
+    description = "Analysis binary for the ReScript VSCode plugin";
+    homepage = "https://github.com/rescript-lang/rescript-vscode";
+    changelog = "https://github.com/rescript-lang/rescript-vscode/releases/tag/${version}";
+    maintainers = with lib.maintainers; [
+      dlip
+      jayesh-bhoot
+      RossSmyth
+    ];
+    license = lib.licenses.mit;
+    mainProgram = "rescript-editor-analysis";
+  };
+}