push sheeet

pkgs/build-support/dlang/builddubpackage/default.nix

@@ -0,0 +1,71 @@
+{
+  lib,
+  stdenv,
+  dub,
+  importDubLock,
+  dubSetupHook,
+  dubBuildHook,
+  dubCheckHook,
+  ldc,
+  removeReferencesTo,
+}:
+
+lib.extendMkDerivation {
+  constructDrv = stdenv.mkDerivation;
+
+  excludeDrvArgNames = [
+    "dubLock"
+    "compiler"
+  ];
+
+  extendDrvArgs =
+    finalAttrs:
+    {
+      # A lockfile generated by `dub-to-nix` from the source of the package.
+      # Can be either a path to the file, or an attrset already parsed with `lib.importJSON`.
+      dubLock,
+      compiler ? ldc,
+      ...
+    }@args:
+
+    {
+      dubDeps = importDubLock {
+        inherit (finalAttrs) pname version;
+        lock = dubLock;
+      };
+
+      strictDeps = args.strictDeps or true;
+
+      nativeBuildInputs = args.nativeBuildInputs or [ ] ++ [
+        dubSetupHook
+        (dubBuildHook.override { inherit dub; })
+        compiler
+        removeReferencesTo
+      ];
+
+      configurePhase = ''
+        runHook preConfigure
+        dubFlags+=("--compiler=${lib.getExe compiler}")
+        runHook postConfigure
+      '';
+
+      doCheck = args.doCheck or false;
+
+      nativeCheckInputs = [
+        (dubCheckHook.override { inherit dub; })
+      ];
+
+      preFixup = ''
+        ${args.preFixup or ""}
+
+        find "$out" -type f -exec remove-references-to -t ${compiler} '{}' +
+      '';
+
+      disallowedReferences = args.disallowedReferences or [ compiler ];
+
+      meta = {
+        platforms = dub.meta.platforms;
+      }
+      // args.meta or { };
+    };
+}

pkgs/build-support/dlang/builddubpackage/hooks/default.nix

@@ -0,0 +1,26 @@
+{ callPackage }:
+
+{
+  dubSetupHook = callPackage (
+    { makeSetupHook }:
+    makeSetupHook {
+      name = "dub-setup-hook";
+    } ./dub-setup-hook.sh
+  ) { };
+
+  dubBuildHook = callPackage (
+    { makeSetupHook, dub }:
+    makeSetupHook {
+      name = "dub-build-hook";
+      propagatedBuildInputs = [ dub ];
+    } ./dub-build-hook.sh
+  ) { };
+
+  dubCheckHook = callPackage (
+    { makeSetupHook, dub }:
+    makeSetupHook {
+      name = "dub-check-hook";
+      propagatedBuildInputs = [ dub ];
+    } ./dub-check-hook.sh
+  ) { };
+}

pkgs/build-support/dlang/builddubpackage/hooks/dub-build-hook.sh

@@ -0,0 +1,13 @@
+dubBuildHook() {
+    runHook preBuild
+    echo "Executing dubBuildHook"
+
+    dub build --skip-registry=all --build="${dubBuildType-"release"}" "${dubBuildFlags[@]}" "${dubFlags[@]}"
+
+    echo "Finished dubBuildHook"
+    runHook postBuild
+}
+
+if [[ -z "${dontDubBuild-}" && -z "${buildPhase-}" ]]; then
+    buildPhase=dubBuildHook
+fi

pkgs/build-support/dlang/builddubpackage/hooks/dub-check-hook.sh

@@ -0,0 +1,13 @@
+dubCheckHook() {
+    runHook preCheck
+    echo "Executing dubCheckHook"
+
+    dub test --skip-registry=all "${dubTestFlags[@]}" "${dubFlags[@]}"
+
+    echo "Finished dubCheckHook"
+    runHook postCheck
+}
+
+if [[ -z "${dontDubCheck-}" && -z "${checkPhase-}" ]]; then
+    checkPhase=dubCheckHook
+fi

pkgs/build-support/dlang/builddubpackage/hooks/dub-setup-hook.sh

@@ -0,0 +1,19 @@
+dubSetupHook() {
+    echo "Executing dubSetupHook"
+
+    if [ -z "${dubDeps-}" ]; then
+        echo "Error: 'dubDeps' must be set when using dubSetupHook."
+        exit 1
+    fi
+
+    export DUB_HOME="$NIX_BUILD_TOP"/.dub
+    echo "Configuring \$DUB_HOME ($DUB_HOME)"
+    cp -Tr "$dubDeps"/.dub "$NIX_BUILD_TOP"/.dub
+    chmod -R +w "$DUB_HOME"
+
+    echo "Finished dubSetupHook"
+}
+
+if [ -z "${dontDubSetup-}" ]; then
+    postPatchHooks+=(dubSetupHook)
+fi

pkgs/build-support/dlang/builddubpackage/import-dub-lock.nix

@@ -0,0 +1,81 @@
+{
+  lib,
+  runCommand,
+  linkFarm,
+  fetchurl,
+  fetchgit,
+  dub,
+}:
+
+{
+  pname,
+  version,
+  lock,
+}:
+
+let
+  makeDubDep =
+    {
+      pname,
+      version,
+      sha256,
+    }:
+    {
+      inherit pname version;
+      src = fetchurl {
+        name = "dub-${pname}-${version}.zip";
+        url = "mirror://dub/${pname}/${version}.zip";
+        inherit sha256;
+      };
+    };
+
+  makeGitDep =
+    {
+      pname,
+      version,
+      repository,
+      sha256,
+    }:
+    {
+      inherit pname version;
+      src = fetchgit {
+        url = repository;
+        rev = version;
+        inherit sha256;
+      };
+    };
+
+  lockJson = if lib.isPath lock then lib.importJSON lock else lock;
+  depsRaw = lib.mapAttrsToList (pname: args: { inherit pname; } // args) lockJson.dependencies;
+
+  dubDeps = map makeDubDep (lib.filter (args: !(args ? repository)) depsRaw);
+  gitDeps = map makeGitDep (lib.filter (args: args ? repository) depsRaw);
+
+  # a directory with multiple single element registries
+  # one big directory with all .zip files leads to version parsing errors
+  # when the name of a package is a prefix of the name of another package
+  dubRegistryBase = linkFarm "dub-registry-base" (
+    map (dep: {
+      name = "${dep.pname}/${dep.pname}-${dep.version}.zip";
+      path = dep.src;
+    }) dubDeps
+  );
+
+in
+runCommand "${pname}-${version}-dub-deps"
+  {
+    nativeBuildInputs = [ dub ];
+  }
+  ''
+    export DUB_HOME="$out/.dub"
+    mkdir -p "$DUB_HOME"
+    # register dub dependencies
+    ${lib.concatMapStringsSep "\n" (dep: ''
+      dub fetch ${dep.pname}@${dep.version} --cache=user --skip-registry=standard --registry=file://${dubRegistryBase}/${dep.pname}
+    '') dubDeps}
+    # register git dependencies
+    ${lib.concatMapStringsSep "\n" (dep: ''
+      mkdir -p "$DUB_HOME/packages/${dep.pname}/${dep.version}"
+      cp -r --no-preserve=all ${dep.src} "$DUB_HOME/packages/${dep.pname}/${dep.version}/${dep.pname}"
+    '') gitDeps}
+  ''