push sheeet

pkgs/build-support/node/build-npm-package/default.nix

@@ -0,0 +1,110 @@
+{
+  lib,
+  stdenv,
+  fetchNpmDeps,
+  buildPackages,
+  nodejs,
+  cctools,
+}@topLevelArgs:
+
+lib.extendMkDerivation {
+  constructDrv = stdenv.mkDerivation;
+
+  extendDrvArgs =
+    finalAttrs:
+    {
+      name ? "${args.pname}-${args.version}",
+      src ? null,
+      srcs ? null,
+      sourceRoot ? null,
+      prePatch ? "",
+      patches ? [ ],
+      postPatch ? "",
+      patchFlags ? [ ],
+      nativeBuildInputs ? [ ],
+      buildInputs ? [ ],
+      # The output hash of the dependencies for this project.
+      # Can be calculated in advance with prefetch-npm-deps.
+      npmDepsHash ? "",
+      # Whether to force the usage of Git dependencies that have install scripts, but not a lockfile.
+      # Use with care.
+      forceGitDeps ? false,
+      # Whether to force allow an empty dependency cache.
+      # This can be enabled if there are truly no remote dependencies, but generally an empty cache indicates something is wrong.
+      forceEmptyCache ? false,
+      # Whether to make the cache writable prior to installing dependencies.
+      # Don't set this unless npm tries to write to the cache directory, as it can slow down the build.
+      makeCacheWritable ? false,
+      # The script to run to build the project.
+      npmBuildScript ? "build",
+      # Flags to pass to all npm commands.
+      npmFlags ? [ ],
+      # Flags to pass to `npm ci`.
+      npmInstallFlags ? [ ],
+      # Flags to pass to `npm rebuild`.
+      npmRebuildFlags ? [ ],
+      # Flags to pass to `npm run ${npmBuildScript}`.
+      npmBuildFlags ? [ ],
+      # Flags to pass to `npm pack`.
+      npmPackFlags ? [ ],
+      # Flags to pass to `npm prune`.
+      npmPruneFlags ? npmInstallFlags,
+      # Value for npm `--workspace` flag and directory in which the files to be installed are found.
+      npmWorkspace ? null,
+      nodejs ? topLevelArgs.nodejs,
+      npmDeps ? fetchNpmDeps {
+        inherit
+          forceGitDeps
+          forceEmptyCache
+          src
+          srcs
+          sourceRoot
+          prePatch
+          patches
+          postPatch
+          patchFlags
+          ;
+        name = "${name}-npm-deps";
+        hash = npmDepsHash;
+      },
+      # Custom npmConfigHook
+      npmConfigHook ? null,
+      # Custom npmBuildHook
+      npmBuildHook ? null,
+      # Custom npmInstallHook
+      npmInstallHook ? null,
+      ...
+    }@args:
+
+    let
+      # .override {} negates splicing, so we need to use buildPackages explicitly
+      npmHooks = buildPackages.npmHooks.override {
+        inherit nodejs;
+      };
+    in
+    {
+      inherit npmDeps npmBuildScript;
+
+      nativeBuildInputs =
+        nativeBuildInputs
+        ++ [
+          nodejs
+          # Prefer passed hooks
+          (if npmConfigHook != null then npmConfigHook else npmHooks.npmConfigHook)
+          (if npmBuildHook != null then npmBuildHook else npmHooks.npmBuildHook)
+          (if npmInstallHook != null then npmInstallHook else npmHooks.npmInstallHook)
+          nodejs.python
+        ]
+        ++ lib.optionals stdenv.hostPlatform.isDarwin [ cctools ];
+      buildInputs = buildInputs ++ [ nodejs ];
+
+      strictDeps = true;
+
+      # Stripping takes way too long with the amount of files required by a typical Node.js project.
+      dontStrip = args.dontStrip or true;
+
+      meta = (args.meta or { }) // {
+        platforms = args.meta.platforms or nodejs.meta.platforms;
+      };
+    };
+}

pkgs/build-support/node/build-npm-package/hooks/default.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  srcOnly,
+  stdenv,
+  makeSetupHook,
+  makeWrapper,
+  nodejs,
+  jq,
+  prefetch-npm-deps,
+  diffutils,
+  installShellFiles,
+  nodejsInstallManuals,
+  nodejsInstallExecutables,
+}:
+
+{
+  npmConfigHook = makeSetupHook {
+    name = "npm-config-hook";
+    substitutions = {
+      nodeSrc = srcOnly nodejs;
+      nodeGyp = "${nodejs}/lib/node_modules/npm/node_modules/node-gyp/bin/node-gyp.js";
+      npmArch = stdenv.targetPlatform.node.arch;
+      npmPlatform = stdenv.targetPlatform.node.platform;
+
+      # Specify `diff`, `jq`, and `prefetch-npm-deps` by abspath to ensure that the user's build
+      # inputs do not cause us to find the wrong binaries.
+      diff = "${diffutils}/bin/diff";
+      jq = "${jq}/bin/jq";
+      prefetchNpmDeps = "${prefetch-npm-deps}/bin/prefetch-npm-deps";
+
+      nodeVersion = nodejs.version;
+      nodeVersionMajor = lib.versions.major nodejs.version;
+    };
+  } ./npm-config-hook.sh;
+
+  npmBuildHook = makeSetupHook {
+    name = "npm-build-hook";
+  } ./npm-build-hook.sh;
+
+  npmInstallHook = makeSetupHook {
+    name = "npm-install-hook";
+    propagatedBuildInputs = [
+      installShellFiles
+      makeWrapper
+      nodejsInstallManuals
+      (nodejsInstallExecutables.override {
+        inherit nodejs;
+      })
+    ];
+    substitutions = {
+      jq = "${jq}/bin/jq";
+    };
+  } ./npm-install-hook.sh;
+}

pkgs/build-support/node/build-npm-package/hooks/npm-build-hook.sh

@@ -0,0 +1,38 @@
+# shellcheck shell=bash
+
+npmBuildHook() {
+    echo "Executing npmBuildHook"
+
+    runHook preBuild
+
+    if [ -z "${npmBuildScript-}" ]; then
+        echo
+        echo "ERROR: no build script was specified"
+        echo 'Hint: set `npmBuildScript`, override `buildPhase`, or set `dontNpmBuild = true`.'
+        echo
+
+        exit 1
+    fi
+
+    if ! npm run ${npmWorkspace+--workspace=$npmWorkspace} "$npmBuildScript" $npmBuildFlags "${npmBuildFlagsArray[@]}" $npmFlags "${npmFlagsArray[@]}"; then
+        echo
+        echo 'ERROR: `npm build` failed'
+        echo
+        echo "Here are a few things you can try, depending on the error:"
+        echo "1. Make sure your build script ($npmBuildScript) exists"
+        echo '  If there is none, set `dontNpmBuild = true`.'
+        echo '2. If the error being thrown is something similar to "error:0308010C:digital envelope routines::unsupported", add `NODE_OPTIONS = "--openssl-legacy-provider"` to your derivation'
+        echo "  See https://github.com/webpack/webpack/issues/14532 for more information."
+        echo
+
+        exit 1
+    fi
+
+    runHook postBuild
+
+    echo "Finished npmBuildHook"
+}
+
+if [ -z "${dontNpmBuild-}" ] && [ -z "${buildPhase-}" ]; then
+    buildPhase=npmBuildHook
+fi

pkgs/build-support/node/build-npm-package/hooks/npm-config-hook.sh

@@ -0,0 +1,123 @@
+# shellcheck shell=bash
+
+npmConfigHook() {
+    echo "Executing npmConfigHook"
+
+    # Use npm patches in the nodejs package
+    export NIX_NODEJS_BUILDNPMPACKAGE=1
+    export prefetchNpmDeps="@prefetchNpmDeps@"
+
+    if [ -n "${npmRoot-}" ]; then
+      pushd "$npmRoot"
+    fi
+
+    echo "Configuring npm"
+
+    export HOME="$TMPDIR"
+    export npm_config_nodedir="@nodeSrc@"
+    export npm_config_node_gyp="@nodeGyp@"
+    export npm_config_arch="@npmArch@"
+    export npm_config_platform="@npmPlatform@"
+
+    if [ -z "${npmDeps-}" ]; then
+        echo
+        echo "ERROR: no dependencies were specified"
+        echo 'Hint: set `npmDeps` if using these hooks individually. If this is happening with `buildNpmPackage`, please open an issue.'
+        echo
+
+        exit 1
+    fi
+
+    local -r cacheLockfile="$npmDeps/package-lock.json"
+    local -r srcLockfile="$PWD/package-lock.json"
+
+    echo "Validating consistency between $srcLockfile and $cacheLockfile"
+
+    if ! @diff@ "$srcLockfile" "$cacheLockfile"; then
+      # If the diff failed, first double-check that the file exists, so we can
+      # give a friendlier error msg.
+      if ! [ -e "$srcLockfile" ]; then
+        echo
+        echo "ERROR: Missing package-lock.json from src. Expected to find it at: $srcLockfile"
+        echo "Hint: You can copy a vendored package-lock.json file via postPatch."
+        echo
+
+        exit 1
+      fi
+
+      if ! [ -e "$cacheLockfile" ]; then
+        echo
+        echo "ERROR: Missing lockfile from cache. Expected to find it at: $cacheLockfile"
+        echo
+
+        exit 1
+      fi
+
+      echo
+      echo "ERROR: npmDepsHash is out of date"
+      echo
+      echo "The package-lock.json in src is not the same as the in $npmDeps."
+      echo
+      echo "To fix the issue:"
+      echo '1. Use `lib.fakeHash` as the npmDepsHash value'
+      echo "2. Build the derivation and wait for it to fail with a hash mismatch"
+      echo "3. Copy the 'got: sha256-' value back into the npmDepsHash field"
+      echo
+
+      exit 1
+    fi
+
+    export CACHE_MAP_PATH="$TMP/MEOW"
+    @prefetchNpmDeps@ --map-cache
+
+    @prefetchNpmDeps@ --fixup-lockfile "$srcLockfile"
+
+    local cachePath
+
+    if [ -z "${makeCacheWritable-}" ]; then
+        cachePath="$npmDeps"
+    else
+        echo "Making cache writable"
+        cp -r "$npmDeps" "$TMPDIR/cache"
+        chmod -R 700 "$TMPDIR/cache"
+        cachePath="$TMPDIR/cache"
+    fi
+
+    echo "Setting npm_config_cache to $cachePath"
+    # do not use npm config to avoid modifying .npmrc
+    export npm_config_cache="$cachePath"
+    export npm_config_offline="true"
+    export npm_config_progress="false"
+
+    echo "Installing dependencies"
+
+    if ! npm ci --ignore-scripts $npmInstallFlags "${npmInstallFlagsArray[@]}" $npmFlags "${npmFlagsArray[@]}"; then
+        echo
+        echo "ERROR: npm failed to install dependencies"
+        echo
+        echo "Here are a few things you can try, depending on the error:"
+        echo '1. Set `makeCacheWritable = true`'
+        echo "  Note that this won't help if npm is complaining about not being able to write to the logs directory -- look above that for the actual error."
+        echo '2. Set `npmFlags = [ "--legacy-peer-deps" ]`'
+        echo
+
+        exit 1
+    fi
+
+    patchShebangs node_modules
+
+    npm rebuild $npmRebuildFlags "${npmRebuildFlagsArray[@]}" $npmFlags "${npmFlagsArray[@]}"
+
+    patchShebangs node_modules
+
+    rm "$CACHE_MAP_PATH"
+    unset CACHE_MAP_PATH
+
+    if [ -n "${npmRoot-}" ]; then
+      popd
+    fi
+
+    echo "Finished npmConfigHook"
+}
+
+postPatchHooks+=(npmConfigHook)

pkgs/build-support/node/build-npm-package/hooks/npm-install-hook.sh

@@ -0,0 +1,49 @@
+# shellcheck shell=bash
+
+npmInstallHook() {
+    echo "Executing npmInstallHook"
+
+    runHook preInstall
+
+    local -r packageOut="$out/lib/node_modules/$(@jq@ --raw-output '.name' package.json)"
+
+    # `npm pack` writes to cache so temporarily override it
+    while IFS= read -r file; do
+        local dest="$packageOut/$(dirname "$file")"
+        mkdir -p "$dest"
+        cp "${npmWorkspace-.}/$file" "$dest"
+    done < <(@jq@ --raw-output '.[0].files | map(.path | select(. | startswith("node_modules/") | not)) | join("\n")' <<< "$(npm_config_cache="$HOME/.npm" npm pack --json --dry-run --loglevel=warn --no-foreground-scripts ${npmWorkspace+--workspace=$npmWorkspace} $npmPackFlags "${npmPackFlagsArray[@]}" $npmFlags "${npmFlagsArray[@]}")")
+
+    nodejsInstallExecutables "${npmWorkspace-.}/package.json"
+
+    nodejsInstallManuals "${npmWorkspace-.}/package.json"
+
+    local -r nodeModulesPath="$packageOut/node_modules"
+
+    if [ ! -d "$nodeModulesPath" ]; then
+        if [ -z "${dontNpmPrune-}" ]; then
+            if ! npm prune --omit=dev --no-save ${npmWorkspace+--workspace=$npmWorkspace} $npmPruneFlags "${npmPruneFlagsArray[@]}" $npmFlags "${npmFlagsArray[@]}"; then
+              echo
+              echo
+              echo "ERROR: npm prune step failed"
+              echo
+              echo 'If npm tried to download additional dependencies above, try setting `dontNpmPrune = true`.'
+              echo
+
+              exit 1
+            fi
+        fi
+
+        find node_modules -maxdepth 1 -type d -empty -delete
+
+        cp -r node_modules "$nodeModulesPath"
+    fi
+
+    runHook postInstall
+
+    echo "Finished npmInstallHook"
+}
+
+if [ -z "${dontNpmInstall-}" ] && [ -z "${installPhase-}" ]; then
+    installPhase=npmInstallHook
+fi