push sheeet

pkgs/by-name/_3/_3270font/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchzip,
+}:
+
+stdenvNoCC.mkDerivation rec {
+  pname = "3270font";
+  version = "3.0.1";
+
+  src = fetchzip {
+    url = "https://github.com/rbanffy/3270font/releases/download/v${version}/3270_fonts_d916271.zip";
+    sha256 = "sha256-Zi6Lp5+sqfjIaHmnaaemaw3i+hXq9mqIsK/81lTkwfM=";
+    stripRoot = false;
+  };
+
+  dontPatch = true;
+  dontConfigure = true;
+  dontBuild = true;
+  doCheck = false;
+  dontFixup = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm644 -t $out/share/fonts/opentype/ *.otf
+    install -Dm644 -t $out/share/fonts/truetype/ *.ttf
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Monospaced font based on IBM 3270 terminals";
+    homepage = "https://github.com/rbanffy/3270font";
+    changelog = "https://github.com/rbanffy/3270font/blob/v${version}/CHANGELOG.md";
+    license = [
+      lib.licenses.bsd3
+      lib.licenses.ofl
+    ];
+    maintainers = [ ];
+    platforms = lib.platforms.all;
+  };
+}

pkgs/by-name/_3/_389-ds-base/package.nix

@@ -0,0 +1,164 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  autoconf,
+  automake,
+  cargo,
+  libtool,
+  pkg-config,
+  cracklib,
+  lmdb,
+  json_c,
+  linux-pam,
+  libevent,
+  libxcrypt,
+  nspr,
+  nss,
+  openldap,
+  withOpenldap ? true,
+  db,
+  withBdb ? true,
+  cyrus_sasl,
+  icu,
+  net-snmp,
+  withNetSnmp ? true,
+  krb5,
+  pcre2,
+  python3,
+  rustPlatform,
+  rustc,
+  openssl,
+  withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd,
+  systemd,
+  zlib,
+  rsync,
+  withCockpit ? true,
+  withAsan ? false,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "389-ds-base";
+  version = "3.1.3";
+
+  src = fetchFromGitHub {
+    owner = "389ds";
+    repo = "389-ds-base";
+    rev = "389-ds-base-${finalAttrs.version}";
+    hash = "sha256-hRTK9xBu8v8+SGa/3IB8Alh/aGUiRRn2LmYOvXy0Yd4=";
+  };
+
+  patches = [
+    (fetchpatch {
+      # https://github.com/389ds/389-ds-base/pull/6930
+      name = "389-ds-base-rustc-1_89.patch";
+      url = "https://github.com/389ds/389-ds-base/commit/1701419551c246e9dc21778b118220eeb2258125.patch";
+      hash = "sha256-trzY/fDH3rs66DWbWI+PY46tIC9ShuVqspMHqEEKZYA=";
+    })
+  ];
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit (finalAttrs) src;
+    sourceRoot = "${finalAttrs.src.name}/src";
+    name = "389-ds-base-${finalAttrs.version}";
+    hash = "sha256-pNzMQjeBpmzFg6oWCxhLDmKGUKIW6jGmZQWai5Yunjc=";
+  };
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+    libtool
+    pkg-config
+    python3
+    cargo
+    rustc
+  ]
+  ++ lib.optional withCockpit rsync;
+
+  buildInputs = [
+    cracklib
+    lmdb
+    json_c
+    linux-pam
+    libevent
+    libxcrypt
+    nspr
+    nss
+    cyrus_sasl
+    icu
+    krb5
+    pcre2
+    openssl
+    zlib
+  ]
+  ++ lib.optional withSystemd systemd
+  ++ lib.optional withOpenldap openldap
+  ++ lib.optional withBdb db
+  ++ lib.optional withNetSnmp net-snmp;
+
+  postPatch = ''
+    patchShebangs ./buildnum.py ./ldap/servers/slapd/mkDBErrStrs.py
+  '';
+
+  preConfigure = ''
+    ./autogen.sh --prefix="$out"
+  '';
+
+  preBuild = ''
+    ln -s ${finalAttrs.cargoDeps} ./vendor
+  '';
+
+  configureFlags = [
+    "--enable-rust-offline"
+    "--enable-autobind"
+  ]
+  ++ lib.optionals withSystemd [
+    "--with-systemd"
+    "--with-systemdsystemunitdir=${placeholder "out"}/etc/systemd/system"
+  ]
+  ++ lib.optionals withOpenldap [
+    "--with-openldap"
+  ]
+  ++ lib.optionals withBdb [
+    "--with-db-inc=${lib.getDev db}/include"
+    "--with-db-lib=${lib.getLib db}/lib"
+  ]
+  ++ lib.optionals withNetSnmp [
+    "--with-netsnmp-inc=${lib.getDev net-snmp}/include"
+    "--with-netsnmp-lib=${lib.getLib net-snmp}/lib"
+  ]
+  ++ lib.optionals (!withCockpit) [
+    "--disable-cockpit"
+  ]
+  ++ lib.optionals withAsan [
+    "--enable-asan"
+    "--enable-debug"
+  ];
+
+  enableParallelBuilding = true;
+  # Disable parallel builds as those lack some dependencies:
+  #   ld: cannot find -lslapd: No such file or directory
+  # https://hydra.nixos.org/log/h38bj77gav0r6jbi4bgzy1lfjq22k2wy-389-ds-base-2.3.1.drv
+  enableParallelInstalling = false;
+
+  doCheck = true;
+
+  installFlags = [
+    "sysconfdir=${placeholder "out"}/etc"
+    "localstatedir=${placeholder "TMPDIR"}"
+  ];
+
+  passthru.version = finalAttrs.version;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://www.port389.org/";
+    description = "Enterprise-class Open Source LDAP server for Linux";
+    license = lib.licenses.gpl3Plus;
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.ners ];
+  };
+})

pkgs/by-name/_3/_3cpio/package.nix

@@ -0,0 +1,35 @@
+{
+  fetchFromGitHub,
+  lib,
+  lz4,
+  lzop,
+  nix-update-script,
+  rustPlatform,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "3cpio";
+  version = "0.11.0";
+
+  src = fetchFromGitHub {
+    owner = "bdrung";
+    repo = "3cpio";
+    tag = version;
+    hash = "sha256-TZw9IixZxQ00uFZw6RtAY4zWV22zuuaP6dAB4vkXwaM=";
+  };
+
+  cargoHash = "sha256-2IT5zdgUvzeYt81iwYssR/xEp03Qz6+Ll5u02y+R3qo=";
+
+  # Tests attempt to access arbitrary filepaths
+  doCheck = false;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Manage initrd cpio archives";
+    homepage = "https://github.com/bdrung/3cpio";
+    license = lib.licenses.isc;
+    maintainers = [ lib.maintainers.jmbaur ];
+    mainProgram = "3cpio";
+  };
+}

pkgs/by-name/_3/_3mux/package.nix

@@ -0,0 +1,68 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  fetchpatch,
+  makeWrapper,
+}:
+
+buildGoModule rec {
+  pname = "3mux";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "aaronjanse";
+    repo = "3mux";
+    tag = "v${version}";
+    sha256 = "sha256-QT4QXTlJf2NfTqXE4GF759EoW6Ri12lxDyodyEFc+ag=";
+  };
+
+  patches = [
+    # Needed so that the subsequent patch applies.
+    (fetchpatch {
+      name = "use-shorter-uuids.patch";
+      url = "https://github.com/aaronjanse/3mux/commit/6dd36694586f96e3c82ef7db1a0e7917ceb05794.patch";
+      hash = "sha256-FnFupOIIQi66mvjshn3EQ6XRzC4cLx3vGTeTUM1HOwM=";
+    })
+    # Fix the build for Darwin when building with Go 1.18.
+    # https://github.com/aaronjanse/3mux/pull/127
+    (fetchpatch {
+      name = "darwin-go-1.18-fix.patch";
+      url = "https://github.com/aaronjanse/3mux/commit/f2c26c1037927896d6e9a17ea038f8260620fbd4.patch";
+      hash = "sha256-RC3p30r0PGUKrxo8uOLL02oyfLqLfhNjBYy6E+OQ2f0=";
+    })
+  ];
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  vendorHash = "sha256-KMcl6mj+cEgvdZMzBxUtGJsgwPdFuXrY3yjmkB3CS4o=";
+
+  # This is a package used for internally testing 3mux. It's meant for
+  # use by 3mux maintainers/contributors only.
+  excludedPackages = [ "fuzz" ];
+
+  # 3mux needs to have itself in the path so users can run `3mux detach`.
+  # This ensures that, while inside 3mux, the binary in the path is the
+  # same version as the 3mux hosting the session. This also allows users
+  # to use 3mux via `nix run nixpkgs#_3mux` (otherwise they'd get "command
+  # not found").
+  postInstall = ''
+    wrapProgram $out/bin/3mux --prefix PATH : $out/bin
+  '';
+
+  meta = {
+    description = "Terminal multiplexer inspired by i3";
+    mainProgram = "3mux";
+    longDescription = ''
+      Terminal multiplexer with out-of-the-box support for search,
+      mouse-controlled scrollback, and i3-like keybindings
+    '';
+    homepage = "https://github.com/aaronjanse/3mux";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      aaronjanse
+      Br1ght0ne
+    ];
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/_3/_3proxy/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nixosTests,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "3proxy";
+  version = "0.9.5";
+
+  src = fetchFromGitHub {
+    owner = "3proxy";
+    repo = "3proxy";
+    tag = version;
+    sha256 = "sha256-uy6flZ1a7o02pr5O0pgl9zCjh8mE9W5JxotJeBMB16A=";
+  };
+
+  # They use 'install -s', that calls the native strip instead of the cross.
+  # Don't strip binary on install, we strip it on fixup phase anyway.
+  postPatch = ''
+    substituteInPlace Makefile.Linux \
+      --replace "(INSTALL_BIN) -s" "(INSTALL_BIN)" \
+      --replace "/usr" ""
+  '';
+
+  makeFlags = [
+    "-f Makefile.Linux"
+    "INSTALL=install"
+    "DESTDIR=${placeholder "out"}"
+    "CC:=$(CC)"
+  ];
+
+  postInstall = ''
+    rm -fr $out/var
+  '';
+
+  # common.c:208:9: error: initialization of 'int (*)(struct pollfd *, unsigned int,  int)' from incompatible pointer type 'int (*)(struct pollfd *, nfds_t,  int)' {aka 'int (*)(struct pollfd *, long unsigned int,  int)'}
+  env.NIX_CFLAGS_COMPILE = "-Wno-error=incompatible-pointer-types";
+
+  passthru.tests = {
+    smoke-test = nixosTests._3proxy;
+  };
+
+  meta = {
+    description = "Tiny free proxy server";
+    homepage = "https://github.com/3proxy/3proxy";
+    license = lib.licenses.bsd2;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ misuzu ];
+  };
+}