push sheeet

pkgs/by-name/ax/ax25-apps/package.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  libax25,
+  ncurses,
+}:
+
+stdenv.mkDerivation {
+  pname = "ax25-apps";
+  version = "0.0.8-rc5-unstable-2021-05-13";
+
+  strictDeps = true;
+
+  nativeBuildInputs = [ autoreconfHook ];
+
+  buildInputs = [
+    libax25
+    ncurses
+  ];
+
+  # src from linux-ax25.in-berlin.de remote has been
+  # unreliable, pointing to github mirror from the radiocatalog
+  src = fetchFromGitHub {
+    owner = "radiocatalog";
+    repo = "ax25-apps";
+    rev = "afc4a5faa01a24c4da1d152b901066405f36adb6";
+    hash = "sha256-RLeFndis2OhIkJPLD+YfEUrJdZL33huVzlHq+kGq7dA=";
+  };
+
+  configureFlags = [
+    "--sysconfdir=/etc"
+    "--localstatedir=/var/lib"
+    "--program-transform-name=s@^call$@ax&@;s@^listen$@ax&@"
+  ];
+
+  meta = {
+    description = "AX.25 ham radio applications";
+    homepage = "https://linux-ax25.in-berlin.de/wiki/Main_Page";
+    license = lib.licenses.lgpl21Only;
+    maintainers = with lib.maintainers; [ sarcasticadmin ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/ax/ax25-tools/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  libax25,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "ax25-tools";
+  version = "0.0.10-rc5";
+
+  strictDeps = true;
+
+  nativeBuildInputs = [ autoreconfHook ];
+
+  buildInputs = [ libax25 ];
+
+  # src from linux-ax25.in-berlin.de remote has been
+  # unreliable, pointing to github mirror from the radiocatalog
+  src = fetchFromGitHub {
+    owner = "radiocatalog";
+    repo = "ax25-tools";
+    tag = "ax25-tools-${finalAttrs.version}";
+    hash = "sha256-yoFflC3KU3cKQEENj4MF793TvUdf38C2Q9B7nMuLgMg=";
+  };
+
+  configureFlags = [
+    "--sysconfdir=/etc"
+    "--localstatedir=/var/lib"
+  ];
+
+  meta = with lib; {
+    description = "Non-GUI tools used to configure an AX.25 enabled computer";
+    homepage = "https://linux-ax25.in-berlin.de/wiki/Main_Page";
+    license = licenses.lgpl21Only;
+    maintainers = with maintainers; [ sarcasticadmin ];
+    platforms = platforms.linux;
+  };
+})

pkgs/by-name/ax/ax25ms/package.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoconf,
+  protobuf,
+  pkg-config,
+  grpc,
+  libtool,
+  which,
+  automake,
+  libax25,
+}:
+
+stdenv.mkDerivation {
+  pname = "ax25ms";
+  version = "0-unstable-2024-04-28";
+
+  src = fetchFromGitHub {
+    owner = "ThomasHabets";
+    repo = "ax25ms";
+    rev = "c7d7213bb182e4b60f655c3f9f1bcb2b2440406b";
+    hash = "sha256-GljGJa44topJ6T0g5wuU8GTHLKzNmQqUl8/AR+pw2+I=";
+  };
+
+  buildInputs = [
+    protobuf
+    grpc
+    libax25
+  ];
+
+  nativeBuildInputs = [
+    which
+    pkg-config
+    autoconf
+    libtool
+    automake
+  ];
+
+  preConfigure = ''
+    patchShebangs scripts
+    ./bootstrap.sh
+  '';
+
+  postInstall = ''
+    set +e
+    for binary_path in "$out/bin"/*; do
+      filename=$(basename "$binary_path")
+      mv "$binary_path" "$out/bin/ax25ms-$filename"
+    done
+    set -e
+  '';
+
+  meta = with lib; {
+    description = "Set of AX.25 microservices, designed to be pluggable for any implementation";
+    homepage = "https://github.com/ThomasHabets/ax25ms";
+    license = licenses.asl20;
+    maintainers = with maintainers; [
+      matthewcroughan
+      sarcasticadmin
+      pkharvey
+    ];
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/ax/axis2/package.nix

@@ -0,0 +1,57 @@
+{
+  lib,
+  stdenvNoCC,
+  ant,
+  fetchurl,
+  jdk,
+  nixosTests,
+  stripJavaArchivesHook,
+  unzip,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "axis2";
+  version = "1.8.2";
+
+  src = fetchurl {
+    url = "mirror://apache/axis/axis2/java/core/${finalAttrs.version}/axis2-${finalAttrs.version}-bin.zip";
+    hash = "sha256-oilPVFFpl3F61nVDxcYx/bc81FopS5fzoIdXzeP8brk=";
+  };
+
+  nativeBuildInputs = [
+    ant
+    jdk
+    stripJavaArchivesHook
+    unzip
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+    ant -f webapp
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm644 lib/* -t $out/lib
+    install -Dm644 dist/axis2.war -t $out/webapps
+    unzip $out/webapps/axis2.war -d $out/webapps/axis2
+
+    runHook postInstall
+  '';
+
+  passthru.tests = {
+    inherit (nixosTests) tomcat;
+  };
+
+  meta = {
+    description = "Web Services / SOAP / WSDL engine, the successor to the widely used Apache Axis SOAP stack";
+    homepage = "https://axis.apache.org/axis2/java/core/";
+    changelog = "https://axis.apache.org/axis2/java/core/release-notes/${finalAttrs.version}.html";
+    maintainers = [ lib.maintainers.anthonyroussel ];
+    platforms = lib.platforms.unix;
+    sourceProvenance = with lib.sourceTypes; [ binaryBytecode ];
+    license = lib.licenses.asl20;
+  };
+})