push sheeet

pkgs/applications/misc/kiwix/default.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nix-update-script,
+  libkiwix,
+  pkg-config,
+  qmake,
+  qtbase,
+  qtwebengine,
+  qtsvg,
+  qtimageformats,
+  wrapQtAppsHook,
+  aria2,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "kiwix";
+  version = "2.4.1";
+
+  src = fetchFromGitHub {
+    owner = "kiwix";
+    repo = "kiwix-desktop";
+    rev = version;
+    hash = "sha256-B3RcYr/b8pZTJV35BWuqmWbq+C2WkkcwBR0oNaUXPRw=";
+  };
+
+  nativeBuildInputs = [
+    qmake
+    pkg-config
+    wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    libkiwix
+    qtbase
+    qtwebengine
+    qtsvg
+    qtimageformats
+  ];
+
+  qtWrapperArgs = [
+    "--prefix PATH : ${lib.makeBinPath [ aria2 ]}"
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = with lib; {
+    description = "Offline reader for Web content";
+    mainProgram = "kiwix-desktop";
+    homepage = "https://kiwix.org";
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ greg ];
+  };
+}

pkgs/applications/misc/kiwix/lib.nix

@@ -0,0 +1,74 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nix-update-script,
+  meson,
+  ninja,
+  pkg-config,
+  python3,
+  curl,
+  icu,
+  libzim,
+  pugixml,
+  zlib,
+  libmicrohttpd,
+  mustache-hpp,
+  gtest,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "libkiwix";
+  version = "14.0.0";
+
+  src = fetchFromGitHub {
+    owner = "kiwix";
+    repo = "libkiwix";
+    rev = finalAttrs.version;
+    hash = "sha256-QP23ZS0FJsMVtnWOofywaAPIU0GJ2L+hLP/x0LXMKiU=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    python3
+  ];
+
+  buildInputs = [
+    icu
+    zlib
+    mustache-hpp
+  ];
+
+  propagatedBuildInputs = [
+    curl
+    libmicrohttpd
+    libzim
+    pugixml
+  ];
+
+  nativeCheckInputs = [
+    gtest
+  ];
+
+  doCheck = true;
+
+  postPatch = ''
+    patchShebangs scripts
+    substituteInPlace meson.build \
+        --replace-fail "libicu_dep = dependency('icu-i18n', static:static_deps)" \
+                       "libicu_dep = [dependency('icu-i18n', static:static_deps), dependency('icu-uc', static:static_deps)]"
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = with lib; {
+    description = "Common code base for all Kiwix ports";
+    homepage = "https://kiwix.org";
+    changelog = "https://github.com/kiwix/libkiwix/releases/tag/${finalAttrs.version}";
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ colinsane ];
+  };
+})

pkgs/applications/misc/kiwix/tools.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  docopt_cpp,
+  fetchFromGitHub,
+  gitUpdater,
+  icu,
+  libkiwix,
+  meson,
+  ninja,
+  pkg-config,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kiwix-tools";
+  version = "3.7.0-unstable-2024-12-21";
+
+  src = fetchFromGitHub {
+    owner = "kiwix";
+    repo = "kiwix-tools";
+    rev = "43b00419dd3f33eb644e1d83c2e802fc200b2de7";
+    hash = "sha256-Rctb6ZPTXjgSrLRB5VK4CEqYHuEPB7a+SQaNi47cxv0=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    docopt_cpp
+    icu
+    libkiwix
+  ];
+
+  passthru.updateScript = gitUpdater { };
+
+  meta = with lib; {
+    description = "Command line Kiwix tools";
+    homepage = "https://kiwix.org";
+    changelog = "https://github.com/kiwix/kiwix-tools/releases/tag/${finalAttrs.version}";
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ colinsane ];
+  };
+})