push sheeet

pkgs/applications/version-management/cgit/common.nix

@@ -0,0 +1,127 @@
+{
+  pname,
+  version,
+  src,
+  gitSrc,
+  buildInputs ? [ ],
+  homepage,
+  description,
+  maintainers,
+  passthru ? { },
+}:
+
+{
+  lib,
+  stdenv,
+  openssl,
+  zlib,
+  asciidoc,
+  libxml2,
+  libxslt,
+  docbook_xsl,
+  pkg-config,
+  coreutils,
+  gnused,
+  groff,
+  docutils,
+  gzip,
+  bzip2,
+  lzip,
+  xz,
+  zstd,
+  python3Packages,
+}:
+
+stdenv.mkDerivation {
+  inherit
+    pname
+    version
+    src
+    gitSrc
+    passthru
+    ;
+
+  separateDebugInfo = true;
+
+  nativeBuildInputs = [
+    pkg-config
+    asciidoc
+  ]
+  ++ (with python3Packages; [
+    python
+    wrapPython
+  ]);
+  buildInputs = buildInputs ++ [
+    openssl
+    zlib
+    libxml2
+    libxslt
+    docbook_xsl
+  ];
+  pythonPath = with python3Packages; [
+    pygments
+    markdown
+  ];
+
+  postPatch = ''
+    sed -e 's|"gzip"|"${gzip}/bin/gzip"|' \
+        -e 's|"bzip2"|"${bzip2.bin}/bin/bzip2"|' \
+        -e 's|"lzip"|"${lzip}/bin/lzip"|' \
+        -e 's|"xz"|"${xz.bin}/bin/xz"|' \
+        -e 's|"zstd"|"${zstd}/bin/zstd"|' \
+        -i ui-snapshot.c
+
+    substituteInPlace filters/html-converters/man2html \
+      --replace 'groff' '${groff}/bin/groff'
+
+    substituteInPlace filters/html-converters/rst2html \
+      --replace 'rst2html.py' '${docutils}/bin/rst2html.py'
+  '';
+
+  # Give cgit a git source tree and pass configuration parameters (as make
+  # variables).
+  preBuild = ''
+    mkdir -p git
+    tar --strip-components=1 -xf "$gitSrc" -C git
+  '';
+
+  makeFlags = [
+    "prefix=$(out)"
+    "CGIT_SCRIPT_PATH=$(out)/cgit/"
+    "CC=${stdenv.cc.targetPrefix}cc"
+    "AR=${stdenv.cc.targetPrefix}ar"
+  ];
+
+  # Install manpage.
+  postInstall = ''
+    # xmllint fails:
+    #make install-man
+
+    # bypassing xmllint works:
+    a2x --no-xmllint -f manpage cgitrc.5.txt
+    mkdir -p "$out/share/man/man5"
+    cp cgitrc.5 "$out/share/man/man5"
+
+    wrapPythonProgramsIn "$out/lib/cgit/filters" "$out $pythonPath"
+
+    for script in $out/lib/cgit/filters/*.sh $out/lib/cgit/filters/html-converters/txt2html; do
+      wrapProgram $script --prefix PATH : '${
+        lib.makeBinPath [
+          coreutils
+          gnused
+        ]
+      }'
+    done
+  '';
+
+  stripDebugList = [ "cgit" ];
+
+  enableParallelBuilding = true;
+
+  meta = {
+    inherit homepage description;
+    license = lib.licenses.gpl2;
+    platforms = lib.platforms.linux;
+    maintainers = maintainers ++ (with lib.maintainers; [ qyliss ]);
+  };
+}

pkgs/applications/version-management/cgit/default.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  fetchurl,
+  callPackage,
+  luajit,
+  nixosTests,
+}:
+
+callPackage (import ./common.nix rec {
+  pname = "cgit";
+  version = "1.2.3";
+
+  src = fetchurl {
+    url = "https://git.zx2c4.com/cgit/snapshot/${pname}-${version}.tar.xz";
+    sha256 = "193d990ym10qlslk0p8mjwp2j6rhqa7fq0y1iff65lvbyv914pss";
+  };
+
+  # cgit is tightly coupled with git and needs a git source tree to build.
+  # IMPORTANT: Remember to check which git version cgit needs on every version
+  # bump (look for "GIT_VER" in the top-level Makefile).
+  gitSrc = fetchurl {
+    url = "mirror://kernel/software/scm/git/git-2.25.1.tar.xz";
+    sha256 = "09lzwa183nblr6l8ib35g2xrjf9wm9yhk3szfvyzkwivdv69c9r2";
+  };
+
+  buildInputs = [ luajit ];
+
+  passthru.tests = { inherit (nixosTests) cgit; };
+
+  homepage = "https://git.zx2c4.com/cgit/about/";
+  description = "Web frontend for git repositories";
+  maintainers = with lib.maintainers; [ bjornfor ];
+}) { }

pkgs/applications/version-management/cgit/pink.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  fetchurl,
+  callPackage,
+}:
+
+callPackage (import ./common.nix rec {
+  pname = "cgit-pink";
+  version = "1.4.1";
+
+  src = fetchurl {
+    url = "https://git.causal.agency/cgit-pink/snapshot/cgit-pink-${version}.tar.gz";
+    sha256 = "1ma6j3r4ba5fhd47pc6xn5bmxaqr8ci2pvky9v100n1hh5n6q97i";
+  };
+
+  # cgit-pink is tightly coupled with git and needs a git source tree to build.
+  # IMPORTANT: Remember to check which git version cgit-pink needs on every
+  # version bump (look for "GIT_VER" in the top-level Makefile).
+  gitSrc = fetchurl {
+    url = "mirror://kernel/software/scm/git/git-2.36.1.tar.xz";
+    sha256 = "0w43a35mhc2qf2gjkxjlnkf2lq8g0snf34iy5gqx2678yq7llpa0";
+  };
+
+  homepage = "https://git.causal.agency/cgit-pink/about/";
+  description = "cgit fork aiming for better maintenance";
+  maintainers = with lib.maintainers; [ sternenseemann ];
+}) { }