push sheeet

pkgs/applications/graphics/sane/backends/default.nix

@@ -0,0 +1,198 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitLab,
+  fetchpatch,
+  buildPackages,
+  gettext,
+  pkg-config,
+  python3,
+  avahi,
+  libgphoto2,
+  libieee1284,
+  libjpeg,
+  libpng,
+  libtiff,
+  libusb1,
+  libv4l,
+  net-snmp,
+  curl,
+  systemdLibs,
+  withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemdLibs,
+  libxml2,
+  poppler,
+  gawk,
+  sane-drivers,
+  nixosTests,
+  autoconf,
+  automake,
+  libtool,
+  autoconf-archive,
+
+  # List of { src name backend } attribute sets - see installFirmware below:
+  extraFirmware ? [ ],
+
+  # For backwards compatibility with older setups; use extraFirmware instead:
+  gt68xxFirmware ? null,
+  snapscanFirmware ? null,
+
+  # Not included by default, scan snap drivers require fetching of unfree binaries.
+  scanSnapDriversUnfree ? false,
+  scanSnapDriversPackage ? sane-drivers.epjitsu,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "sane-backends";
+  version = "1.4.0";
+
+  src = fetchFromGitLab {
+    owner = "sane-project";
+    repo = "backends";
+    tag = finalAttrs.version;
+    hash = "sha256-e7Wjda+CobYatblvVCGkMAO2aWrdSCp7q+qIEGnGDCY=";
+  };
+
+  # Fix hangs in tests, hopefully
+  # FIXME: remove in next release
+  patches = [
+    (fetchpatch {
+      url = "https://gitlab.com/sane-project/backends/-/commit/8acc267d5f4049d8438456821137ae56e91baea9.patch";
+      hash = "sha256-IyupDeH1MPvEBnGaUzBbCu106Gp7zXxlPGFAaiiINQI=";
+    })
+  ];
+
+  postPatch = ''
+    # Do not create lock dir in install phase
+    sed -i '/^install-lockpath:/!b;n;c\       # pass' backend/Makefile.am
+  '';
+
+  preConfigure = ''
+    # create version files, so that autotools macros can use them:
+    # https://gitlab.com/sane-project/backends/-/issues/440
+    printf "%s\n" "$version" > .tarball-version
+    printf "%s\n" "$version" > .version
+
+    autoreconf -fiv
+
+    # Fixes for cross compilation
+    # https://github.com/NixOS/nixpkgs/issues/308283
+
+    # sane-desc will be used in postInstall so compile it for build
+    # https://github.com/void-linux/void-packages/blob/master/srcpkgs/sane/patches/sane-desc-cross.patch
+    patch -p1 -i ${./sane-desc-cross.patch}
+  '';
+
+  outputs = [
+    "out"
+    "doc"
+    "man"
+  ];
+
+  depsBuildBuild = [ buildPackages.stdenv.cc ];
+
+  nativeBuildInputs = [
+    autoconf
+    autoconf-archive
+    automake
+    gettext
+    libtool
+    pkg-config
+    python3
+  ];
+
+  buildInputs = [
+    avahi
+    libgphoto2
+    libjpeg
+    libpng
+    libtiff
+    libusb1
+    curl
+    libxml2
+    poppler
+    gawk
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    libieee1284
+    libv4l
+    net-snmp
+  ]
+  ++ lib.optionals withSystemd [
+    systemdLibs
+  ];
+
+  enableParallelBuilding = true;
+
+  configureFlags = [
+    "--with-lockdir=/var/lock/sane"
+  ]
+  ++ lib.optionals (avahi != null) [ "--with-avahi" ]
+  ++ lib.optionals (libusb1 != null) [ "--with-usb" ];
+
+  # autoconf check for HAVE_MMAP is never set on cross compilation.
+  # The pieusb backend fails compilation if HAVE_MMAP is not set.
+  buildFlags = lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
+    "CFLAGS=-DHAVE_MMAP=${if stdenv.hostPlatform.isLinux then "1" else "0"}"
+  ];
+
+  postInstall =
+    let
+      compatFirmware =
+        extraFirmware
+        ++ lib.optional (gt68xxFirmware != null) {
+          src = gt68xxFirmware.fw;
+          inherit (gt68xxFirmware) name;
+          backend = "gt68xx";
+        }
+        ++ lib.optional (snapscanFirmware != null) {
+          src = snapscanFirmware;
+          name = "your-firmwarefile.bin";
+          backend = "snapscan";
+        };
+
+      installFirmware = f: ''
+        mkdir -p $out/share/sane/${f.backend}
+        ln -sv ${f.src} $out/share/sane/${f.backend}/${f.name}
+      '';
+    in
+    ''
+      mkdir -p $out/etc/udev/rules.d/ $out/etc/udev/hwdb.d
+      ./tools/sane-desc -m udev+hwdb -s doc/descriptions:doc/descriptions-external > $out/etc/udev/rules.d/49-libsane.rules
+      ./tools/sane-desc -m udev+hwdb -s doc/descriptions:doc/descriptions-external -m hwdb > $out/etc/udev/hwdb.d/20-sane.hwdb
+
+      # net.conf conflicts with the file generated by the nixos module
+      rm $out/etc/sane.d/net.conf
+
+    ''
+    + lib.optionalString scanSnapDriversUnfree ''
+      # the ScanSnap drivers live under the epjitsu subdirectory, which was already created by the build but is empty.
+      rmdir $out/share/sane/epjitsu
+      ln -svT ${scanSnapDriversPackage} $out/share/sane/epjitsu
+    ''
+    + lib.concatStrings (map installFirmware compatFirmware);
+
+  # parallel install creates a bad symlink at $out/lib/sane/libsane.so.1 which prevents finding plugins
+  # https://github.com/NixOS/nixpkgs/issues/224569
+  enableParallelInstalling = false;
+
+  doInstallCheck = true;
+
+  passthru.tests = {
+    inherit (nixosTests) sane;
+  };
+
+  meta = {
+    description = "SANE (Scanner Access Now Easy) backends";
+    longDescription = ''
+      Collection of open-source SANE backends (device drivers).
+      SANE is a universal scanner interface providing standardized access to
+      any raster image scanner hardware: flatbed scanners, hand-held scanners,
+      video- and still-cameras, frame-grabbers, etc. For a list of supported
+      scanners, see http://www.sane-project.org/sane-backends.html.
+    '';
+    homepage = "http://www.sane-project.org/";
+    license = lib.licenses.gpl2Plus;
+    platforms = lib.platforms.linux ++ lib.platforms.darwin;
+    maintainers = [ lib.maintainers.symphorien ];
+  };
+})

pkgs/applications/graphics/sane/backends/sane-desc-cross.patch

@@ -0,0 +1,12 @@
+--- a/tools/Makefile.in
++++ b/tools/Makefile.in
+@@ -586,7 +586,7 @@ gamma4scanimage$(EXEEXT): $(gamma4scanimage_OBJECTS) $(gamma4scanimage_DEPENDENC
+ 
+ sane-desc$(EXEEXT): $(sane_desc_OBJECTS) $(sane_desc_DEPENDENCIES) $(EXTRA_sane_desc_DEPENDENCIES) 
+ 	@rm -f sane-desc$(EXEEXT)
+-	$(AM_V_CCLD)$(LINK) $(sane_desc_OBJECTS) $(sane_desc_LDADD) $(LIBS)
++	cc -I. sane-desc.c -I../include ../sanei/sanei_config.c ../sanei/sanei_init_debug.c ../sanei/sanei_constrain_value.c -o $@
+ 
+ sane-find-scanner$(EXEEXT): $(sane_find_scanner_OBJECTS) $(sane_find_scanner_DEPENDENCIES) $(EXTRA_sane_find_scanner_DEPENDENCIES) 
+ 	@rm -f sane-find-scanner$(EXEEXT)
+

pkgs/applications/graphics/sane/config.nix

@@ -0,0 +1,55 @@
+{ lib, stdenv }:
+
+{
+  paths,
+  disabledDefaultBackends ? [ ],
+}:
+
+let
+  installSanePath = path: ''
+    if [ -e "${path}/lib/sane" ]; then
+      find "${path}/lib/sane" -maxdepth 1 -not -type d | while read backend; do
+        symlink "$backend" "$out/lib/sane/$(basename "$backend")"
+      done
+    fi
+
+    if [ -e "${path}/etc/sane.d" ]; then
+      find "${path}/etc/sane.d" -maxdepth 1 -not -type d | while read conf; do
+        name="$(basename $conf)"
+        if [ "$name" = "dll.conf" ] || [ "$name" = "saned.conf" ] || [ "$name" = "net.conf" ]; then
+          cat "$conf" >> "$out/etc/sane.d/$name"
+        else
+          symlink "$conf" "$out/etc/sane.d/$name"
+        fi
+      done
+    fi
+
+    if [ -e "${path}/etc/sane.d/dll.d" ]; then
+      find "${path}/etc/sane.d/dll.d" -maxdepth 1 -not -type d | while read conf; do
+        symlink "$conf" "$out/etc/sane.d/dll.d/$(basename $conf)"
+      done
+    fi
+  '';
+  disableBackend = backend: ''
+    grep -w -q '${backend}' $out/etc/sane.d/dll.conf || { echo '${backend} is not a default plugin in $SANE_CONFIG_DIR/dll.conf'; exit 1; }
+    sed -i 's/\b${backend}\b/# ${backend} disabled by nixos config/' $out/etc/sane.d/dll.conf
+  '';
+in
+stdenv.mkDerivation {
+  name = "sane-config";
+  dontUnpack = true;
+
+  installPhase = ''
+    function symlink () {
+      local target=$1 linkname=$2
+      if [ -e "$linkname" ]; then
+        echo "warning: conflict for $linkname. Overriding $(readlink $linkname) with $target."
+      fi
+      ln -sfn "$target" "$linkname"
+    }
+
+    mkdir -p $out/etc/sane.d $out/etc/sane.d/dll.d $out/lib/sane
+  ''
+  + (lib.concatMapStrings installSanePath paths)
+  + (lib.concatMapStrings disableBackend disabledDefaultBackends);
+}

pkgs/applications/graphics/sane/drivers.nix

@@ -0,0 +1,13 @@
+{ lib, fetchFromGitHub }:
+
+{
+  # Fujitsu ScanSnap
+  epjitsu = fetchFromGitHub {
+    name = "scansnap-firmware";
+    owner = "stevleibelt";
+    repo = "scansnap-firmware";
+    rev = "96c3a8b2a4e4f1ccc4e5827c5eb5598084fd17c8";
+    sha256 = "1inchnvaqyw9d0skpg8hp5rpn27c09q58lsr42by4bahpbx5qday";
+    meta.license = lib.licenses.unfree;
+  };
+}

pkgs/applications/graphics/sane/frontends.nix

@@ -0,0 +1,80 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  fetchpatch,
+  sane-backends,
+  libX11,
+  gtk2,
+  pkg-config,
+  libusb-compat-0_1 ? null,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "sane-frontends";
+  version = "1.0.14";
+
+  src = fetchurl {
+    url = "https://alioth-archive.debian.org/releases/sane/${pname}/${version}/${pname}-${version}.tar.gz";
+    sha256 = "1ad4zr7rcxpda8yzvfkq1rfjgx9nl6lan5a628wvpdbh3fn9v0z7";
+  };
+
+  # add all fedora patchs. fix gcc-14 build among other things
+  # https://src.fedoraproject.org/rpms/sane-frontends/tree/main
+  patches =
+    let
+      fetchFedoraPatch =
+        { name, hash }:
+        fetchpatch {
+          inherit name hash;
+          url = "https://src.fedoraproject.org/rpms/sane-frontends/raw/89f752d7e236e86be8d64b7ac6991a36f9e9f7d0/f/${name}";
+        };
+    in
+    map fetchFedoraPatch [
+      {
+        name = "0001-src-scanadf.c-Fix-segfault-when-scanadf-h-d-device.patch";
+        hash = "sha256-sSUWm5fL7YTebzXh3Thb/qwgr7d++1Y+74uI8R5oF0g=";
+      }
+      {
+        name = "frontends-scanadf-segv.patch";
+        hash = "sha256-VRag9nMk8ZCjg9Oq0siHdT8J6sbNjq9cU2ktOH2vkLo=";
+      }
+      {
+        name = "sane-frontends-1.0.14-array-out-of-bounds.patch";
+        hash = "sha256-a0lzbAogSrXsK5jVeNffDS+zFxpuDHXpHQlOJ5874+U=";
+      }
+      {
+        name = "sane-frontends-1.0.14-sane-backends-1.0.20.patch";
+        hash = "sha256-ViYjxXGj58P6EaZ+fIiAydrgbyS1ivn39uN3EWcvnZg=";
+      }
+      {
+        name = "sane-frontends-1.0.14-xcam-man.patch";
+        hash = "sha256-HGANgQPujn/jjOMGs9LlzYvYZphMWwbsI74NCad5ADc=";
+      }
+      {
+        name = "sane-frontends-c99.patch";
+        hash = "sha256-LPELEG11wEom05ECAMgXUDRWvrbuU4nT3apuS1eITyA=";
+      }
+      {
+        name = "sane-frontends-configure-c99.patch";
+        hash = "sha256-SPvMDCZv8VRGP+cXRFjVbqgbTeVhdLOTEQbbBgSMLvY=";
+      }
+    ];
+
+  buildInputs = [
+    sane-backends
+    libX11
+    gtk2
+  ]
+  ++ lib.optional (libusb-compat-0_1 != null) libusb-compat-0_1;
+  nativeBuildInputs = [ pkg-config ];
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "Scanner Access Now Easy";
+    homepage = "http://www.sane-project.org/";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+  };
+}