push sheeet

pkgs/build-support/testers/shellcheck/src/example.sh

@@ -0,0 +1,3 @@
+#!/usr/bin/env bash
+
+echo $@

pkgs/build-support/testers/shellcheck/tester.nix

@@ -0,0 +1,35 @@
+# Dependencies (callPackage)
+{
+  lib,
+  stdenvNoCC,
+  shellcheck,
+}:
+
+# testers.shellcheck function
+# Docs: doc/build-helpers/testers.chapter.md
+# Tests: ./tests.nix
+{
+  name ? null,
+  src,
+}:
+stdenvNoCC.mkDerivation {
+  __structuredAttrs = true;
+  strictDeps = true;
+  name =
+    if name == null then
+      lib.warn "testers.shellcheck: name will be required in a future release, defaulting to run-shellcheck" "run-shellcheck"
+    else
+      "shellcheck-${name}";
+  inherit src;
+  dontUnpack = true; # Unpack phase tries to extract an archive, which we don't want to do with source trees
+  nativeBuildInputs = [ shellcheck ];
+  doCheck = true;
+  dontConfigure = true;
+  dontBuild = true;
+  checkPhase = ''
+    find "$src" -type f -print0 | xargs -0 shellcheck --source-path="$src"
+  '';
+  installPhase = ''
+    touch "$out"
+  '';
+}

pkgs/build-support/testers/shellcheck/tests.nix

@@ -0,0 +1,36 @@
+# Run:
+#   nix-build -A tests.testers.shellcheck
+
+{
+  lib,
+  testers,
+}:
+lib.recurseIntoAttrs {
+  example-dir = testers.testBuildFailure' {
+    drv = testers.shellcheck {
+      name = "example-dir";
+      src = ./src;
+    };
+    expectedBuilderExitCode = 123;
+    expectedBuilderLogEntries = [
+      ''
+        echo $@
+             ^-- SC2068 (error): Double quote array expansions to avoid re-splitting elements.
+      ''
+    ];
+  };
+
+  example-file = testers.testBuildFailure' {
+    drv = testers.shellcheck {
+      name = "example-file";
+      src = ./src/example.sh;
+    };
+    expectedBuilderExitCode = 123;
+    expectedBuilderLogEntries = [
+      ''
+        echo $@
+             ^-- SC2068 (error): Double quote array expansions to avoid re-splitting elements.
+      ''
+    ];
+  };
+}