push sheeet

pkgs/by-name/ab/ab-av1/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+  stdenv,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "ab-av1";
+  version = "0.10.1";
+
+  src = fetchFromGitHub {
+    owner = "alexheretic";
+    repo = "ab-av1";
+    tag = "v${version}";
+    hash = "sha256-uW5BXUNzk94bqSWQSaCiuSO8Angwt0eo4ZmvGRr/4S8=";
+  };
+
+  cargoHash = "sha256-oLmE+xkatgIDIu6mUJ49O9s6ULp0bvpWdBP8rEGb5yc=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd ab-av1 \
+      --bash <($out/bin/ab-av1 print-completions bash) \
+      --fish <($out/bin/ab-av1 print-completions fish) \
+      --zsh <($out/bin/ab-av1 print-completions zsh)
+  '';
+
+  meta = {
+    description = "AV1 re-encoding using ffmpeg, svt-av1 & vmaf";
+    homepage = "https://github.com/alexheretic/ab-av1";
+    changelog = "https://github.com/alexheretic/ab-av1/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = [ ];
+    mainProgram = "ab-av1";
+  };
+}

pkgs/by-name/ab/aba/package.nix

@@ -0,0 +1,59 @@
+{
+  fetchFromSourcehut,
+  just,
+  lib,
+  nix-update-script,
+  rustPlatform,
+  scdoc,
+}:
+let
+  version = "0.8.0";
+in
+rustPlatform.buildRustPackage {
+  pname = "aba";
+  inherit version;
+
+  src = fetchFromSourcehut {
+    owner = "~onemoresuza";
+    repo = "aba";
+    tag = version;
+    hash = "sha256-2zVQNchL4DFh2v2/kwupJTBSmXiKqlxzUMrP9TbfCMs=";
+  };
+
+  cargoHash = "sha256-U1f68DY+yV6Uxwk1Re0eSNCFWYrYKCN08hJAYcp4ksE=";
+
+  nativeBuildInputs = [
+    just
+    scdoc
+  ];
+
+  postPatch = ''
+    # Let only nix strip the binary by disabling cargo's `strip = true`, like
+    # buildRustPackage does when not using just's setup hooks.
+    sed -i '/strip[[:space:]]*=[[:space:]]*true/s/true/false/' ./Cargo.toml
+  '';
+
+  preBuild = ''
+    justFlagsArray+=(
+      PREFIX=${placeholder "out"}
+      MANIFEST_OPTS="--frozen --locked --profile=release"
+      INSTALL_OPTS="--no-track"
+    )
+  '';
+
+  # There are no tests
+  doCheck = false;
+  dontUseJustCheck = true;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Address book for aerc";
+    homepage = "https://sr.ht/~onemoresuza/aba/";
+    changelog = "https://git.sr.ht/~onemoresuza/aba/tree/main/item/CHANGELOG.md";
+    downloadPage = "https://git.sr.ht/~onemoresuza/aba/refs/${version}";
+    maintainers = with lib.maintainers; [ onemoresuza ];
+    license = lib.licenses.isc;
+    mainProgram = "aba";
+  };
+}

pkgs/by-name/ab/abaddon/package.nix

@@ -0,0 +1,98 @@
+{
+  lib,
+  fetchFromGitHub,
+  stdenv,
+  cmake,
+  copyDesktopItems,
+  makeDesktopItem,
+  makeWrapper,
+  pkg-config,
+  alsa-lib,
+  curl,
+  gtkmm3,
+  libhandy,
+  libopus,
+  libpulseaudio,
+  libsecret,
+  libsodium,
+  nlohmann_json,
+  pcre2,
+  spdlog,
+  sqlite,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "abaddon";
+  version = "0.2.2";
+
+  src = fetchFromGitHub {
+    owner = "uowuo";
+    repo = "abaddon";
+    tag = "v${version}";
+    hash = "sha256-48lR1rIWMwLaTv+nIdqmQ3mHOayrC1P5OQuUb+URYh0=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [
+    cmake
+    copyDesktopItems
+    makeWrapper
+    pkg-config
+  ];
+
+  buildInputs = [
+    curl
+    gtkmm3
+    libhandy
+    libopus
+    libsecret
+    libsodium
+    nlohmann_json
+    pcre2
+    spdlog
+    sqlite
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/abaddon
+    cp -r ../res/{css,res} $out/share/abaddon
+    mkdir $out/bin
+    cp abaddon $out/bin
+    wrapProgram $out/bin/abaddon \
+      --prefix LD_LIBRARY_PATH : "${
+        lib.makeLibraryPath [
+          alsa-lib
+          libpulseaudio
+        ]
+      }" \
+      --chdir $out/share/abaddon
+
+    runHook postInstall
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = pname;
+      exec = pname;
+      desktopName = "Abaddon";
+      genericName = meta.description;
+      startupWMClass = pname;
+      categories = [
+        "Network"
+        "InstantMessaging"
+      ];
+      mimeTypes = [ "x-scheme-handler/discord" ];
+    })
+  ];
+
+  meta = {
+    description = "Discord client reimplementation, written in C++";
+    mainProgram = "abaddon";
+    homepage = "https://github.com/uowuo/abaddon";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ genericnerdyusername ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/ab/abbaye-des-morts/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  SDL2,
+  SDL2_image,
+  SDL2_mixer,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "abbaye-des-morts";
+  version = "2.0.5";
+
+  src = fetchFromGitHub {
+    owner = "nevat";
+    repo = "abbayedesmorts-gpl";
+    tag = "v${finalAttrs.version}";
+    sha256 = "sha256-muJt1cml0nYdgl0v8cudpUXcdSntc49e6zICTCwzkks=";
+  };
+
+  buildInputs = [
+    SDL2
+    SDL2_image
+    SDL2_mixer
+  ];
+
+  makeFlags = [
+    "PREFIX=${placeholder "out"}"
+    "DESTDIR="
+  ]
+  ++ lib.optional stdenv.isDarwin "PLATFORM=mac";
+
+  # Even with PLATFORM=mac, the Makefile specifies some GCC-specific CFLAGS that
+  # are not supported by modern Clang on macOS
+  postPatch = lib.optionalString stdenv.isDarwin ''
+    substituteInPlace Makefile \
+      --replace-fail "-funswitch-loops" "" \
+      --replace-fail "-fgcse-after-reload" ""
+  '';
+
+  meta = {
+    homepage = "https://locomalito.com/abbaye_des_morts.php";
+    description = "Retro arcade video game";
+    mainProgram = "abbayev2";
+    license = lib.licenses.gpl3;
+    maintainers = with lib.maintainers; [ marius851000 ];
+  };
+})

pkgs/by-name/ab/abbreviate/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+}:
+
+buildGoModule rec {
+  pname = "abbreviate";
+  version = "1.6.0";
+
+  src = fetchFromGitHub {
+    owner = "dnnrly";
+    repo = "abbreviate";
+    tag = "v${version}";
+    hash = "sha256-foGg+o+BbPsfpph+XHIfyPaknQD1N1rcZW58kgZ5HYM=";
+  };
+
+  vendorHash = "sha256-9z3M3FEjllNpae+5EcLVkF1rAtOQzUQGebJeU7QsmTA=";
+
+  nativeBuildInputs = [
+    installShellFiles
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd abbreviate \
+      --bash <($out/bin/abbreviate completion bash) \
+      --fish <($out/bin/abbreviate completion fish) \
+      --zsh <($out/bin/abbreviate completion zsh)
+  '';
+
+  meta = {
+    description = "Shorten your strings using common abbreviations";
+    mainProgram = "abbreviate";
+    homepage = "https://github.com/dnnrly/abbreviate";
+    changelog = "https://github.com/dnnrly/abbreviate/releases/tag/${src.rev}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ figsoda ];
+  };
+}

pkgs/by-name/ab/abc-verifier/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  readline,
+  cmake,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "abc-verifier";
+  version = "unstable-2023-10-13";
+
+  src = fetchFromGitHub {
+    owner = "yosyshq";
+    repo = "abc";
+    rev = "896e5e7dedf9b9b1459fa019f1fa8aa8101fdf43";
+    hash = "sha256-ou+E2lvDEOxXRXNygE/TyVi7quqk+CJHRI+HDI0xljE=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [ readline ];
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 'abc' "$out/bin/abc"
+    runHook postInstall
+  '';
+
+  # needed by yosys
+  passthru.rev = finalAttrs.src.rev;
+
+  meta = {
+    description = "Tool for squential logic synthesis and formal verification";
+    homepage = "https://people.eecs.berkeley.edu/~alanmi/abc";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      thoughtpolice
+      Luflosi
+    ];
+    mainProgram = "abc";
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/ab/abcde/package.nix

@@ -0,0 +1,92 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  libcdio-paranoia,
+  cddiscid,
+  wget,
+  which,
+  vorbis-tools,
+  id3v2,
+  python3Packages,
+  lame,
+  flac,
+  glyr,
+  perlPackages,
+  makeWrapper,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "abcde";
+  version = "2.9.3";
+
+  src = fetchurl {
+    url = "https://abcde.einval.com/download/abcde-${finalAttrs.version}.tar.gz";
+    hash = "sha256-BGzQu6eN1LvcvPgv5iWGXGDfNaAFSC3hOmaZxaO4MSQ=";
+  };
+
+  # FIXME: This package does not support `distmp3', `eject', etc.
+
+  configurePhase = ''
+    runHook preConfigure
+
+    sed -i "s|^[[:blank:]]*prefix *=.*$|prefix = $out|g ;
+            s|^[[:blank:]]*etcdir *=.*$|etcdir = $out/etc|g ;
+            s|^[[:blank:]]*INSTALL *=.*$|INSTALL = install -c|g" \
+      "Makefile";
+
+    echo 'CDPARANOIA=${lib.getExe libcdio-paranoia}' >>abcde.conf
+    echo CDROMREADERSYNTAX=cdparanoia >>abcde.conf
+
+    substituteInPlace "abcde" \
+      --replace "/etc/abcde.conf" "$out/etc/abcde.conf"
+
+    runHook postConfigure
+  '';
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  buildInputs = with perlPackages; [
+    perl
+    MusicBrainz
+    MusicBrainzDiscID
+    IOSocketSSL
+  ];
+
+  installFlags = [ "sysconfdir=$(out)/etc" ];
+
+  postFixup = ''
+    for cmd in abcde cddb-tool abcde-musicbrainz-tool; do
+      wrapProgram "$out/bin/$cmd" \
+        --prefix PERL5LIB : "$PERL5LIB" \
+        --prefix PATH ":" ${
+          lib.makeBinPath [
+            "$out"
+            which
+            libcdio-paranoia
+            cddiscid
+            wget
+            vorbis-tools
+            id3v2
+            python3Packages.eyed3
+            lame
+            flac
+            glyr
+          ]
+        }
+    done
+  '';
+
+  meta = {
+    homepage = "http://abcde.einval.com/wiki/";
+    license = lib.licenses.gpl2Plus;
+    maintainers = [ ];
+    description = "Command-line audio CD ripper";
+    longDescription = ''
+      abcde is a front-end command-line utility (actually, a shell
+      script) that grabs tracks off a CD, encodes them to
+      Ogg/Vorbis, MP3, FLAC, Ogg/Speex and/or MPP/MP+ (Musepack)
+      format, and tags them, all in one go.
+    '';
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/ab/abcm2ps/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenv,
+  fetchfossil,
+  docutils,
+  pkg-config,
+  freetype,
+  pango,
+  testers,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "abcm2ps";
+  version = "8.14.17";
+
+  src = fetchfossil {
+    url = "https://chiselapp.com/user/moinejf/repository/abcm2ps";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-YA36wfj7owKu/KyWgCj6U8EJEh831cFtQj4/JtH6kVg=";
+  };
+
+  configureFlags = [
+    "--INSTALL=install"
+  ];
+
+  nativeBuildInputs = [
+    docutils
+    pkg-config
+  ];
+
+  buildInputs = [
+    freetype
+    pango
+  ];
+
+  passthru.tests = {
+    version = testers.testVersion {
+      package = finalAttrs.finalPackage;
+      command = "abcm2ps -V";
+    };
+  };
+
+  meta = {
+    homepage = "http://moinejf.free.fr/";
+    license = lib.licenses.lgpl3Plus;
+    description = "Command line program which converts ABC to music sheet in PostScript or SVG format";
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ dotlambda ];
+    mainProgram = "abcm2ps";
+  };
+})

pkgs/by-name/ab/abcmidi/package.nix

@@ -0,0 +1,26 @@
+{
+  fetchFromGitHub,
+  lib,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "abcmidi";
+  version = "2025.06.27";
+
+  src = fetchFromGitHub {
+    owner = "sshlien";
+    repo = "abcmidi";
+    tag = finalAttrs.version;
+    hash = "sha256-bOuMiFm4wP+AgCLbarhZMmtGcEzzVsqiwi8sBRj/jy8=";
+  };
+
+  meta = {
+    homepage = "https://abc.sourceforge.net/abcMIDI/";
+    downloadPage = "https://ifdo.ca/~seymour/runabc/top.html";
+    license = lib.licenses.gpl2Plus;
+    description = "Utilities for converting between abc and MIDI";
+    platforms = lib.platforms.unix;
+    maintainers = [ lib.maintainers.dotlambda ];
+  };
+})

pkgs/by-name/ab/abctl/package.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  stdenv,
+  nix-update-script,
+}:
+
+buildGoModule rec {
+  pname = "abctl";
+  version = "0.29.0";
+
+  src = fetchFromGitHub {
+    owner = "airbytehq";
+    repo = "abctl";
+    tag = "v${version}";
+    hash = "sha256-tb0KBATOitgFN49gJVrctxPKjrFY7w6AdBa2AN+scBU=";
+  };
+
+  checkFlags =
+    let
+      skippedTests = [
+        # network access
+        "TestManifestCmd"
+        "TestManifestCmd_Enterprise"
+        "TestManifestCmd_Nightly"
+        # docker
+        "TestValues_BadYaml"
+        "TestInvalidHostFlag_IpAddr"
+        "TestInvalidHostFlag_IpAddrWithPort"
+        "TestNewWithOptions_InitErr"
+      ];
+    in
+    [ "-skip=^${lib.concatStringsSep "$|^" skippedTests}$" ];
+
+  vendorHash = "sha256-ZJbZDfVB6gxToinuUNLsjBEB+7+OgC19Cc2Q8Ej7kfo=";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Airbyte's CLI for managing local Airbyte installations";
+    homepage = "https://airbyte.com/";
+    changelog = "https://github.com/airbytehq/abctl/releases/tag/v${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ xelden ];
+    mainProgram = "abctl";
+    broken = stdenv.hostPlatform.isDarwin;
+  };
+}

pkgs/by-name/ab/abduco/package.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  stdenv,
+  fetchpatch,
+  fetchzip,
+  writeText,
+  conf ? null,
+}:
+
+let
+  rev = "8c32909a159aaa9484c82b71f05b7a73321eb491";
+  defaultUserConfig = writeText "config.def.h" conf;
+in
+stdenv.mkDerivation {
+  pname = "abduco";
+  version = "0.6.0-unstable-2020-04-30";
+
+  src = fetchzip {
+    urls = [
+      "https://github.com/martanne/abduco/archive/${rev}.tar.gz"
+      "https://git.sr.ht/~martanne/abduco/archive/${rev}.tar.gz"
+    ];
+    hash = "sha256-o7SPK/G31cW/rrLwV3UJOTq6EBHl6AEE/GdeKGlHdyg=";
+  };
+
+  configureFlags = lib.optionals stdenv.hostPlatform.isDarwin [ "-D_DARWIN_C_SOURCE" ];
+
+  preBuild = lib.optionalString (conf != null) "cp ${defaultUserConfig} config.def.h";
+
+  installFlags = [ "install-completion" ];
+
+  patches = [
+    # https://github.com/martanne/abduco/pull/22
+    (fetchpatch {
+      name = "use-XDG-directory-scheme-by-default";
+      url = "https://github.com/martanne/abduco/commit/0e9a00312ac9777edcb169122144762e3611287b.patch";
+      hash = "sha256-4NkIflbRkUpS5XTM/fxBaELpvlZ4S5lecRa8jk0XC9g=";
+    })
+
+    # “fix bug where attaching to dead session won't give underlying exit code”
+    # https://github.com/martanne/abduco/pull/45
+    (fetchpatch {
+      name = "exit-code-when-attaching-to-dead-session";
+      url = "https://github.com/martanne/abduco/commit/972ca8ab949ee342569dbd66b47cc4a17b28247b.patch";
+      hash = "sha256-8hios0iKYDOmt6Bi5NNM9elTflGudnG2xgPF1pSkHI0=";
+    })
+
+    # “report pixel sizes to child processes that use ioctl(0, TIOCGWINSZ, ...)”
+    # used for kitty & other terminals that display images
+    # https://github.com/martanne/abduco/pull/62
+    (fetchpatch {
+      name = "report-pixel-sizes-to-child-processes";
+      url = "https://github.com/martanne/abduco/commit/a1e222308119b3251f00b42e1ddff74a385d4249.patch";
+      hash = "sha256-eiF0A4IqJrrvXxjBYtltuVNpxQDv/iQPO+K7Y8hWBGg=";
+    })
+  ];
+
+  meta = {
+    homepage = "http://brain-dump.org/projects/abduco";
+    license = lib.licenses.isc;
+    description = "Allows programs to be run independently from its controlling terminal";
+    maintainers = with lib.maintainers; [ pSub ];
+    platforms = lib.platforms.unix;
+    mainProgram = "abduco";
+  };
+}

pkgs/by-name/ab/abi-compliance-checker/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  ctags,
+  perl,
+  binutils,
+  abi-dumper,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "abi-compliance-checker";
+  version = "2.3";
+
+  src = fetchFromGitHub {
+    owner = "lvc";
+    repo = "abi-compliance-checker";
+    tag = version;
+    sha256 = "1f1f9j2nf9j83sfl2ljadch99v6ha8rq8xm7ax5akc05hjpyckij";
+  };
+
+  buildInputs = [
+    binutils
+    ctags
+    perl
+  ];
+  propagatedBuildInputs = [ abi-dumper ];
+
+  makeFlags = [ "prefix=$(out)" ];
+
+  meta = {
+    homepage = "https://lvc.github.io/abi-compliance-checker";
+    description = "Tool for checking backward API/ABI compatibility of a C/C++ library";
+    mainProgram = "abi-compliance-checker";
+    license = lib.licenses.lgpl21;
+    maintainers = with lib.maintainers; [ bhipple ];
+    platforms = lib.platforms.all;
+  };
+}

pkgs/by-name/ab/abi-dumper/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  ctags,
+  perl,
+  elfutils,
+  vtable-dumper,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "abi-dumper";
+  version = "1.4";
+
+  src = fetchFromGitHub {
+    owner = "lvc";
+    repo = "abi-dumper";
+    tag = version;
+    sha256 = "sha256-BefDMeKHx4MNU6SyX5UpQnwdI+zqap7zunsgdWG/2xc=";
+  };
+
+  patchPhase = ''
+    substituteInPlace abi-dumper.pl \
+      --replace eu-readelf ${elfutils}/bin/eu-readelf \
+      --replace vtable-dumper ${vtable-dumper}/bin/vtable-dumper \
+      --replace '"ctags"' '"${ctags}/bin/ctags"'
+  '';
+
+  buildInputs = [
+    elfutils
+    ctags
+    perl
+    vtable-dumper
+  ];
+
+  preBuild = "mkdir -p $out";
+  makeFlags = [ "prefix=$(out)" ];
+
+  meta = {
+    homepage = "https://github.com/lvc/abi-dumper";
+    description = "Dump ABI of an ELF object containing DWARF debug info";
+    mainProgram = "abi-dumper";
+    license = lib.licenses.lgpl21;
+    maintainers = with lib.maintainers; [ bhipple ];
+    platforms = lib.platforms.all;
+  };
+}

pkgs/by-name/ab/abiword/package.nix

@@ -0,0 +1,89 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  autoreconfHook,
+  autoconf-archive,
+  pkg-config,
+  gtk3,
+  fribidi,
+  libpng,
+  popt,
+  libgsf,
+  enchant,
+  wv,
+  librsvg,
+  bzip2,
+  libjpeg,
+  perl,
+  boost,
+  libxslt,
+  goffice,
+  wrapGAppsHook3,
+  gitUpdater,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "abiword";
+  version = "3.0.7";
+
+  src = fetchFromGitLab {
+    domain = "gitlab.gnome.org";
+    owner = "World";
+    repo = "AbiWord";
+    rev = "refs/tags/release-${version}";
+    hash = "sha256-dYbJ726Zuxs7+VTTCWHYQLsVZ/86hRUBQRac6toO4UI=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    autoconf-archive
+    pkg-config
+    wrapGAppsHook3
+    perl
+  ];
+
+  buildInputs = [
+    gtk3
+    librsvg
+    bzip2
+    fribidi
+    libpng
+    popt
+    libgsf
+    enchant
+    wv
+    libjpeg
+    boost
+    libxslt
+    goffice
+  ];
+
+  strictDeps = true;
+  enableParallelBuilding = true;
+
+  postPatch = ''
+    patchShebangs ./tools/cdump/xp/cdump.pl ./po/ui-backport.pl
+  '';
+
+  preAutoreconf = ''
+    ./autogen-common.sh
+  '';
+
+  passthru.updateScript = gitUpdater {
+    rev-prefix = "release-";
+  };
+
+  meta = {
+    description = "Word processing program, similar to Microsoft Word";
+    mainProgram = "abiword";
+    homepage = "https://gitlab.gnome.org/World/AbiWord/";
+    license = lib.licenses.gpl3;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [
+      pSub
+      ylwghst
+      sna
+    ];
+  };
+}

pkgs/by-name/ab/ablog/package.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  python3Packages,
+  fetchFromGitHub,
+  gitUpdater,
+}:
+
+let
+  version = "0.11.12";
+in
+python3Packages.buildPythonApplication {
+  pname = "ablog";
+  inherit version;
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "sunpy";
+    repo = "ablog";
+    tag = "v${version}";
+    hash = "sha256-bPTaxkuIKeypfnZItG9cl51flHBIx/yg0qENuiqQgY4=";
+  };
+
+  build-system = with python3Packages; [
+    setuptools
+    setuptools-scm
+    wheel
+  ];
+
+  dependencies = with python3Packages; [
+    docutils
+    feedgen
+    invoke
+    packaging
+    python-dateutil
+    sphinx
+    watchdog
+  ];
+
+  nativeCheckInputs = with python3Packages; [
+    pytestCheckHook
+    defusedxml
+  ];
+
+  pytestFlags = [
+    "--rootdir=src/ablog"
+    "-Wignore::sphinx.deprecation.RemovedInSphinx90Warning" # Ignore ImportError
+  ];
+
+  disabledTests = [
+    # upstream investigation is still ongoing
+    # https://github.com/sunpy/ablog/issues/302
+    "test_not_safe_for_parallel_read"
+    # need sphinx old version
+    "test_feed"
+  ];
+
+  passthru.updateScript = gitUpdater { rev-prefix = "v"; };
+
+  meta = {
+    description = "Sphinx extension that converts any documentation or personal website project into a full-fledged blog";
+    mainProgram = "ablog";
+    homepage = "https://ablog.readthedocs.io/en/latest/";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ rgrinberg ];
+  };
+}

pkgs/by-name/ab/abook/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchgit,
+  fetchpatch,
+  autoreconfHook,
+  pkg-config,
+  ncurses,
+  readline,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "abook";
+  version = "0.6.2";
+
+  src = fetchgit {
+    url = "https://git.code.sf.net/p/abook/git";
+    rev = "ver_${lib.replaceStrings [ "." ] [ "_" ] finalAttrs.version}";
+    hash = "sha256-aV57Ob6KN6/eNPrxxmNOy/qfhG687uVy5WY0cd4daCU=";
+  };
+
+  patches = [
+    (fetchpatch {
+      url = "https://aur.archlinux.org/cgit/aur.git/plain/abook-gcc15.patch?h=abook";
+      hash = "sha256-+73+USELoby8JvuVOWZe6E+xtdhajnLnDkzD/77QoTo=";
+    })
+  ];
+
+  # error: implicit declaration of function 'isalnum' [-Wimplicit-function-declaration]
+  # if (isalnum (*str)) *(p++) = *str;
+  postPatch = ''
+    substituteInPlace database.c \
+      --replace-fail '#include "xmalloc.h"' $'#include "xmalloc.h"\n#include <ctype.h>'
+  '';
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+  ];
+
+  buildInputs = [
+    ncurses
+    readline
+  ];
+
+  meta = {
+    homepage = "http://abook.sourceforge.net/";
+    description = "Text-based addressbook program designed to use with mutt mail client";
+    license = lib.licenses.gpl3Only;
+    maintainers = [ lib.maintainers.edwtjo ];
+    platforms = lib.platforms.unix;
+    mainProgram = "abook";
+  };
+})

pkgs/by-name/ab/abootimg/package.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  coreutils,
+  cpio,
+  findutils,
+  gzip,
+  makeWrapper,
+  util-linux,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "abootimg";
+  version = "0.6";
+
+  src = fetchFromGitHub {
+    owner = "ggrandou";
+    repo = "abootimg";
+    rev = "7e127fee6a3981f6b0a50ce9910267cd501e09d4";
+    sha256 = "1qgx9fxwhylgnixzkz2mzv2707f65qq7rar2rsqak536vhig1z9a";
+  };
+
+  strictDeps = true;
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [ util-linux ];
+
+  postPatch = ''
+    cat <<EOF > version.h
+    #define VERSION_STR "${version}"
+    EOF
+  '';
+
+  installPhase = ''
+    mkdir -p $out/bin
+    install -D -m 755 abootimg $out/bin
+    install -D -m444 ./debian/abootimg.1 $out/share/man/man1/abootimg.1;
+
+    install -D -m 755 abootimg-pack-initrd $out/bin
+    wrapProgram $out/bin/abootimg-pack-initrd --prefix PATH : ${
+      lib.makeBinPath [
+        coreutils
+        cpio
+        findutils
+        gzip
+      ]
+    }
+
+    install -D -m 755 abootimg-unpack-initrd $out/bin
+    wrapProgram $out/bin/abootimg-unpack-initrd --prefix PATH : ${
+      lib.makeBinPath [
+        cpio
+        gzip
+      ]
+    }
+  '';
+
+  meta = {
+    homepage = "https://github.com/ggrandou/abootimg";
+    description = "Manipulate Android Boot Images";
+    license = lib.licenses.gpl2;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ flokli ];
+  };
+}

pkgs/by-name/ab/above/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  python3,
+  fetchFromGitHub,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "above";
+  version = "2.8";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "casterbyte";
+    repo = "Above";
+    tag = "v${version}";
+    hash = "sha256-kG+eaTT72jmeC9R9IKwfd/+9oLAzHLJoKfFJhJDJzDM=";
+  };
+
+  build-system = with python3.pkgs; [ setuptools ];
+
+  dependencies = with python3.pkgs; [
+    colorama
+    scapy
+  ];
+
+  postFixup = ''
+    mv $out/bin/above.py $out/bin/$pname
+  '';
+
+  # Project has no tests
+  doCheck = false;
+
+  meta = {
+    description = "Invisible network protocol sniffer";
+    homepage = "https://github.com/casterbyte/Above";
+    changelog = "https://github.com/casterbyte/Above/releases/tag/${src.tag}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ fab ];
+    mainProgram = "above";
+  };
+}

pkgs/by-name/ab/abpoa/package.nix

@@ -0,0 +1,102 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  simde,
+  zlib,
+  enableSse4_1 ? stdenv.hostPlatform.sse4_1Support,
+  enableAvx ? stdenv.hostPlatform.avxSupport,
+  enablePython ? false,
+  python3Packages,
+  runCommand,
+  abpoa,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "${lib.optionalString enablePython "py"}abpoa";
+  version = "1.5.4";
+
+  src = fetchFromGitHub {
+    owner = "yangao07";
+    repo = "abPOA";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-E6XdiRULgJy9rf4NfXGBqUC+m0pMZKMsA5pHvCNNLJk=";
+  };
+
+  patches = [ ./simd-arch.patch ];
+
+  postPatch = ''
+    cp -r ${simde.src}/* include/simde
+    substituteInPlace Makefile \
+      --replace-fail "-march=native" ""
+  '';
+
+  nativeBuildInputs = lib.optionals enablePython (
+    with python3Packages;
+    [
+      cython_0
+      pypaBuildHook
+      pypaInstallHook
+      pythonImportsCheckHook
+      setuptools
+    ]
+  );
+
+  buildFlags = lib.optionals stdenv.hostPlatform.isx86_64 [
+    (
+      if enableAvx then
+        "avx2=1"
+      else if enableSse4_1 then
+        "sse41=1"
+      else
+        "sse2=1"
+    )
+  ];
+
+  env = lib.optionalAttrs enablePython (
+    if enableAvx then
+      { "AVX2" = 1; }
+    else if enableSse4_1 then
+      { "SSE41" = 1; }
+    else
+      { "SSE2" = 1; }
+  );
+
+  buildInputs = [ zlib ];
+
+  installPhase = lib.optionalString (!enablePython) ''
+    runHook preInstall
+
+    install -Dm755 ./bin/abpoa* $out/bin/abpoa
+
+    runHook postInstall
+  '';
+
+  pythonImportsCheck = [ "pyabpoa" ];
+
+  doInstallCheck = enablePython;
+
+  installCheckPhase = ''
+    runHook preInstallCheck
+
+    python python/example.py
+
+    runHook postInstallCheck
+  '';
+
+  passthru.tests = {
+    simple = runCommand "${finalAttrs.pname}-test" { } ''
+      ${lib.getExe abpoa} ${abpoa.src}/test_data/seq.fa > $out
+    '';
+  };
+
+  meta = {
+    description = "SIMD-based C library for fast partial order alignment using adaptive band";
+    homepage = "https://github.com/yangao07/abPOA";
+    changelog = "https://github.com/yangao07/abPOA/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ natsukium ];
+    mainProgram = "abpoa";
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/ab/abpoa/simd-arch.patch

@@ -0,0 +1,27 @@
+diff --git a/setup.py b/setup.py
+index c6fc019..49fb3c8 100644
+--- a/setup.py
++++ b/setup.py
+@@ -14,11 +14,12 @@ machine_arch = os.popen("uname -m").readlines()[0].rsplit()[0]
+ 
+ if machine_system == "Darwin":
+     # note: see https://github.com/pypa/wheel/issues/406
+-    simd_flag = ['-march=native', '-D__AVX2__', '-mmacosx-version-min=10.9']
+     if machine_arch in ["aarch64", "arm64"]:
++        simd_flag = ['-march=armv8-a+simd', '-D__AVX2__', '-mmacosx-version-min=10.9']
+         os.environ['_PYTHON_HOST_PLATFORM'] = "macosx-10.9-arm64"
+         os.environ['ARCHFLAGS'] = "-arch arm64"
+     else: # x86_64
++        simd_flag = ['-msse2', '-mmacosx-version-min=10.9']
+         os.environ['_PYTHON_HOST_PLATFORM'] = "macosx-10.9-x86_64"
+         os.environ['ARCHFLAGS'] = "-arch x86_64"
+ else:
+@@ -27,7 +28,7 @@ else:
+     elif machine_arch in ["aarch32"]:
+         simd_flag = ['-march=armv8-a+simd', '-mfpu=auto -D__AVX2__']
+     else: # x86_64
+-        simd_flag=['-march=native']
++        simd_flag=[]
+         if os.getenv('SSE4', False):
+             simd_flag=['-msse4.1']
+         elif os.getenv('SSE2', False):

pkgs/by-name/ab/abracadabra/package.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  qt6,
+  faad2,
+  mpg123,
+  portaudio,
+  libusb1,
+  rtl-sdr,
+  airspy,
+  soapysdr-with-plugins,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "abracadabra";
+  version = "3.3.1";
+
+  src = fetchFromGitHub {
+    owner = "KejPi";
+    repo = "AbracaDABra";
+    tag = "v${version}";
+    hash = "sha256-cx5Kq5V0XTUJdqEDI0iDICIygbYkGu8JwdCACNLMgtY=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    qt6.wrapQtAppsHook
+    qt6.qttools
+  ];
+
+  buildInputs = [
+    qt6.qtbase
+    qt6.qtmultimedia
+    qt6.qtlocation
+    qt6.qtpositioning
+    faad2
+    mpg123
+    portaudio
+    libusb1
+    rtl-sdr
+    airspy
+    soapysdr-with-plugins
+  ];
+
+  cmakeFlags = [
+    "-DAIRSPY=ON"
+    "-DSOAPYSDR=ON"
+  ];
+
+  meta = {
+    description = "DAB/DAB+ radio application";
+    homepage = "https://github.com/KejPi/AbracaDABra";
+    platforms = lib.platforms.linux;
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ markuskowa ];
+    mainProgram = "AbracaDABra";
+  };
+}

pkgs/by-name/ab/abseil-cpp/package.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  gtest,
+  static ? stdenv.hostPlatform.isStatic,
+  cxxStandard ? null,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "abseil-cpp";
+  version = "20250814.0";
+
+  src = fetchFromGitHub {
+    owner = "abseil";
+    repo = "abseil-cpp";
+    tag = finalAttrs.version;
+    hash = "sha256-6Ro7miql9+wcArsOKTjlyDSyD91rmmPsIfO5auk9kiI=";
+  };
+
+  cmakeFlags = [
+    (lib.cmakeBool "ABSL_BUILD_TEST_HELPERS" true)
+    (lib.cmakeBool "ABSL_USE_EXTERNAL_GOOGLETEST" true)
+    (lib.cmakeBool "BUILD_SHARED_LIBS" (!static))
+  ]
+  ++ lib.optionals (cxxStandard != null) [
+    (lib.cmakeFeature "CMAKE_CXX_STANDARD" cxxStandard)
+  ];
+
+  strictDeps = true;
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [ gtest ];
+
+  meta = {
+    description = "Open-source collection of C++ code designed to augment the C++ standard library";
+    homepage = "https://abseil.io/";
+    changelog = "https://github.com/abseil/abseil-cpp/releases/tag/${finalAttrs.version}";
+    license = lib.licenses.asl20;
+    platforms = lib.platforms.all;
+    maintainers = [ lib.maintainers.GaetanLepage ];
+  };
+})

pkgs/by-name/ab/abuild/package.nix

@@ -0,0 +1,96 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  gitUpdater,
+  makeWrapper,
+  pkg-config,
+  file,
+  scdoc,
+  openssl,
+  zlib,
+  busybox,
+  apk-tools,
+  perl,
+  findutils,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "abuild";
+  version = "3.15.0";
+
+  src = fetchFromGitLab {
+    domain = "gitlab.alpinelinux.org";
+    owner = "alpine";
+    repo = "abuild";
+    tag = finalAttrs.version;
+    hash = "sha256-vHRh36igfb6WZ8JdtxW8OOqgiVBAXreTy+QOOKaWEwA=";
+  };
+
+  buildInputs = [
+    openssl
+    zlib
+    busybox
+    # for $out/bin/apkbuild-cpan and $out/bin/apkbuild-pypi
+    (perl.withPackages (
+      ps: with ps; [
+        LWP
+        JSON
+        ModuleBuildTiny
+        LWPProtocolHttps
+        IPCSystemSimple
+      ]
+    ))
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    scdoc
+    makeWrapper
+    file
+    findutils
+  ];
+
+  patchPhase = ''
+    substituteInPlace ./Makefile \
+      --replace 'chmod 4555' '#chmod 4555' \
+      --replace 'pkg-config' "$PKG_CONFIG"
+  '';
+
+  makeFlags = [
+    "prefix=${placeholder "out"}"
+    "CFLAGS=-Wno-error"
+  ];
+
+  installFlags = [
+    "sysconfdir=${placeholder "out"}/etc"
+  ];
+
+  postInstall = ''
+    # this script requires unpackaged 'augeas' rubygem, no reason
+    # to ship it if we can't provide the dependencies for it
+    rm -f ${placeholder "out"}/bin/apkbuild-gem-resolver
+
+    # Find all executables that are not compiled binaries and wrap
+    # them, make `apk-tools` available in their PATH and also the
+    # $out directory since many of the binaries provided call into
+    # other binaries
+    for prog in \
+      $(find ${placeholder "out"}/bin -type f -exec ${file}/bin/file -i '{}' + \
+      | grep -v x-executable | cut -d : -f1); do
+      wrapProgram $prog \
+        --prefix PATH : "${lib.makeBinPath [ apk-tools ]}" \
+        --prefix PATH : "${placeholder "out"}/bin"
+    done
+  '';
+
+  passthru.updateScript = gitUpdater { };
+
+  meta = {
+    description = "Alpine Linux build tools";
+    homepage = "https://gitlab.alpinelinux.org/alpine/abuild";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ onny ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/ab/abuse/abuse.sh

@@ -0,0 +1,18 @@
+#! @shell@
+
+if grep datadir ~/.abuse/abuserc &>/dev/null; then
+  if [ ! -d "$(grep datadir ~/.abuse/abuserc | cut -d= -f2)" ]; then
+    echo "Warning: ~/.abuse/abuserc references a datadir which is not existent." >&2
+    echo "Try removing ~/.abuse/abuserc, else abuse will most likely not run." >&2
+    echo >&2
+    # This can happen if the build hash of abuse changes and the older version
+    # is garbage-collected. The correct path of the datadir is compiled into
+    # the binary, but unfortunately abuse writes out the path into abuserc on
+    # first start. This entry may later become stale.
+  fi
+fi
+
+# The timidity bundled into SDL_mixer looks in . and in several global places
+# like /etc for its configuration file.
+cd @out@/etc
+exec @out@/bin/.abuse-bin "$@"

pkgs/by-name/ab/abuse/package.nix

@@ -0,0 +1,87 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+  fetchFromGitHub,
+  makeDesktopItem,
+  copyDesktopItems,
+  cmake,
+  SDL2,
+  SDL2_mixer,
+  freepats,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "abuse";
+  version = "0.9.1";
+
+  src = fetchFromGitHub {
+    owner = "Xenoveritas";
+    repo = "abuse";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-eneu0HxEoM//Ju2XMHnDMZ/igeVMPSLg7IaxR2cnJrk=";
+  };
+
+  data = fetchzip {
+    url = "http://abuse.zoy.org/raw-attachment/wiki/download/abuse-0.8.tar.gz";
+    hash = "sha256-SOrtBNLWskN7Tqa0B3+KjlZlqPjC64Jp02Pk7to2hFg=";
+  };
+
+  preConfigure = ''
+    cp --reflink=auto -r ${finalAttrs.data}/data/sfx ${finalAttrs.data}/data/music data/
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "abuse";
+      exec = "abuse";
+      icon = "abuse";
+      desktopName = "Abuse";
+      comment = "Side-scroller action game that pits you against ruthless alien killers";
+      categories = [
+        "Game"
+        "ActionGame"
+      ];
+    })
+  ];
+
+  postInstall = ''
+    mkdir $out/etc
+    echo -e "dir ${freepats}\nsource ${freepats}/freepats.cfg" > $out/etc/timidity.cfg
+
+    mv $out/bin/abuse $out/bin/.abuse-bin
+    substituteAll "${./abuse.sh}" $out/bin/abuse
+    chmod +x $out/bin/abuse
+
+    install -Dm644 ${finalAttrs.data}/doc/abuse.png $out/share/pixmaps/abuse.png
+  '';
+
+  env.NIX_CFLAGS_COMPILE = "-I${lib.getDev SDL2}/include/SDL2";
+
+  cmakeFlags = [
+    (lib.cmakeFeature "CMAKE_POLICY_VERSION_MINIMUM" "3.10")
+  ];
+
+  nativeBuildInputs = [
+    copyDesktopItems
+    cmake
+  ];
+  buildInputs = [
+    SDL2
+    SDL2_mixer
+    freepats
+  ];
+
+  meta = {
+    description = "Side-scroller action game that pits you against ruthless alien killers";
+    homepage = "http://abuse.zoy.org/";
+    license = lib.licenses.unfree;
+    # Most of abuse is free (public domain, GPL2+, WTFPL), however the creator
+    # of its sfx and music only gave Debian permission to redistribute the
+    # files. Our friends from Debian thought about it some more:
+    # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=648272
+    maintainers = with lib.maintainers; [ iblech ];
+    platforms = lib.platforms.unix;
+    broken = stdenv.hostPlatform.isDarwin;
+  };
+})