push sheeet

pkgs/build-support/testers/shfmt/default.nix

@@ -0,0 +1,29 @@
+{
+  lib,
+  shfmt,
+  stdenvNoCC,
+}:
+# See https://nixos.org/manual/nixpkgs/unstable/#tester-shfmt
+# or doc/build-helpers/testers.chapter.md
+{
+  name,
+  src,
+  indent ? 2,
+}:
+stdenvNoCC.mkDerivation (finalAttrs: {
+  __structuredAttrs = true;
+  strictDeps = true;
+  inherit src indent;
+  name = "shfmt-${name}";
+  dontUnpack = true; # Unpack phase tries to extract archive
+  nativeBuildInputs = [ shfmt ];
+  doCheck = true;
+  dontConfigure = true;
+  dontBuild = true;
+  checkPhase = ''
+    shfmt --diff --indent $indent --simplify "$src"
+  '';
+  installPhase = ''
+    touch "$out"
+  '';
+})

pkgs/build-support/testers/shfmt/src/indent2.sh

@@ -0,0 +1,3 @@
+hello() {
+  echo "hello"
+}

pkgs/build-support/testers/shfmt/tests.nix

@@ -0,0 +1,43 @@
+{ lib, testers }:
+lib.recurseIntoAttrs {
+  # Positive tests
+  indent2 = testers.shfmt {
+    name = "indent2";
+    indent = 2;
+    src = ./src/indent2.sh;
+  };
+  indent2Bin = testers.shfmt {
+    name = "indent2Bin";
+    indent = 2;
+    src = ./src;
+  };
+  # Negative tests
+  indent2With0 = testers.testBuildFailure' {
+    drv = testers.shfmt {
+      name = "indent2";
+      indent = 0;
+      src = ./src/indent2.sh;
+    };
+  };
+  indent2BinWith0 = testers.testBuildFailure' {
+    drv = testers.shfmt {
+      name = "indent2Bin";
+      indent = 0;
+      src = ./src;
+    };
+  };
+  indent2With4 = testers.testBuildFailure' {
+    drv = testers.shfmt {
+      name = "indent2";
+      indent = 4;
+      src = ./src/indent2.sh;
+    };
+  };
+  indent2BinWith4 = testers.testBuildFailure' {
+    drv = testers.shfmt {
+      name = "indent2Bin";
+      indent = 4;
+      src = ./src;
+    };
+  };
+}