push sheeet

pkgs/applications/emulators/cdemu/analyzer.nix

@@ -0,0 +1,54 @@
+{
+  cmake,
+  pkg-config,
+  callPackage,
+  gobject-introspection,
+  wrapGAppsHook3,
+  python3Packages,
+  libxml2,
+  gnuplot,
+  adwaita-icon-theme,
+  gdk-pixbuf,
+  intltool,
+  libmirage,
+}:
+python3Packages.buildPythonApplication {
+
+  inherit
+    (callPackage ./common-drv-attrs.nix {
+      version = "3.2.6";
+      pname = "image-analyzer";
+      hash = "sha256-7I8RUgd+k3cEzskJGbziv1f0/eo5QQXn62wGh/Y5ozc=";
+    })
+    pname
+    version
+    src
+    meta
+    ;
+
+  buildInputs = [
+    libxml2
+    gnuplot
+    libmirage
+    adwaita-icon-theme
+    gdk-pixbuf
+  ];
+  propagatedBuildInputs = with python3Packages; [
+    pygobject3
+    matplotlib
+  ];
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    wrapGAppsHook3
+    intltool
+    gobject-introspection
+  ];
+
+  pyproject = false;
+  dontWrapGApps = true;
+  preFixup = ''
+    makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
+  '';
+
+}

pkgs/applications/emulators/cdemu/client.nix

@@ -0,0 +1,42 @@
+{
+  callPackage,
+  python3Packages,
+  cmake,
+  pkg-config,
+  intltool,
+  wrapGAppsNoGuiHook,
+  gobject-introspection,
+}:
+python3Packages.buildPythonApplication {
+
+  inherit
+    (callPackage ./common-drv-attrs.nix {
+      version = "3.2.5";
+      pname = "cdemu-client";
+      hash = "sha256-py2F61v8vO0BCM18GCflAiD48deZjbMM6wqoCDZsOd8=";
+    })
+    pname
+    version
+    src
+    meta
+    ;
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    intltool
+    wrapGAppsNoGuiHook
+    gobject-introspection
+  ];
+  propagatedBuildInputs = with python3Packages; [
+    dbus-python
+    pygobject3
+  ];
+
+  pyproject = false;
+  dontWrapGApps = true;
+  preFixup = ''
+    makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
+  '';
+
+}

pkgs/applications/emulators/cdemu/common-drv-attrs.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  fetchurl,
+  pname,
+  version,
+  hash,
+}:
+
+{
+  inherit pname version;
+  src = fetchurl {
+    url = "mirror://sourceforge/cdemu/${pname}-${version}.tar.xz";
+    inherit hash;
+  };
+  meta = with lib; {
+    description = "Suite of tools for emulating optical drives and discs";
+    longDescription = ''
+      CDEmu consists of:
+
+      - a kernel module implementing a virtual drive-controller
+      - libmirage which is a software library for interpreting optical disc images
+      - a daemon which emulates the functionality of an optical drive+disc
+      - textmode and GTK clients for controlling the emulator
+      - an image analyzer to view the structure of image files
+
+      Optical media emulated by CDemu can be mounted within Linux. Automounting is also allowed.
+    '';
+    homepage = "https://cdemu.sourceforge.io/";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = with lib.maintainers; [ bendlas ];
+  };
+}

pkgs/applications/emulators/cdemu/daemon.nix

@@ -0,0 +1,59 @@
+{
+  stdenv,
+  callPackage,
+  cmake,
+  pkg-config,
+  glib,
+  libao,
+  intltool,
+  libmirage,
+  coreutils,
+}:
+
+let
+  inherit
+    (callPackage ./common-drv-attrs.nix {
+      version = "3.2.7";
+      pname = "cdemu-daemon";
+      hash = "sha256-EKh2G6RA9Yq46BpTAqN2s6TpLJb8gwDuEpGiwdGcelc=";
+    })
+    pname
+    version
+    src
+    meta
+    ;
+in
+stdenv.mkDerivation {
+  inherit pname version src;
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    intltool
+  ];
+  buildInputs = [
+    glib
+    libao
+    libmirage
+  ];
+  postInstall = ''
+    mkdir -p $out/share/dbus-1/services
+    cp -R ../service-example $out/share/cdemu
+    substitute \
+      $out/share/cdemu/net.sf.cdemu.CDEmuDaemon.service \
+      $out/share/dbus-1/services/net.sf.cdemu.CDEmuDaemon.service \
+      --replace /bin/true ${coreutils}/bin/true
+  '';
+
+  meta = {
+    inherit (meta)
+      description
+      license
+      longDescription
+      maintainers
+      platforms
+      ;
+    homepage = "https://cdemu.sourceforge.io/about/daemon/";
+    mainProgram = "cdemu-daemon";
+  };
+}

pkgs/applications/emulators/cdemu/gui.nix

@@ -0,0 +1,49 @@
+{
+  callPackage,
+  cmake,
+  pkg-config,
+  wrapGAppsHook3,
+  gobject-introspection,
+  python3Packages,
+  libnotify,
+  intltool,
+  adwaita-icon-theme,
+  gdk-pixbuf,
+  libappindicator-gtk3,
+}:
+python3Packages.buildPythonApplication {
+
+  inherit
+    (callPackage ./common-drv-attrs.nix {
+      version = "3.2.6";
+      pname = "gcdemu";
+      hash = "sha256-w4vzKoSotL5Cjfr4Cu4YhNSWXJqS+n/vySrwvbhR1zA=";
+    })
+    pname
+    version
+    src
+    meta
+    ;
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    wrapGAppsHook3
+    intltool
+    gobject-introspection
+  ];
+  buildInputs = [
+    libnotify
+    adwaita-icon-theme
+    gdk-pixbuf
+    libappindicator-gtk3
+  ];
+  propagatedBuildInputs = with python3Packages; [ pygobject3 ];
+
+  pyproject = false;
+  dontWrapGApps = true;
+  preFixup = ''
+    makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
+  '';
+
+}

pkgs/applications/emulators/cdemu/libmirage.nix

@@ -0,0 +1,70 @@
+{
+  stdenv,
+  callPackage,
+  cmake,
+  pkg-config,
+  gobject-introspection,
+  vala,
+  glib,
+  libsndfile,
+  zlib,
+  bzip2,
+  xz,
+  libsamplerate,
+  intltool,
+  pcre,
+  util-linux,
+  libselinux,
+  libsepol,
+}:
+
+let
+  inherit
+    (callPackage ./common-drv-attrs.nix {
+      version = "3.2.10";
+      pname = "libmirage";
+      hash = "sha256-+T5Gu3VcprCkSJcq/kTySRnNI7nc+GbRtctLkzPhgK4=";
+    })
+    pname
+    version
+    src
+    meta
+    ;
+in
+stdenv.mkDerivation {
+  inherit pname version src;
+
+  PKG_CONFIG_GOBJECT_INTROSPECTION_1_0_GIRDIR = "${placeholder "out"}/share/gir-1.0";
+  PKG_CONFIG_GOBJECT_INTROSPECTION_1_0_TYPELIBDIR = "${placeholder "out"}/lib/girepository-1.0";
+  buildInputs = [
+    glib
+    libsndfile
+    zlib
+    bzip2
+    xz
+    libsamplerate
+  ];
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    intltool
+    gobject-introspection
+    vala
+  ];
+  propagatedBuildInputs = [
+    pcre
+    util-linux
+    libselinux
+    libsepol
+  ];
+
+  meta = {
+    inherit (meta)
+      maintainers
+      license
+      platforms
+      ;
+    description = "CD-ROM image access library";
+    homepage = "https://cdemu.sourceforge.io/about/libmirage/";
+  };
+}

pkgs/applications/emulators/cdemu/vhba.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  kernel,
+  kernelModuleMakeFlags,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "vhba";
+  version = "20250329";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/cdemu/vhba-module-${version}.tar.xz";
+    hash = "sha256-piog1yDd8M/lpTIo9FE9SY2JwurZ6a8LG2lZ/4EmB14=";
+  };
+
+  makeFlags = kernelModuleMakeFlags ++ [
+    "KDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
+    "INSTALL_MOD_PATH=$(out)"
+  ];
+  nativeBuildInputs = kernel.moduleBuildDependencies;
+
+  meta = with lib; {
+    description = "Provides a Virtual (SCSI) HBA";
+    homepage = "https://cdemu.sourceforge.io/about/vhba/";
+    platforms = platforms.linux;
+    license = licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ bendlas ];
+  };
+}