push sheeet

pkgs/by-name/bk/bk/package.nix

@@ -0,0 +1,42 @@
+{
+  fetchCrate,
+  go-md2man,
+  installShellFiles,
+  lib,
+  rustPlatform,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "bk";
+  version = "0.6.0";
+
+  src = fetchCrate {
+    inherit pname version;
+    hash = "sha256-rSMvx/zUZqRRgj48TVVG7RwQT8e70m0kertRJysDY4Y=";
+  };
+
+  cargoHash = "sha256-i62vUvR/iX0zKD29WsIvlcn49lcFvv2uN05oTexvPMc=";
+
+  nativeBuildInputs = [
+    go-md2man
+    installShellFiles
+  ];
+
+  postBuild = ''
+    sed -i '$ a # Source and further info' README.md
+    sed -i '$ a https://github.com/aeosynth/bk' README.md
+    go-md2man -in README.md -out bk.1
+  '';
+
+  postInstall = ''
+    installManPage bk.?
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/aeosynth/bk";
+    description = "Terminal epub reader written in rust";
+    license = licenses.mit;
+    maintainers = with maintainers; [ vuimuich ];
+    mainProgram = "bk";
+  };
+}

pkgs/by-name/bk/bkcrack/package.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "bkcrack";
+  version = "1.8.0";
+
+  src = fetchFromGitHub {
+    owner = "kimci86";
+    repo = "bkcrack";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-MFY+YBw9cpmUHrL7fpop63ty0ZdESlAgrWRYwK0IowY=";
+  };
+
+  passthru.updateScript = nix-update-script { };
+
+  nativeBuildInputs = [ cmake ];
+
+  cmakeFlags = [
+    "-DBKCRACK_BUILD_TESTING=${if finalAttrs.finalPackage.doCheck then "ON" else "OFF"}"
+  ];
+
+  postInstall = ''
+    mkdir -p $out/bin $out/share/doc/bkcrack $out/share/licenses/bkcrack
+    mv $out/bkcrack $out/bin/
+    mv $out/license.txt $out/share/licenses/bkcrack
+    mv $out/example $out/tools $out/readme.md $out/share/doc/bkcrack
+  '';
+
+  doCheck = true;
+
+  meta = with lib; {
+    description = "Crack legacy zip encryption with Biham and Kocher's known plaintext attack";
+    homepage = "https://github.com/kimci86/bkcrack";
+    license = licenses.zlib;
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ erdnaxe ];
+    mainProgram = "bkcrack";
+  };
+})

pkgs/by-name/bk/bklk/package.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  ncurses,
+}:
+
+stdenv.mkDerivation {
+  pname = "bklk";
+  version = "0-unstable-2020-12-29";
+
+  src = fetchFromGitHub {
+    owner = "Ruunyox";
+    repo = "bklk";
+    rev = "26f3420aa5726e152a745278ddb98dc99c0a935e";
+    sha256 = "sha256-R3H6tv6fzQG41Y2rui0K8fdQ/+Ywnc5hqTPFjktrhF8=";
+  };
+
+  makeFlags = [ "CC=$$CXX" ];
+
+  buildInputs = [ ncurses ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp bklk $out/bin
+  '';
+
+  meta = with lib; {
+    description = "Ncurses Binary Clock";
+    longDescription = "bklk is a simple binary clock for your terminal.";
+    homepage = "https://github.com/Ruunyox/bklk";
+    license = licenses.mit;
+    maintainers = with maintainers; [ j0hax ];
+    platforms = platforms.all;
+    mainProgram = "bklk";
+  };
+}

pkgs/by-name/bk/bkt/package.nix

@@ -0,0 +1,27 @@
+{
+  rustPlatform,
+  fetchFromGitHub,
+  lib,
+}:
+rustPlatform.buildRustPackage rec {
+
+  pname = "bkt";
+  version = "0.8.0";
+
+  src = fetchFromGitHub {
+    owner = "dimo414";
+    repo = "bkt";
+    tag = version;
+    sha256 = "sha256-XQK7oZfutqCvFoGzMH5G5zoGvqB8YaXSdrwjS/SVTNU=";
+  };
+
+  cargoHash = "sha256-4CY2A6mPTfGhqUh+nNg6eaTIVwA9ZtgH5jHQDGHnK4c=";
+
+  meta = {
+    description = "Subprocess caching utility";
+    homepage = "https://github.com/dimo414/bkt";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.mangoiv ];
+    mainProgram = "bkt";
+  };
+}

pkgs/by-name/bk/bkyml/package.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  python3,
+  fetchPypi,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "bkyml";
+  version = "1.4.3";
+  format = "pyproject";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "01kpx35572mp4xl2fjyvfk39jfgfjcyzymbifk76891kaqkjb7r9";
+  };
+
+  # The pyscaffold is not a runtime dependency but just a python project bootstrapping tool. Thus,
+  # instead of implement this package in nix we remove a dependency on it and fix up the version
+  # of the package, that has been affected by the pyscaffold package dependency removal.
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace-fail "['pyscaffold>=3.0a0,<3.1a0'] + " "" \
+      --replace-fail "use_pyscaffold=True"  ""
+    substituteInPlace src/bkyml/__init__.py \
+      --replace-fail "from pkg_resources" "# from pkg_resources" \
+      --replace-fail "get_distribution(dist_name).version" '"${version}"'
+  '';
+
+  build-system = with python3.pkgs; [
+    setuptools
+  ];
+
+  dependencies = with python3.pkgs; [
+    ruamel-yaml
+  ];
+
+  # Don't run tests because they are broken when run within
+  # buildPythonApplication for reasons I don't quite understand.
+  doCheck = false;
+
+  pythonImportsCheck = [ "bkyml" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/joscha/bkyml";
+    description = "CLI tool to generate a pipeline.yaml file for Buildkite on the fly";
+    license = licenses.mit;
+    maintainers = with maintainers; [ olebedev ];
+  };
+}