push sheeet

pkgs/applications/misc/clight/clight-gui.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  qtbase,
+  qtcharts,
+  wrapQtAppsHook,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "clight-gui";
+  version = "unstable-2023-02-21";
+
+  src = fetchFromGitHub {
+    owner = "nullobsi";
+    repo = "clight-gui";
+    rev = "29e7216bfcc68135350a695ce446134bcb0463a6";
+    hash = "sha256-U4vaMwnVDZnYLc+K3/yD81Q1vyBL8uSrrhOHbjbox5U=";
+  };
+
+  buildInputs = [
+    qtbase
+    qtcharts
+  ];
+  nativeBuildInputs = [
+    cmake
+    wrapQtAppsHook
+  ];
+
+  sourceRoot = "${src.name}/src";
+
+  meta = with lib; {
+    description = "Qt GUI for clight";
+    homepage = "https://github.com/nullobsi/clight-gui";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ nickhu ];
+    mainProgram = "clight-gui";
+    platforms = platforms.linux;
+  };
+}

pkgs/applications/misc/clight/clightd.nix

@@ -0,0 +1,111 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  dbus,
+  cmake,
+  pkg-config,
+  wayland-scanner,
+  glib,
+  udev,
+  polkit,
+  libusb1,
+  libjpeg,
+  libmodule,
+  libXdmcp,
+  util-linux,
+  libpthreadstubs,
+  enableDdc ? true,
+  ddcutil,
+  enableDpms ? true,
+  libXext,
+  enableGamma ? true,
+  libdrm,
+  libXrandr,
+  libiio,
+  wayland,
+  enableScreen ? true,
+  enableYoctolight ? true,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "clightd";
+  version = "5.9";
+
+  src = fetchFromGitHub {
+    owner = "FedeDP";
+    repo = "Clightd";
+    rev = version;
+    hash = "sha256-LOhBBd7QL5kH4TzMFgrh70C37WsFdsiKArP+tIEiPWo=";
+  };
+
+  # dbus-1.pc has datadir=/etc
+  SYSTEM_BUS_DIR = "${placeholder "out"}/share/dbus-1/system-services";
+  # polkit-gobject-1.pc has prefix=${polkit.out}
+  POLKIT_ACTION_DIR = "${placeholder "out"}/share/polkit-1/actions";
+
+  postPatch = ''
+    sed -i "s@pkg_get_variable(SYSTEM_BUS_DIR.*@set(SYSTEM_BUS_DIR $SYSTEM_BUS_DIR)@" CMakeLists.txt
+    sed -i "s@pkg_get_variable(POLKIT_ACTION_DIR.*@set(POLKIT_ACTION_DIR $POLKIT_ACTION_DIR)@" CMakeLists.txt
+  '';
+
+  cmakeFlags = [
+    "-DSYSTEMD_SERVICE_DIR=${placeholder "out"}/lib/systemd/system"
+    "-DDBUS_CONFIG_DIR=${placeholder "out"}/etc/dbus-1/system.d"
+    # systemd.pc has prefix=${systemd.out}
+    "-DMODULE_LOAD_DIR=${placeholder "out"}/lib/modules-load.d"
+  ]
+  ++ lib.optional enableDdc "-DENABLE_DDC=1"
+  ++ lib.optional enableDpms "-DENABLE_DPMS=1"
+  ++ lib.optional enableGamma "-DENABLE_GAMMA=1"
+  ++ lib.optional enableScreen "-DENABLE_SCREEN=1"
+  ++ lib.optional enableYoctolight "-DENABLE_YOCTOLIGHT=1";
+
+  depsBuildBuild = [
+    pkg-config
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    wayland-scanner
+  ];
+
+  buildInputs = [
+    dbus
+    glib
+    udev
+    polkit
+    libusb1
+    libjpeg
+    libmodule
+    libiio
+
+    libXdmcp
+    util-linux
+    libpthreadstubs
+  ]
+  ++ lib.optionals enableDdc [ ddcutil ]
+  ++ lib.optionals enableDpms [ libXext ]
+  ++ lib.optionals enableGamma [ libXrandr ]
+  ++ lib.optionals (enableDpms || enableGamma || enableScreen) [
+    libdrm
+    wayland
+  ];
+
+  postInstall = ''
+    mkdir -p $out/bin
+    ln -svT $out/libexec/clightd $out/bin/clightd
+  '';
+
+  meta = with lib; {
+    description = "Linux bus interface that changes screen brightness/temperature";
+    mainProgram = "clightd";
+    homepage = "https://github.com/FedeDP/Clightd";
+    platforms = platforms.linux;
+    license = licenses.gpl3;
+    maintainers = with maintainers; [
+      eadwu
+    ];
+  };
+}

pkgs/applications/misc/clight/default.nix

@@ -0,0 +1,68 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  dbus,
+  cmake,
+  pkg-config,
+  bash-completion,
+  gsl,
+  popt,
+  clightd,
+  systemd,
+  libconfig,
+  libmodule,
+  withGeoclue ? true,
+  geoclue2,
+  withUpower ? true,
+  upower,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "clight";
+  version = "4.11";
+
+  src = fetchFromGitHub {
+    owner = "FedeDP";
+    repo = "Clight";
+    rev = version;
+    sha256 = "sha256-Fu38HRP83Yn2jsq9xnCWOXNlV/0hJKD1/cOOp3EV45Q=";
+  };
+
+  nativeBuildInputs = [
+    dbus
+    cmake
+    pkg-config
+    bash-completion
+  ];
+
+  buildInputs = [
+    gsl
+    popt
+    upower
+    clightd
+    systemd
+    geoclue2
+    libconfig
+    libmodule
+  ]
+  ++ lib.optional withGeoclue geoclue2
+  ++ lib.optional withUpower upower;
+
+  cmakeFlags = [
+    "-DSESSION_BUS_DIR=${placeholder "out"}/share/dbus-1/services"
+    "-DBASH_COMPLETIONS_DIR=${placeholder "out"}/share/bash-completions/completions"
+    "-DZSH_COMPLETIONS_DIR=${placeholder "out"}/share/zsh/site-functions"
+  ];
+
+  meta = with lib; {
+    description = "C daemon that turns your webcam into a light sensor";
+    homepage = "https://github.com/FedeDP/Clight";
+    platforms = platforms.linux;
+    license = licenses.gpl3;
+    maintainers = with maintainers; [
+      eadwu
+    ];
+    mainProgram = "clight";
+  };
+}