push sheeet

pkgs/build-support/fetchfirefoxaddon/default.nix

@@ -0,0 +1,65 @@
+{
+  stdenv,
+  fetchurl,
+  jq,
+  strip-nondeterminism,
+  unzip,
+  writeScript,
+  zip,
+}:
+
+{
+  name,
+  url ? null,
+  sha1 ? "",
+  sha256 ? "",
+  sha512 ? "",
+  fixedExtid ? null,
+  hash ? "",
+  src ? "",
+}:
+
+let
+  extid = if fixedExtid == null then "nixos@${name}" else fixedExtid;
+  source =
+    if url == null then
+      src
+    else
+      fetchurl {
+        url = url;
+        inherit
+          sha1
+          sha256
+          sha512
+          hash
+          ;
+      };
+in
+stdenv.mkDerivation {
+  inherit name;
+
+  passthru = {
+    inherit extid;
+  };
+
+  builder = writeScript "xpibuilder" ''
+    echo "firefox addon $name into $out"
+
+    UUID="${extid}"
+    mkdir -p "$out/$UUID"
+    unzip -q ${source} -d "$out/$UUID"
+    NEW_MANIFEST=$(jq '. + {"applications": { "gecko": { "id": "${extid}" }}, "browser_specific_settings":{"gecko":{"id": "${extid}"}}}' "$out/$UUID/manifest.json")
+    echo "$NEW_MANIFEST" > "$out/$UUID/manifest.json"
+    cd "$out/$UUID"
+    zip -r -q -FS "$out/$UUID.xpi" *
+    strip-nondeterminism "$out/$UUID.xpi"
+    rm -r "$out/$UUID"
+  '';
+
+  nativeBuildInputs = [
+    jq
+    strip-nondeterminism
+    unzip
+    zip
+  ];
+}

pkgs/build-support/fetchfirefoxaddon/tests.nix

@@ -0,0 +1,26 @@
+{
+  testers,
+  fetchFirefoxAddon,
+  fetchurl,
+  ...
+}:
+
+{
+  simple = testers.invalidateFetcherByDrvHash fetchFirefoxAddon {
+    name = "image-search-options";
+    # Chosen because its only 147KB
+    url = "https://addons.mozilla.org/firefox/downloads/file/3059971/image_search_options-3.0.12-fx.xpi";
+    sha256 = "sha256-H73YWX/DKxvhEwKpWOo7orAQ7c/rQywpljeyxYxv0Gg=";
+  };
+  overridden-source =
+    let
+      image-search-options = fetchurl {
+        url = "https://addons.mozilla.org/firefox/downloads/file/3059971/image_search_options-3.0.12-fx.xpi";
+        sha256 = "sha256-H73YWX/DKxvhEwKpWOo7orAQ7c/rQywpljeyxYxv0Gg=";
+      };
+    in
+    testers.invalidateFetcherByDrvHash fetchFirefoxAddon {
+      name = "image-search-options";
+      src = image-search-options;
+    };
+}