push sheeet

pkgs/by-name/bd/bdf2psf/package.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  perl,
+  dpkg,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bdf2psf";
+  version = "1.240";
+
+  src = fetchurl {
+    url = "mirror://debian/pool/main/c/console-setup/bdf2psf_${version}_all.deb";
+    sha256 = "sha256-TFCTCoWyEUzFQTSObk5SavBH1bTHQaGc5E/z6mtY5yU=";
+  };
+
+  nativeBuildInputs = [ dpkg ];
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+    substituteInPlace usr/bin/bdf2psf --replace /usr/bin/perl "${perl}/bin/perl"
+    rm usr/share/doc/bdf2psf/changelog.gz
+    mv usr "$out"
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "BDF to PSF converter";
+    homepage = "https://packages.debian.org/sid/bdf2psf";
+    longDescription = ''
+      Font converter to generate console fonts from BDF source fonts
+    '';
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ rnhmjoj ];
+    platforms = platforms.all;
+    mainProgram = "bdf2psf";
+  };
+}

pkgs/by-name/bd/bdf2sfd/package.nix

@@ -0,0 +1,29 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bdf2sfd";
+  version = "1.1.9";
+
+  src = fetchFromGitHub {
+    owner = "fcambus";
+    repo = "bdf2sfd";
+    tag = version;
+    sha256 = "sha256-L1fIPZdVP4px73VbnEA6sb28WrmsNUJ2tqLeGPpwDbA=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  meta = with lib; {
+    description = "BDF to SFD converter";
+    homepage = "https://github.com/fcambus/bdf2sfd";
+    license = licenses.bsd2;
+    platforms = platforms.all;
+    maintainers = [ ];
+    mainProgram = "bdf2sfd";
+  };
+}

pkgs/by-name/bd/bdf2ttf/package.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+}:
+
+stdenv.mkDerivation {
+  pname = "bdf2ttf";
+  version = "2.0-unstable-2016-07-03";
+
+  src = fetchFromGitHub {
+    owner = "koron";
+    repo = "bdf2ttf";
+    rev = "1baae7b70a432153e3d876966e47a78f0e572eac";
+    hash = "sha256-235BTcTaC/30yLlgo0OO2cp3YCHWa87GFJGBx5lmz6o=";
+  };
+
+  dontConfigure = true;
+
+  makeFlags = [ "gcc" ];
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 bdf2ttf $out/bin/bdf2ttf
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Convert BDF font file to TTF (embed bitmap as is, not convert to vector)";
+    homepage = "https://github.com/koron/bdf2ttf";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ ners ];
+    platforms = lib.platforms.all;
+    broken = stdenv.hostPlatform.isDarwin;
+  };
+}

pkgs/by-name/bd/bdfresize/fix-configure.patch

@@ -0,0 +1,11 @@
+--- a/configure
++++ b/configure
+@@ -904,7 +904,7 @@
+ #line 905 "configure"
+ #include "confdefs.h"
+
+-main(){return(0);}
++int main(){return(0);}
+ EOF
+ if { (eval echo configure:910: \"$ac_link\") 1>&5; (eval $ac_link) 2>&5; } && test -s conftest${ac_exeext}; then
+   ac_cv_prog_cc_works=yes

pkgs/by-name/bd/bdfresize/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bdfresize";
+  version = "1.5";
+
+  src = fetchzip {
+    url = "http://openlab.ring.gr.jp/efont/dist/tools/bdfresize/bdfresize-${version}.tar.gz";
+    hash = "sha256-C4ZLJIn6vVeVUCpNwMu0vdfQQ3qUz4EVIcPob9NejP0=";
+  };
+
+  patches = [
+    ./fix-configure.patch
+    ./remove-malloc-declaration.patch
+  ];
+
+  # Fix compilation of getopt; see getopt package for more details
+  env.NIX_CFLAGS_COMPILE = "-D__GNU_LIBRARY__";
+
+  meta = with lib; {
+    description = "Tool to resize BDF fonts";
+    homepage = "http://openlab.ring.gr.jp/efont/dist/tools/bdfresize/";
+    license = licenses.gpl2Only;
+    maintainers = with maintainers; [ malte-v ];
+    mainProgram = "bdfresize";
+  };
+}

pkgs/by-name/bd/bdfresize/remove-malloc-declaration.patch

@@ -0,0 +1,11 @@
+Remove an unneeded declaration of malloc so gcc doesn't complain.
+--- a/charresize.c
++++ b/charresize.c
+@@ -46,7 +46,6 @@ static int	bit[8] = { 0x80, 0x40, 0x20, 0x10, 0x08, 0x04, 0x02, 0x01 };
+ void
+ processChar(void)
+ {
+-  char	*malloc();
+   char	*srcimage;
+   int	*dstgray;
+ 

pkgs/by-name/bd/bdftopcf/package.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  xorgproto,
+  writeScript,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "bdftopcf";
+  version = "1.1.2";
+
+  src = fetchurl {
+    url = "mirror://xorg/individual/util/bdftopcf-${finalAttrs.version}.tar.xz";
+    hash = "sha256-vGC+WQQzD6qj3dKu14dL7i8p5Dh8JF1nh1UvBn6wUjo=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ xorgproto ];
+
+  passthru = {
+    updateScript = writeScript "update-${finalAttrs.pname}" ''
+      #!/usr/bin/env nix-shell
+      #!nix-shell -i bash -p common-updater-scripts
+      version="$(list-directory-versions --pname ${finalAttrs.pname} \
+        --url https://xorg.freedesktop.org/releases/individual/util/ \
+        | sort -V | tail -n1)"
+      update-source-version ${finalAttrs.pname} "$version"
+    '';
+  };
+
+  meta = {
+    description = "Converts X font from Bitmap Distribution Format to Portable Compiled Format";
+    homepage = "https://gitlab.freedesktop.org/xorg/util/bdftopcf";
+    license = lib.licenses.mitOpenGroup;
+    mainProgram = "bdftopcf";
+    maintainers = [ ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/bd/bdsync/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  openssl,
+  pandoc,
+  which,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bdsync";
+  version = "0.11.4";
+
+  src = fetchFromGitHub {
+    owner = "rolffokkens";
+    repo = "bdsync";
+    rev = "v${version}";
+    sha256 = "sha256-uvP26gdyIPC+IHxO5CYVuabfT4mnoWDOyaLTplYCW0I=";
+  };
+
+  nativeBuildInputs = [
+    pandoc
+    which
+  ];
+  buildInputs = [ openssl ];
+
+  postPatch = ''
+    patchShebangs ./tests.sh
+    patchShebangs ./tests/
+  '';
+
+  doCheck = true;
+
+  installPhase = ''
+    install -Dm755 bdsync -t $out/bin/
+    install -Dm644 bdsync.1 -t $out/share/man/man1/
+  '';
+
+  meta = with lib; {
+    description = "Fast block device synchronizing tool";
+    homepage = "https://github.com/rolffokkens/bdsync";
+    license = licenses.gpl2Only;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ jluttine ];
+    mainProgram = "bdsync";
+  };
+}

pkgs/by-name/bd/bdt/package.nix

@@ -0,0 +1,26 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+}:
+rustPlatform.buildRustPackage {
+  pname = "bdt";
+  version = "0.18.0";
+
+  src = fetchFromGitHub {
+    owner = "datafusion-contrib";
+    repo = "bdt";
+    rev = "5c6730a8e3cd43c7847aef76b499197730cded58";
+    hash = "sha256-gUKsJwbpMPSO+KPqyJRodrRLjUpTh/y6C2xhrgvJFKk=";
+  };
+
+  cargoHash = "sha256-TikWh0U56x3HKca5Dj68Z59mOgedv+K5r+y7/CcpWa8=";
+
+  meta = with lib; {
+    description = "CLI tool to query parquet, json and avro files";
+    homepage = "https://github.com/datafusion-contrib/bdt";
+    license = licenses.asl20;
+    mainProgram = "bdt";
+    maintainers = with maintainers; [ matthiasq ];
+  };
+}