push sheeet

pkgs/applications/networking/cluster/helm/plugins/default.nix

@@ -0,0 +1,21 @@
+{ callPackage }:
+
+{
+  helm-cm-push = callPackage ./helm-cm-push.nix { };
+
+  helm-diff = callPackage ./helm-diff.nix { };
+
+  helm-dt = callPackage ./helm-dt.nix { };
+
+  helm-git = callPackage ./helm-git.nix { };
+
+  helm-mapkubeapis = callPackage ./helm-mapkubeapis.nix { };
+
+  helm-s3 = callPackage ./helm-s3.nix { };
+
+  helm-secrets = callPackage ./helm-secrets.nix { };
+
+  helm-schema = callPackage ./helm-schema.nix { };
+
+  helm-unittest = callPackage ./helm-unittest.nix { };
+}

pkgs/applications/networking/cluster/helm/plugins/helm-cm-push.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "helm-cm-push";
+  version = "0.10.4";
+
+  src = fetchFromGitHub {
+    owner = "chartmuseum";
+    repo = "helm-push";
+    rev = "v${version}";
+    hash = "sha256-YnhI1/BDk9swr3YFm5ajGf4LLgPty7blA2tlsMH0erY=";
+  };
+
+  vendorHash = "sha256-7bUDKqkvBV1Upcrj4DQnVCP74QtKlSwF0Kl2sPFZpjc=";
+
+  subPackage = [ "cmd/helm-cm-push" ];
+
+  # Remove hooks.
+  postPatch = ''
+    sed -e '/^hooks:/,+2 d' -i plugin.yaml
+  '';
+
+  env.CGO_ENABLED = 0;
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  postInstall = ''
+    install -Dm644 plugin.yaml $out/helm-cm-push/plugin.yaml
+    mv $out/bin $out/helm-cm-push
+  '';
+
+  # Tests require the ChartMuseum service.
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Helm plugin to push chart package to ChartMuseum";
+    homepage = "https://github.com/chartmuseum/helm-push";
+    license = licenses.asl20;
+    maintainers = [ ];
+  };
+}

pkgs/applications/networking/cluster/helm/plugins/helm-diff.nix

@@ -0,0 +1,44 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+}:
+
+buildGoModule rec {
+  pname = "helm-diff";
+  version = "3.13.0";
+
+  src = fetchFromGitHub {
+    owner = "databus23";
+    repo = "helm-diff";
+    rev = "v${version}";
+    hash = "sha256-U1lNCOYix+7aPNq4U0A7KU4Cr+AqQsTUrYTg/0Zg5cs=";
+  };
+
+  vendorHash = "sha256-nwL6n0pthW12ij9iqmS404r0m9xv0qh8RYiQhqvJC2U=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/databus23/helm-diff/v3/cmd.Version=${version}"
+  ];
+
+  # NOTE: Remove the install and upgrade hooks.
+  postPatch = ''
+    sed -i '/^hooks:/,+2 d' plugin.yaml
+  '';
+
+  postInstall = ''
+    install -dm755 $out/${pname}
+    mv $out/bin $out/${pname}/
+    mv $out/${pname}/bin/{helm-,}diff
+    install -m644 -Dt $out/${pname} plugin.yaml
+  '';
+
+  meta = with lib; {
+    description = "Helm plugin that shows a diff";
+    homepage = "https://github.com/databus23/helm-diff";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ yurrriq ];
+  };
+}

pkgs/applications/networking/cluster/helm/plugins/helm-dt.nix

@@ -0,0 +1,48 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+}:
+buildGoModule rec {
+  pname = "helm-dt";
+  version = "0.4.9";
+
+  src = fetchFromGitHub {
+    owner = "vmware-labs";
+    repo = "distribution-tooling-for-helm";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-3zEu4fnvjM1SvyOyj6NzQteyfEh5X7ro/G0gkzt7ghY=";
+  };
+
+  vendorHash = "sha256-CIVgNS74V75etC9WBzoxu6aoMHlUYxWd22h2NG1uNn0=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X 'main.BuildDate=1970-01-01 00:00:00 UTC'"
+    "-X 'main.Commit=v${version}'"
+  ];
+
+  # NOTE: Remove the install and upgrade hooks.
+  postPatch = ''
+    sed -i '/^hooks:/,+2 d' plugin.yaml
+  '';
+
+  # require network/login
+  doCheck = false;
+  env.CGO_ENABLED = 1;
+
+  postInstall = ''
+    install -dm755 $out/helm-dt/bin
+    mv $out/bin/dt $out/helm-dt/bin/dt
+    rmdir $out/bin
+    install -m644 -Dt $out/helm-dt plugin.yaml
+  '';
+
+  meta = {
+    description = "Helm Distribution plugin is is a set of utilities and Helm Plugin for making offline work with Helm Charts easier";
+    homepage = "https://github.com/vmware-labs/distribution-tooling-for-helm";
+    maintainers = with lib.maintainers; [ ascii17 ];
+    license = lib.licenses.mit;
+  };
+}

pkgs/applications/networking/cluster/helm/plugins/helm-git.nix

@@ -0,0 +1,55 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  coreutils,
+  findutils,
+  gitMinimal,
+  gnugrep,
+  gnused,
+  makeWrapper,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "helm-git";
+  version = "1.4.1";
+
+  src = fetchFromGitHub {
+    owner = "aslafy-z";
+    repo = "helm-git";
+    rev = "v${version}";
+    sha256 = "sha256-gMx61fhAaiYHYd/so65DEBKANZZO826AFLU1FIE3hSs=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  # NOTE: helm-git is comprised of shell scripts.
+  dontBuild = true;
+
+  installPhase = ''
+    install -dm755 $out/helm-git
+    install -m644 -Dt $out/helm-git plugin.yaml
+    cp helm-git helm-git-plugin.sh $out/helm-git/
+
+    patchShebangs $out/helm-git/helm-git{,-plugin.sh}
+    wrapProgram $out/helm-git/helm-git \
+        --prefix PATH : ${
+          lib.makeBinPath [
+            coreutils
+            findutils
+            gitMinimal
+            gnugrep
+            gnused
+          ]
+        }
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Helm downloader plugin that provides GIT protocol support";
+    homepage = "https://github.com/aslafy-z/helm-git";
+    license = licenses.mit;
+    maintainers = with maintainers; [ flokli ];
+  };
+}

pkgs/applications/networking/cluster/helm/plugins/helm-mapkubeapis.nix

@@ -0,0 +1,38 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+}:
+
+buildGoModule rec {
+  pname = "helm-mapkubeapis";
+  version = "0.6.1";
+
+  src = fetchFromGitHub {
+    owner = "helm";
+    repo = "helm-mapkubeapis";
+    rev = "v${version}";
+    hash = "sha256-RvyoqfhvoXESmc6M4B1XeUtal0zQt6LCKjByyBe6pUU=";
+  };
+
+  vendorHash = "sha256-ZnfNje0JuTCckW9SMc2TLb968nHiGK/bgOJnIllJJq4=";
+
+  # NOTE: Remove the install and upgrade hooks.
+  postPatch = ''
+    sed -i '/^hooks:/,+2 d' plugin.yaml
+  '';
+
+  postInstall = ''
+    install -dm755 $out/helm-mapkubeapis
+    mv $out/bin $out/helm-mapkubeapis/
+    install -m644 -Dt $out/helm-mapkubeapis/config/ config/Map.yaml
+    install -m644 -Dt $out/helm-mapkubeapis plugin.yaml
+  '';
+
+  meta = {
+    description = "Helm plugin which maps deprecated or removed Kubernetes APIs in a release to supported APIs";
+    homepage = "https://github.com/helm/helm-mapkubeapis";
+    license = with lib.licenses; [ asl20 ];
+    maintainers = with lib.maintainers; [ aos ];
+  };
+}

pkgs/applications/networking/cluster/helm/plugins/helm-s3.nix

@@ -0,0 +1,50 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+}:
+
+buildGoModule rec {
+  pname = "helm-s3";
+  version = "0.17.0";
+
+  src = fetchFromGitHub {
+    owner = "hypnoglow";
+    repo = "helm-s3";
+    rev = "v${version}";
+    hash = "sha256-9n/Dzgr/wYGgJq47FdNGPPpOFzTRt4VaK8HA06F5FIE=";
+  };
+
+  vendorHash = "sha256-6YBIUUIvQ6ZDPF9Dz5tNXuHS+pa/yiNs4sKZbMudMxs=";
+
+  # NOTE: Remove the install and upgrade hooks.
+  postPatch = ''
+    sed -i '/^hooks:/,+2 d' plugin.yaml
+  '';
+
+  # NOTE: make test-unit, but skip awsutil, which needs internet access
+  checkPhase = ''
+    go test $(go list ./... | grep -vE '(awsutil|e2e)')
+  '';
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.version=${version}"
+  ];
+
+  subPackages = [ "cmd/helm-s3" ];
+
+  postInstall = ''
+    install -dm755 $out/helm-s3
+    mv $out/bin $out/helm-s3/
+    install -m644 -Dt $out/helm-s3 plugin.yaml
+  '';
+
+  meta = with lib; {
+    description = "Helm plugin that allows to set up a chart repository using AWS S3";
+    homepage = "https://github.com/hypnoglow/helm-s3";
+    license = licenses.mit;
+    maintainers = with maintainers; [ yurrriq ];
+  };
+}

pkgs/applications/networking/cluster/helm/plugins/helm-schema.nix

@@ -0,0 +1,66 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "helm-schema";
+  version = "2.3.0";
+
+  src = fetchFromGitHub {
+    owner = "losisin";
+    repo = "helm-values-schema-json";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-q5A+tCnuHTtUyejP4flID7XhsoBfWGge2jCgsL0uEOc=";
+  };
+
+  vendorHash = "sha256-xmj2i1WNI/9ItbxRk8mPIygjq83xuvNu6THyPqZsysY=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X 'main.Version=v${finalAttrs.version}'"
+  ];
+
+  postPatch = ''
+    # Remove the install and upgrade hooks
+    sed -i '/^hooks:/,+2 d' plugin.yaml
+
+    substituteInPlace {plugin.yaml,plugin.complete} \
+      --replace-fail '$HELM_PLUGIN_DIR' '${placeholder "out"}/${finalAttrs.pname}/bin'
+  '';
+
+  postInstall = ''
+    install -D plugin.complete -t $out/helm-schema/
+    install -m644 plugin.yaml -t $out/helm-schema/
+    mv $out/bin/{helm-values-schema-json,schema}
+    mv $out/bin $out/helm-schema
+  '';
+
+  # Unit tests try to open web server on port 0
+  __darwinAllowLocalNetworking = true;
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgram = "${placeholder "out"}/helm-schema/bin/schema";
+  versionCheckProgramArg = "--version";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    mainProgram = "schema";
+    description = "Helm plugin for generating values.schema.json from multiple values files";
+    longDescription = ''
+      Helm plugin for generating `values.schema.json` from single or
+      multiple values files. Schema can be enriched by reading
+      annotations from comments. Works only with Helm3 charts.
+    '';
+    homepage = "https://github.com/losisin/helm-values-schema-json";
+    changelog = "https://github.com/losisin/helm-values-schema-json/releases/tag/v${finalAttrs.version}";
+    maintainers = with lib.maintainers; [ applejag ];
+    license = lib.licenses.mit;
+  };
+})

pkgs/applications/networking/cluster/helm/plugins/helm-secrets.nix

@@ -0,0 +1,67 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  makeWrapper,
+  coreutils,
+  findutils,
+  getopt,
+  gnugrep,
+  gnused,
+  sops,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "helm-secrets";
+  version = "4.6.10";
+
+  src = fetchFromGitHub {
+    owner = "jkroepke";
+    repo = "helm-secrets";
+    rev = "v${version}";
+    hash = "sha256-hno6+kik+U9XA7Mr9OnuuVidfc/xoqWRjMbBMI6M3QA=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [
+    getopt
+    sops
+  ];
+
+  # NOTE: helm-secrets is comprised of shell scripts.
+  dontBuild = true;
+
+  # NOTE: Fix version string
+  postPatch = ''
+    sed -i 's/^version:.*/version: "${version}"/' plugin.yaml
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -dm755 $out/helm-secrets $out/helm-secrets/scripts
+    install -m644 -Dt $out/helm-secrets plugin.yaml
+    cp -r scripts/* $out/helm-secrets/scripts
+    wrapProgram $out/helm-secrets/scripts/run.sh \
+        --prefix PATH : ${
+          lib.makeBinPath [
+            coreutils
+            findutils
+            getopt
+            gnugrep
+            gnused
+            sops
+          ]
+        }
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Helm plugin that helps manage secrets";
+    homepage = "https://github.com/jkroepke/helm-secrets";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ yurrriq ];
+    platforms = platforms.unix;
+  };
+}

pkgs/applications/networking/cluster/helm/plugins/helm-unittest.nix

@@ -0,0 +1,38 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+}:
+
+buildGoModule rec {
+  pname = "helm-unittest";
+  version = "0.7.2";
+
+  src = fetchFromGitHub {
+    owner = "helm-unittest";
+    repo = "helm-unittest";
+    rev = "v${version}";
+    hash = "sha256-RWucFZlyVYV5pHFGP7x5I+SILAJ9k12R7l5o7WKGS/c=";
+  };
+
+  vendorHash = "sha256-tTM9n/ahtAJoQt0fwf1jrSokWER+cOnpPX7NTNrhKc4=";
+
+  # NOTE: Remove the install and upgrade hooks.
+  postPatch = ''
+    sed -i '/^hooks:/,+2 d' plugin.yaml
+  '';
+
+  postInstall = ''
+    install -dm755 $out/helm-unittest
+    mv $out/bin/helm-unittest $out/helm-unittest/untt
+    rmdir $out/bin
+    install -m644 -Dt $out/helm-unittest plugin.yaml
+  '';
+
+  meta = with lib; {
+    description = "BDD styled unit test framework for Kubernetes Helm charts as a Helm plugin";
+    homepage = "https://github.com/helm-unittest/helm-unittest";
+    license = licenses.mit;
+    maintainers = with maintainers; [ yurrriq ];
+  };
+}