push sheeet

pkgs/build-support/fetchdebianpatch/default.nix

@@ -0,0 +1,24 @@
+{ lib, fetchpatch }:
+
+lib.makeOverridable (
+  {
+    pname,
+    version,
+    debianRevision ? null,
+    area ? "main",
+    patch,
+    name ? patch,
+    hash,
+  }:
+  let
+    inherit (lib.strings) hasPrefix substring;
+    prefix = substring 0 (if hasPrefix "lib" pname then 4 else 1) pname;
+    versionString = if debianRevision == null then version else "${version}-${debianRevision}";
+  in
+  fetchpatch {
+    inherit name hash;
+    url =
+      "https://sources.debian.org/data/${area}/${prefix}/"
+      + "${pname}/${versionString}/debian/patches/${patch}";
+  }
+)

pkgs/build-support/fetchdebianpatch/tests.nix

@@ -0,0 +1,19 @@
+{ testers, fetchDebianPatch, ... }:
+
+{
+  simple = testers.invalidateFetcherByDrvHash fetchDebianPatch {
+    pname = "pysimplesoap";
+    version = "1.16.2";
+    debianRevision = "5";
+    patch = "Add-quotes-to-SOAPAction-header-in-SoapClient.patch";
+    hash = "sha256-xA8Wnrpr31H8wy3zHSNfezFNjUJt1HbSXn3qUMzeKc0=";
+  };
+
+  libPackage = testers.invalidateFetcherByDrvHash fetchDebianPatch {
+    pname = "libfile-pid-perl";
+    version = "1.01";
+    debianRevision = "2";
+    patch = "missing-pidfile.patch";
+    hash = "sha256-VBsIYyCnjcZLYQ2Uq2MKPK3kF2wiMKvnq0m727DoavM=";
+  };
+}