push sheeet

pkgs/applications/window-managers/wayfire/default.nix

@@ -0,0 +1,101 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nixosTests,
+  cmake,
+  meson,
+  ninja,
+  pkg-config,
+  wf-config,
+  cairo,
+  doctest,
+  libGL,
+  libdrm,
+  libexecinfo,
+  libevdev,
+  libinput,
+  libjpeg,
+  libxkbcommon,
+  wayland,
+  wayland-protocols,
+  wayland-scanner,
+  wlroots,
+  pango,
+  nlohmann_json,
+  xorg,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wayfire";
+  version = "0.9.0";
+
+  src = fetchFromGitHub {
+    owner = "WayfireWM";
+    repo = "wayfire";
+    rev = "v${finalAttrs.version}";
+    fetchSubmodules = true;
+    hash = "sha256-xQZ4/UE66IISZQLl702OQXAAr8XmEsA4hJwB7aXua+E=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    wayland-scanner
+  ];
+
+  buildInputs = [
+    libGL
+    libdrm
+    libexecinfo
+    libevdev
+    libinput
+    libjpeg
+    libxkbcommon
+    wayland-protocols
+    xorg.xcbutilwm
+    nlohmann_json
+  ];
+
+  propagatedBuildInputs = [
+    wf-config
+    wlroots
+    wayland
+    cairo
+    pango
+  ];
+
+  nativeCheckInputs = [
+    cmake
+    doctest
+  ];
+
+  # CMake is just used for finding doctest.
+  dontUseCmakeConfigure = true;
+
+  doCheck = true;
+
+  mesonFlags = [
+    "--sysconfdir /etc"
+    "-Duse_system_wlroots=enabled"
+    "-Duse_system_wfconfig=enabled"
+    (lib.mesonEnable "wf-touch:tests" (stdenv.buildPlatform.canExecute stdenv.hostPlatform))
+  ];
+
+  passthru.providedSessions = [ "wayfire" ];
+
+  passthru.tests.mate = nixosTests.mate-wayland;
+
+  meta = {
+    homepage = "https://wayfire.org/";
+    description = "3D Wayland compositor";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      wucke13
+      wineee
+    ];
+    platforms = lib.platforms.unix;
+    mainProgram = "wayfire";
+  };
+})

pkgs/applications/window-managers/wayfire/focus-request.nix

@@ -0,0 +1,59 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitLab,
+  meson,
+  ninja,
+  pkg-config,
+  wayfire,
+  wf-config,
+  wayland,
+  pango,
+  libinput,
+  libxkbcommon,
+  librsvg,
+  libGL,
+  xcbutilwm,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "focus-request";
+  version = "0.8.0.2";
+
+  src = fetchFromGitLab {
+    owner = "wayfireplugins";
+    repo = "focus-request";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-kUYvLC28IPrvnMT/wKFRlOVkc2ohF3k0T/Qrm/zVkpE=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    wayfire
+    wf-config
+    wayland
+    pango
+    libinput
+    libxkbcommon
+    librsvg
+    libGL
+    xcbutilwm
+  ];
+
+  env = {
+    PKG_CONFIG_WAYFIRE_METADATADIR = "${placeholder "out"}/share/wayfire/metadata";
+  };
+
+  meta = {
+    homepage = "https://gitlab.com/wayfireplugins/focus-request";
+    description = "Wayfire plugin provides a mechanism to grant focus to views that make a focus self-request";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ wineee ];
+    inherit (wayfire.meta) platforms;
+  };
+})

pkgs/applications/window-managers/wayfire/plugins.nix

@@ -0,0 +1,24 @@
+{
+  config,
+  lib,
+  pkgs,
+}:
+
+lib.makeScope pkgs.newScope (
+  self:
+  let
+    inherit (self) callPackage;
+  in
+  {
+    focus-request = callPackage ./focus-request.nix { };
+    wayfire-plugins-extra = callPackage ./wayfire-plugins-extra.nix { };
+    wayfire-shadows = callPackage ./wayfire-shadows.nix { };
+    wcm = callPackage ./wcm.nix { };
+    wf-shell = callPackage ./wf-shell.nix { };
+    windecor = callPackage ./windecor.nix { };
+    wwp-switcher = callPackage ./wwp-switcher.nix { };
+  }
+)
+// lib.optionalAttrs config.allowAliases {
+  firedecor = throw "wayfirePlugins.firedecor has been removed as it is unmaintained and no longer used by mate-wayland-session."; # Added 2025-09-03
+}

pkgs/applications/window-managers/wayfire/wayfire-plugins-extra.nix

@@ -0,0 +1,66 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  wayfire,
+  wayland-scanner,
+  wf-config,
+  libevdev,
+  libinput,
+  libxkbcommon,
+  nlohmann_json,
+  xcbutilwm,
+  gtkmm3,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wayfire-plugins-extra";
+  version = "0.9.0";
+
+  src = fetchFromGitHub {
+    owner = "WayfireWM";
+    repo = "wayfire-plugins-extra";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-TukDomxqfrM45+C7azfO8jVaqk3E5irdphH8U5IYItg=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    wayland-scanner
+  ];
+
+  buildInputs = [
+    wayfire
+    wf-config
+    libevdev
+    libinput
+    libxkbcommon
+    nlohmann_json
+    xcbutilwm
+    gtkmm3
+  ];
+
+  mesonFlags = [
+    # plugins in submodule, packaged individually
+    (lib.mesonBool "enable_windecor" false)
+    (lib.mesonBool "enable_wayfire_shadows" false)
+    (lib.mesonBool "enable_focus_request" false)
+  ];
+
+  env = {
+    PKG_CONFIG_WAYFIRE_METADATADIR = "${placeholder "out"}/share/wayfire/metadata";
+  };
+
+  meta = {
+    homepage = "https://github.com/WayfireWM/wayfire-plugins-extra";
+    description = "Additional plugins for Wayfire";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ wineee ];
+    inherit (wayfire.meta) platforms;
+  };
+})

pkgs/applications/window-managers/wayfire/wayfire-shadows.nix

@@ -0,0 +1,54 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  unstableGitUpdater,
+  meson,
+  ninja,
+  pkg-config,
+  wayfire,
+  libxkbcommon,
+  libGL,
+  libinput,
+  xcbutilwm,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wayfire-shadows";
+  version = "0-unstable-2025-03-04";
+
+  src = fetchFromGitHub {
+    owner = "timgott";
+    repo = "wayfire-shadows";
+    rev = "8257a4f04670d8baf29e2d9cee0d78f978f0233f";
+    hash = "sha256-cRayvjbolVxWtr1PbLSjxtIpZogTJaoAMxPOcZ+zBT8=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    wayfire
+    libxkbcommon
+    libGL
+    libinput
+    xcbutilwm
+  ];
+
+  env = {
+    PKG_CONFIG_WAYFIRE_METADATADIR = "${placeholder "out"}/share/wayfire/metadata";
+  };
+
+  passthru.updateScript = unstableGitUpdater { };
+
+  meta = {
+    homepage = "https://github.com/timgott/wayfire-shadows";
+    description = "Wayfire plugin that adds window shadows";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ wineee ];
+    inherit (wayfire.meta) platforms;
+  };
+})

pkgs/applications/window-managers/wayfire/wcm.nix

@@ -0,0 +1,66 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  wrapGAppsHook3,
+  wayfire,
+  wf-shell,
+  wayland-scanner,
+  wayland-protocols,
+  gtk3,
+  gtkmm3,
+  libevdev,
+  libxml2,
+  libxkbcommon,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wcm";
+  version = "0.9.0";
+
+  src = fetchFromGitHub {
+    owner = "WayfireWM";
+    repo = "wcm";
+    rev = "v${finalAttrs.version}";
+    fetchSubmodules = true;
+    hash = "sha256-oaaEtyu/9XVhFTkmD7WjScMycpKf+M7oPyQatbY23Vo=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    wayland-scanner
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    wayfire
+    wf-shell
+    wayland-protocols
+    gtk3
+    gtkmm3
+    libevdev
+    libxml2
+    libxkbcommon
+  ];
+
+  mesonFlags = [
+    "-Denable_wdisplays=false"
+  ];
+
+  meta = {
+    homepage = "https://github.com/WayfireWM/wcm";
+    description = "Wayfire Config Manager";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      wucke13
+      wineee
+    ];
+    platforms = lib.platforms.unix;
+    mainProgram = "wcm";
+  };
+})

pkgs/applications/window-managers/wayfire/wf-config.nix

@@ -0,0 +1,68 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  cmake,
+  meson,
+  ninja,
+  pkg-config,
+  doctest,
+  glm,
+  libevdev,
+  libxml2,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wf-config";
+  version = "0.9.0";
+
+  src = fetchFromGitHub {
+    owner = "WayfireWM";
+    repo = "wf-config";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-5HejuluCTsRsnHuaMCTnCPkbFvT/IcLkfNGjnXnZjJ0=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    libevdev
+    libxml2
+  ];
+
+  propagatedBuildInputs = [
+    glm
+  ];
+
+  nativeCheckInputs = [
+    cmake
+  ];
+  checkInputs = [
+    doctest
+  ];
+  # CMake is just used for finding doctest.
+  dontUseCmakeConfigure = true;
+
+  strictDeps = true;
+
+  mesonFlags = [
+    (lib.mesonEnable "tests" (stdenv.buildPlatform.canExecute stdenv.hostPlatform))
+  ];
+
+  doCheck = true;
+
+  meta = {
+    homepage = "https://github.com/WayfireWM/wf-config";
+    description = "Library for managing configuration files, written for Wayfire";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      wucke13
+      wineee
+    ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/applications/window-managers/wayfire/wf-shell.nix

@@ -0,0 +1,57 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  wayland-scanner,
+  wayfire,
+  alsa-lib,
+  gtkmm3,
+  gtk-layer-shell,
+  pulseaudio,
+  libdbusmenu-gtk3,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wf-shell";
+  version = "0.10.0";
+
+  src = fetchFromGitHub {
+    owner = "WayfireWM";
+    repo = "wf-shell";
+    rev = "v${finalAttrs.version}";
+    fetchSubmodules = true;
+    hash = "sha256-PLTeFGecxVwU2LdwnDwiWB1OcbaZjJemMpT0pcCFf/w=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    wayland-scanner
+  ];
+
+  buildInputs = [
+    wayfire
+    alsa-lib
+    gtkmm3
+    gtk-layer-shell
+    pulseaudio
+    libdbusmenu-gtk3
+  ];
+
+  mesonFlags = [ "--sysconfdir /etc" ];
+
+  meta = {
+    homepage = "https://github.com/WayfireWM/wf-shell";
+    description = "GTK3-based panel for Wayfire";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      wucke13
+      wineee
+    ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/applications/window-managers/wayfire/windecor.nix

@@ -0,0 +1,58 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitLab,
+  meson,
+  ninja,
+  pkg-config,
+  wayfire,
+  eudev,
+  libinput,
+  libxkbcommon,
+  librsvg,
+  libGL,
+  xcbutilwm,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "windecor";
+  version = "0.8.0";
+
+  src = fetchFromGitLab {
+    owner = "wayfireplugins";
+    repo = "windecor";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-v0kGT+KrtfFJ/hp1Dr8izKVj6UHhuW6udHFjWt1y9TY=";
+  };
+
+  postPatch = ''
+    substituteInPlace meson.build \
+      --replace "wayfire.get_variable( pkgconfig: 'metadatadir' )" "join_paths(get_option('prefix'), 'share/wayfire/metadata')"
+  '';
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    wayfire
+    eudev
+    libinput
+    libxkbcommon
+    librsvg
+    libGL
+    xcbutilwm
+  ];
+
+  mesonFlags = [ "--sysconfdir=/etc" ];
+
+  meta = {
+    homepage = "https://gitlab.com/wayfireplugins/windecor";
+    description = "Window decoration plugin for wayfire";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ wineee ];
+    inherit (wayfire.meta) platforms;
+  };
+})

pkgs/applications/window-managers/wayfire/wrapper.nix

@@ -0,0 +1,39 @@
+{
+  symlinkJoin,
+  lib,
+  makeWrapper,
+  wayfire,
+  plugins ? [ ],
+}:
+
+symlinkJoin {
+  name = "wayfire-wrapped-${lib.getVersion wayfire}";
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  paths = [
+    wayfire
+  ]
+  ++ plugins;
+
+  postBuild = ''
+    for binary in $out/bin/*; do
+      wrapProgram $binary \
+        --prefix WAYFIRE_PLUGIN_PATH : $out/lib/wayfire \
+        --prefix WAYFIRE_PLUGIN_XML_PATH : $out/share/wayfire/metadata
+    done
+  '';
+
+  preferLocalBuild = true;
+
+  passthru = wayfire.passthru // {
+    unwrapped = wayfire;
+  };
+
+  meta = wayfire.meta // {
+    # To prevent builds on hydra
+    hydraPlatforms = [ ];
+    # prefer wrapper over the package
+    priority = (wayfire.meta.priority or lib.meta.defaultPriority) - 1;
+  };
+}

pkgs/applications/window-managers/wayfire/wwp-switcher.nix

@@ -0,0 +1,58 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  unstableGitUpdater,
+  meson,
+  ninja,
+  pkg-config,
+  wayfire,
+  libxkbcommon,
+  libGL,
+  libinput,
+  gtk3,
+  glibmm,
+  xcbutilwm,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wwp-switcher";
+  version = "0-unstable-2024-07-23";
+
+  src = fetchFromGitHub {
+    owner = "wb9688";
+    repo = "wwp-switcher";
+    rev = "d0cd97534a2a6355697efecb7bcf8f85f5dc4b5b";
+    hash = "sha256-cU8INUb+JXlSCM7cAOUBU7z7W0IM6pAGN0izGdFYntc=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    wayfire
+    libxkbcommon
+    libGL
+    libinput
+    gtk3
+    glibmm
+    xcbutilwm
+  ];
+
+  env = {
+    PKG_CONFIG_WAYFIRE_METADATADIR = "${placeholder "out"}/share/wayfire/metadata";
+  };
+
+  passthru.updateScript = unstableGitUpdater { };
+
+  meta = {
+    homepage = "https://github.com/wb9688/wwp-switcher";
+    description = "Plugin to switch active window";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ wineee ];
+    inherit (wayfire.meta) platforms;
+  };
+})