push sheeet

pkgs/by-name/bf/bfetch/package.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  bash,
+}:
+
+stdenvNoCC.mkDerivation {
+  pname = "bfetch";
+  version = "unstable-2021-05-21";
+
+  src = fetchFromGitHub {
+    owner = "NNBnh";
+    repo = "bfetch";
+    rev = "ef88e9d3f815e5074efc8ef4b7f32be6818130f2";
+    sha256 = "sha256-jS9zI8b+z3KbI+LeHFwIMJfEmAKSzO8HRZ2rk35hJCk=";
+  };
+
+  buildInputs = [ bash ];
+
+  postPatch = ''
+    patchShebangs --host bin/bfetch
+  '';
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "SuperB general-purpose fetch displayer written in portable sh";
+    homepage = "https://github.com/NNBnh/bfetch";
+    license = licenses.gpl3Only;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ moni ];
+    mainProgram = "bfetch";
+  };
+}

pkgs/by-name/bf/bfg-repo-cleaner/package.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  jre,
+  makeWrapper,
+  versionCheckHook,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bfg-repo-cleaner";
+  version = "1.15.0";
+
+  jarName = "bfg-${version}.jar";
+
+  src = fetchurl {
+    url = "mirror://maven/com/madgag/bfg/${version}/${jarName}";
+    hash = "sha256-3+KIWtwpFjeQk/AqgBgSAFNoVsmph78hxJLkUq3v73o=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [ jre ];
+
+  dontUnpack = true;
+
+  installPhase = ''
+    mkdir -p $out/share/java
+    mkdir -p $out/bin
+    cp $src $out/share/java/$jarName
+    makeWrapper "${jre}/bin/java" $out/bin/bfg --add-flags "-cp $out/share/java/$jarName com.madgag.git.bfg.cli.Main"
+  '';
+
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+  doInstallCheck = true;
+  versionCheckProgram = "${placeholder "out"}/bin/${meta.mainProgram}";
+  versionCheckProgramArg = "--version";
+
+  meta = with lib; {
+    homepage = "https://rtyley.github.io/bfg-repo-cleaner/";
+    # Descriptions taken with minor modification from the homepage of bfg-repo-cleaner
+    description = "Removes large or troublesome blobs in a git repository like git-filter-branch does, but faster";
+    longDescription = ''
+      The BFG is a simpler, faster alternative to git-filter-branch for
+      cleansing bad data out of your Git repository history, in particular removing
+      crazy big files and removing passwords, credentials, and other private data.
+
+      The git-filter-branch command is enormously powerful and can do things
+      that the BFG can't - but the BFG is much better for the tasks above, because
+      it's faster (10-720x), simpler (dedicated to just removing things), and
+      beautiful (can use Scala instead of bash to script customizations).
+    '';
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    license = licenses.gpl3;
+    maintainers = [ maintainers.changlinli ];
+    mainProgram = "bfg";
+    platforms = platforms.unix;
+    downloadPage = "https://mvnrepository.com/artifact/com.madgag/bfg/${version}";
+  };
+
+}

pkgs/by-name/bf/bfr/configure-log-compiler-errors-to-stderr.patch

@@ -0,0 +1,13 @@
+diff --git a/configure b/configure
+index 53e90a7..4afeb58 100755
+--- a/configure
++++ b/configure
+@@ -411,7 +411,7 @@ if test "$silent" = yes; then
+ else
+   exec 6>&1
+ fi
+-exec 5>./config.log
++exec 5>&2
+ 
+ echo "\
+ This file contains any messages produced by compilers while

pkgs/by-name/bf/bfr/fix-gcc-complaining-about-invalid-configure-example-code.patch

@@ -0,0 +1,13 @@
+diff --git a/configure b/configure
+index 53e90a7..cc80615 100755
+--- a/configure
++++ b/configure
+@@ -908,7 +908,7 @@ cat > conftest.$ac_ext << EOF
+ #line 909 "configure"
+ #include "confdefs.h"
+ 
+-main(){return(0);}
++int main(){return(0);}
+ EOF
+ if { (eval echo configure:914: \"$ac_link\") 1>&5; (eval $ac_link) 2>&5; } && test -s conftest${ac_exeext}; then
+   ac_cv_prog_cc_works=yes

pkgs/by-name/bf/bfr/package.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  perl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bfr";
+  version = "1.6";
+
+  src = fetchurl {
+    url = "http://www.sourcefiles.org/Utilities/Text_Utilities/bfr-${version}.tar.bz2";
+    sha256 = "0fadfssvj9klj4dq9wdrzys1k2a1z2j0p6kgnfgbjv0n1bq6h4cy";
+  };
+
+  patches = [
+    ./configure-log-compiler-errors-to-stderr.patch
+    ./fix-gcc-complaining-about-invalid-configure-example-code.patch
+
+    (fetchurl {
+      url = "https://gitweb.gentoo.org/repo/gentoo.git/plain/app-misc/bfr/files/bfr-1.6-perl.patch?id=dec60bb6900d6ebdaaa6aa1dcb845b30b739f9b5";
+      sha256 = "1pk9jm3c1qzs727lh0bw61w3qbykaqg4jblywf9pvq5bypk88qfj";
+    })
+  ];
+
+  buildInputs = [ perl ];
+
+  meta = with lib; {
+    description = "General-purpose command-line pipe buffer";
+    license = lib.licenses.gpl2Only;
+    maintainers = with maintainers; [ pSub ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/bf/bfs/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  attr,
+  acl,
+  libcap,
+  liburing,
+  oniguruma,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bfs";
+  version = "4.1";
+
+  src = fetchFromGitHub {
+    repo = "bfs";
+    owner = "tavianator";
+    tag = version;
+    hash = "sha256-+hGxdsk9MU5MVvvx3C2cqomboNxD0UZ5y7t84fAwfqs=";
+  };
+
+  buildInputs = [
+    oniguruma
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    acl
+    attr
+    libcap
+    liburing
+  ];
+
+  configureFlags = [ "--enable-release" ];
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "Breadth-first version of the UNIX find command";
+    longDescription = ''
+      bfs is a variant of the UNIX find command that operates breadth-first rather than
+      depth-first. It is otherwise intended to be compatible with many versions of find.
+    '';
+    homepage = "https://github.com/tavianator/bfs";
+    license = licenses.bsd0;
+    platforms = platforms.unix;
+    maintainers = with maintainers; [
+      yesbox
+      cafkafk
+    ];
+    mainProgram = "bfs";
+  };
+}

pkgs/by-name/bf/bfscripts/package.nix

@@ -0,0 +1,73 @@
+{
+  fetchFromGitHub,
+  git,
+  lib,
+  python3,
+  rpm,
+  stdenv,
+}:
+
+let
+  # Most of the binaries are not really useful because they have hardcoded
+  # paths that only make sense when you're running the stock BlueField OS on
+  # your BlueField. These might be patched in the future with resholve
+  # (https://github.com/abathur/resholve). If there is one that makes sense
+  # without resholving it, it can simply be uncommented and will be included in
+  # the output.
+  binaries = [
+    # "bfacpievt"
+    # "bfbootmgr"
+    # "bfcfg"
+    # "bfcpu-freq"
+    # "bfdracut"
+    # "bffamily"
+    # "bfgrubcheck"
+    # "bfhcafw"
+    # "bfinst"
+    # "bfpxe"
+    # "bfrec"
+    "bfrshlog"
+    # "bfsbdump"
+    # "bfsbkeys"
+    # "bfsbverify"
+    # "bfver"
+    # "bfvcheck"
+    "mlx-mkbfb"
+    "bfup"
+  ];
+in
+stdenv.mkDerivation {
+  pname = "bfscripts";
+  version = "unstable-2025-06-27";
+
+  src = fetchFromGitHub {
+    owner = "Mellanox";
+    repo = "bfscripts";
+    rev = "ed8ede79fa002a2d83719a1bef6fbe0f7dcf37a4";
+    hash = "sha256-x+hpH6D5HTl39zD0vYj6wRFw881M4AcfM+ePcgXMst8=";
+  };
+
+  buildInputs = [
+    python3
+  ];
+
+  nativeBuildInputs = [
+    git
+    rpm
+  ];
+
+  installPhase = ''
+    ${lib.concatStringsSep "\n" (map (b: "install -D ${b} $out/bin/${b}") binaries)}
+  '';
+
+  meta = with lib; {
+    description = "Collection of scripts used for BlueField SoC system management";
+    homepage = "https://github.com/Mellanox/bfscripts";
+    license = licenses.bsd2;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [
+      nikstur
+      thillux
+    ];
+  };
+}

pkgs/by-name/bf/bftools/package.nix

@@ -0,0 +1,48 @@
+{
+  stdenv,
+  lib,
+  makeWrapper,
+  fetchzip,
+  jre,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bftools";
+  version = "6.3.0";
+
+  src = fetchzip {
+    url = "http://downloads.openmicroscopy.org/bio-formats/${version}/artifacts/bftools.zip";
+    sha256 = "02nvvmpfglpah1ihd08aw65g1794w588c988cdar1hfl4s80qwhb";
+  };
+
+  installPhase = ''
+    find . -maxdepth 1 -perm -111 -type f -not -name "*.sh" \
+      -exec install -vD {} "$out"/bin/{} \;
+
+    mkdir $out/libexec
+    mkdir -p $out/share/java
+
+    cp ./*.sh $out/libexec
+    cp ./*.jar $out/share/java
+
+    for file in $out/bin/*; do
+      substituteInPlace $file --replace "\$BF_DIR" $out/libexec
+    done
+    substituteInPlace $out/libexec/bf.sh --replace "\$BF_JAR_DIR" $out/share/java
+  '';
+
+  postFixup = ''
+    wrapProgram $out/libexec/bf.sh --prefix PATH : "${lib.makeBinPath [ jre ]}"
+  '';
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  meta = with lib; {
+    description = "Bundle of scripts for using Bio-Formats on the command line with bioformats_package.jar already included";
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    license = licenses.gpl2;
+    platforms = platforms.all;
+    homepage = "https://www.openmicroscopy.org/bio-formats/";
+    maintainers = [ maintainers.tbenst ];
+  };
+}

pkgs/by-name/bf/bftpd/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  libxcrypt,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bftpd";
+  version = "6.3";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/project/${pname}/${pname}/${pname}-${version}/${pname}-${version}.tar.gz";
+    sha256 = "sha256-f7XZCSrGwmQqyf5C4xtJ46Q4SDHxbr15rDzcAK1PvB4=";
+  };
+
+  # utmp has been replaced by utmpx since Mac OS X 10.6 (Snow Leopard):
+  #
+  #   https://stackoverflow.com/a/37913019
+  #
+  # bftpd does not have support for this, so disable it.
+  #
+  postPatch = lib.optionalString stdenv.hostPlatform.isDarwin ''
+    for file in login.*; do
+      substituteInPlace $file --replace-fail "#ifdef HAVE_UTMP_H" "#if 0"
+    done
+  '';
+
+  buildInputs = [ libxcrypt ];
+
+  CFLAGS = "-std=gnu89";
+
+  preConfigure = ''
+    sed -re 's/-[og] 0//g' -i Makefile*
+  '';
+
+  postInstall = ''
+    mkdir -p $out/share/doc/${pname}
+    mv $out/etc/*.conf $out/share/doc/${pname}
+    rm -rf $out/{etc,var}
+  '';
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "Minimal ftp server";
+    mainProgram = "bftpd";
+    downloadPage = "http://bftpd.sf.net/download.html";
+    homepage = "http://bftpd.sf.net/";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ raskin ];
+    platforms = platforms.all;
+  };
+}