push sheeet

pkgs/by-name/bi/bitbox/package.nix

@@ -0,0 +1,105 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  runCommand,
+  buildNpmPackage,
+  clang,
+  go,
+  libsForQt5,
+  qt6,
+  udevCheckHook,
+}:
+
+let
+  # Qt 6 doesn’t provide the rcc binary so we create an ad hoc package pulling
+  # it from Qt 5.
+  rcc = runCommand "rcc" { } ''
+    mkdir -p $out/bin
+    cp ${lib.getExe' libsForQt5.qt5.qtbase.dev "rcc"} $out/bin
+  '';
+in
+stdenv.mkDerivation rec {
+  pname = "bitbox";
+  version = "4.48.1";
+
+  src = fetchFromGitHub {
+    owner = "BitBoxSwiss";
+    repo = "bitbox-wallet-app";
+    tag = "v${version}";
+    fetchSubmodules = true;
+    hash = "sha256-zpkjYnGsmPKjxUpp2H1qSzqthOO1mTmki3bPqo35sBo=";
+  };
+
+  postPatch = ''
+    substituteInPlace frontends/qt/resources/linux/usr/share/applications/bitbox.desktop \
+        --replace-fail 'Exec=BitBox %u' 'Exec=bitbox %u'
+  '';
+
+  dontConfigure = true;
+
+  passthru.web = buildNpmPackage {
+    pname = "bitbox-web";
+    inherit version;
+    inherit src;
+    sourceRoot = "${src.name}/frontends/web";
+    npmDepsHash = "sha256-9NS85U4L5sLX3n/uN4p4CB5vfpWMMcnf6wESlFdQPlI=";
+    installPhase = "cp -r build $out";
+  };
+
+  buildPhase = ''
+    runHook preBuild
+
+    ln -s ${passthru.web} frontends/web/build
+    export GOCACHE=$TMPDIR/go-cache
+    cd frontends/qt
+    make -C server linux
+    ./genassets.sh
+    qmake -o build/Makefile
+    cd build
+    make
+    cd ../../..
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir $out
+    cp -r frontends/qt/resources/linux/usr/share $out
+    mkdir $out/{bin,lib}
+    cp frontends/qt/build/BitBox $out/bin/bitbox
+    cp frontends/qt/build/assets.rcc $out/bin
+    cp frontends/qt/server/libserver.so $out/lib
+    install -Dt $out/lib/udev/rules.d ${./rules.d}/*
+
+    runHook postInstall
+  '';
+
+  buildInputs = [ qt6.qtwebengine ];
+
+  nativeBuildInputs = [
+    clang
+    go
+    qt6.wrapQtAppsHook
+    rcc
+    udevCheckHook
+  ];
+
+  doInstallCheck = true;
+
+  meta = {
+    description = "Companion app for the BitBox02 hardware wallet";
+    homepage = "https://bitbox.swiss/app/";
+    downloadPage = "https://github.com/BitBoxSwiss/bitbox-wallet-app";
+    changelog = "https://github.com/BitBoxSwiss/bitbox-wallet-app/blob/master/CHANGELOG.md#${
+      builtins.replaceStrings [ "." ] [ "" ] version
+    }";
+    license = lib.licenses.asl20;
+    maintainers = [ lib.maintainers.tensor5 ];
+    mainProgram = "bitbox";
+    sourceProvenance = [ lib.sourceTypes.fromSource ];
+    platforms = [ "x86_64-linux" ];
+  };
+}

pkgs/by-name/bi/bitbox/rules.d/51-hid-digitalbitbox.rules

@@ -0,0 +1 @@
+SUBSYSTEM=="usb", TAG+="uaccess", TAG+="udev-acl", SYMLINK+="dbb%n", ATTRS{idVendor}=="03eb", ATTRS{idProduct}=="2402"

pkgs/by-name/bi/bitbox/rules.d/52-hid-digitalbitbox.rules

@@ -0,0 +1 @@
+KERNEL=="hidraw*", SUBSYSTEM=="hidraw", ATTRS{idVendor}=="03eb", ATTRS{idProduct}=="2402", TAG+="uaccess", TAG+="udev-acl", SYMLINK+="dbbf%n"

pkgs/by-name/bi/bitbox/rules.d/53-hid-bitbox02.rules

@@ -0,0 +1 @@
+SUBSYSTEM=="usb", TAG+="uaccess", TAG+="udev-acl", SYMLINK+="bitbox02_%n", ATTRS{idVendor}=="03eb", ATTRS{idProduct}=="2403"

pkgs/by-name/bi/bitbox/rules.d/54-hid-bitbox02.rules

@@ -0,0 +1 @@
+KERNEL=="hidraw*", SUBSYSTEM=="hidraw", ATTRS{idVendor}=="03eb", ATTRS{idProduct}=="2403", TAG+="uaccess", TAG+="udev-acl", SYMLINK+="bitbox02-%n"