push sheeet

pkgs/by-name/bw/bwa-mem2/no-submodule.patch

@@ -0,0 +1,42 @@
+diff --git a/Makefile b/Makefile
+index 359585f..13ec279 100644
+--- a/Makefile
++++ b/Makefile
+@@ -49,7 +49,6 @@ OBJS=		src/fastmap.o src/bwtindex.o src/utils.o src/memcpy_bwamem.o src/kthread.
+ 			src/FMI_search.o src/read_index_ele.o src/bwamem_pair.o src/kswv.o src/bwa.o \
+ 			src/bwamem_extra.o src/kopen.o
+ BWA_LIB=    libbwa.a
+-SAFE_STR_LIB=    ext/safestringlib/libsafestring.a
+ 
+ ifeq ($(arch),sse41)
+ 	ifeq ($(CXX), icpc)
+@@ -101,16 +100,6 @@ CXXFLAGS+=	-g -O3 -fpermissive $(ARCH_FLAGS) #-Wall ##-xSSE2
+ all:$(EXE)
+ 
+ multi:
+-	rm -f src/*.o $(BWA_LIB); cd ext/safestringlib/ && $(MAKE) clean;
+-	$(MAKE) arch=sse41    EXE=bwa-mem2.sse41    CXX=$(CXX) all
+-	rm -f src/*.o $(BWA_LIB); cd ext/safestringlib/ && $(MAKE) clean;
+-	$(MAKE) arch=sse42    EXE=bwa-mem2.sse42    CXX=$(CXX) all
+-	rm -f src/*.o $(BWA_LIB); cd ext/safestringlib/ && $(MAKE) clean;
+-	$(MAKE) arch=avx    EXE=bwa-mem2.avx    CXX=$(CXX) all
+-	rm -f src/*.o $(BWA_LIB); cd ext/safestringlib/ && $(MAKE) clean;
+-	$(MAKE) arch=avx2   EXE=bwa-mem2.avx2     CXX=$(CXX) all
+-	rm -f src/*.o $(BWA_LIB); cd ext/safestringlib/ && $(MAKE) clean;
+-	$(MAKE) arch=avx512 EXE=bwa-mem2.avx512bw CXX=$(CXX) all
+ 	$(CXX) -Wall -O3 src/runsimd.cpp -Iext/safestringlib/include -Lext/safestringlib/ -lsafestring $(STATIC_GCC) -o bwa-mem2
+ 
+ 
+@@ -120,12 +109,8 @@ $(EXE):$(BWA_LIB) $(SAFE_STR_LIB) src/main.o
+ $(BWA_LIB):$(OBJS)
+ 	ar rcs $(BWA_LIB) $(OBJS)
+ 
+-$(SAFE_STR_LIB):
+-	cd ext/safestringlib/ && $(MAKE) clean && $(MAKE) CC=$(CC) directories libsafestring.a
+-
+ clean:
+ 	rm -fr src/*.o $(BWA_LIB) $(EXE) bwa-mem2.sse41 bwa-mem2.sse42 bwa-mem2.avx bwa-mem2.avx2 bwa-mem2.avx512bw
+-	cd ext/safestringlib/ && $(MAKE) clean
+ 
+ depend:
+ 	(LC_ALL=C; export LC_ALL; makedepend -Y -- $(CXXFLAGS) $(CPPFLAGS) -I. -- src/*.cpp)

pkgs/by-name/bw/bwa-mem2/package.nix

@@ -0,0 +1,94 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  safestringlib,
+  zlib,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "bwa-mem2";
+  version = "unstable-2023-03-18";
+
+  src = fetchFromGitHub {
+    owner = "bwa-mem2";
+    repo = "bwa-mem2";
+    rev = "cf4306a47dac35e7e79a9e75398a35f33900cfd0";
+    hash = "sha256-hY8nLRFWt0GAElhDIcYdUX6cJrzOE3NlYRQr0tC3on4=";
+  };
+
+  buildInputs = [ zlib ];
+
+  buildFlags = [
+    (
+      if stdenv.hostPlatform.sse4_2Support then
+        "arch=sse42"
+      else if stdenv.hostPlatform.avxSupport then
+        "arch=avx"
+      else if stdenv.hostPlatform.avx2Support then
+        "arch=avx2"
+      else if stdenv.hostPlatform.avx512Support then
+        "arch=avx512"
+      else
+        "arch=sse41"
+    )
+  ];
+
+  patches = [
+    ./no-submodule.patch
+  ];
+
+  # Also, patch the tests
+  postPatch =
+    # Force path to static link, otherwise, it fails at runtime to
+    # find the shared library
+    ''
+      substituteInPlace Makefile \
+        --replace-fail "-Iext/safestringlib/include" "-I${safestringlib}/include" \
+        --replace-fail "-Lext/safestringlib" "-L${safestringlib}/lib"
+    ''
+    # Make test compile by changing the compiler and path to library
+    # Remove xeonbsw test that fails to compile due to missing _rdsc
+    # also, not portable
+    + ''
+      substituteInPlace test/Makefile \
+        --replace-fail "icpc" "g++" \
+        --replace-fail "../ext/safestringlib/libsafestring.a"  \
+                       "${safestringlib}/lib/libsafestring.a" \
+        --replace-fail \
+          "fmi_test smem2_test bwt_seed_strategy_test sa2ref_test xeonbsw" \
+          "fmi_test smem2_test bwt_seed_strategy_test sa2ref_test"
+    '';
+
+  env.NIX_CFLAGS_COMPILE = toString (
+    lib.optionals stdenv.hostPlatform.isDarwin [
+      "-Wno-error=register"
+      "-Wno-error=implicit-function-declaration"
+    ]
+  );
+
+  nativeBuildInputs = [
+    safestringlib
+  ];
+
+  enableParallelBuilding = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    cp bwa-mem2* $out/bin/
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Next version of the bwa-mem algorithm in bwa, a software package for mapping low-divergent sequences against a large reference genome";
+    mainProgram = "bwa-mem2";
+    license = licenses.mit;
+    homepage = "https://github.com/bwa-mem2/bwa-mem2/";
+    changelog = "https://github.com/bwa-mem2/bwa-mem2/blob/${finalAttrs.src.rev}/NEWS.md";
+    platforms = platforms.x86_64;
+    maintainers = with maintainers; [ apraga ];
+  };
+})

pkgs/by-name/bw/bwa/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  zlib,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bwa";
+  version = "0.7.19";
+
+  src = fetchFromGitHub {
+    owner = "lh3";
+    repo = "bwa";
+    tag = "v${version}";
+    hash = "sha256-o3+7kf+49mnRn5PjtdOiAaI9VK1cyT9p5QUSQ/W4GxI=";
+  };
+
+  buildInputs = [ zlib ];
+
+  # Avoid hardcoding gcc to allow environments with a different
+  # C compiler to build
+  preConfigure = ''
+    sed -i '/^CC/d' Makefile
+  '';
+
+  makeFlags = lib.optional stdenv.hostPlatform.isStatic "AR=${stdenv.cc.targetPrefix}ar";
+
+  # it's unclear which headers are intended to be part of the public interface
+  # so we may find ourselves having to add more here over time
+  installPhase = ''
+    runHook preInstall
+
+    install -vD -t $out/bin bwa
+    install -vD -t $out/lib libbwa.a
+    install -vD -t $out/include bntseq.h
+    install -vD -t $out/include bwa.h
+    install -vD -t $out/include bwamem.h
+    install -vD -t $out/include bwt.h
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Software package for mapping low-divergent sequences against a large reference genome, such as the human genome";
+    mainProgram = "bwa";
+    license = licenses.gpl3Plus;
+    homepage = "https://bio-bwa.sourceforge.net/";
+    maintainers = with maintainers; [ luispedro ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/bw/bwbasic/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  gccStdenv,
+  dos2unix,
+  fetchurl,
+  unzip,
+}:
+
+gccStdenv.mkDerivation (finalAttrs: {
+  pname = "bwbasic";
+  version = "3.30";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/project/bwbasic/bwbasic/version%20${finalAttrs.version}/bwbasic-${finalAttrs.version}.zip";
+    hash = "sha256-Cab8/DvYjw6K8c46ZTJImISa0vJt5UeFDB+ZTSVfkGQ=";
+  };
+
+  nativeBuildInputs = [
+    dos2unix
+    unzip
+  ];
+
+  unpackPhase = ''
+    unzip $src
+  '';
+
+  postPatch = ''
+    dos2unix configure
+    patchShebangs configure
+    chmod +x configure
+  '';
+
+  hardeningDisable = [ "format" ];
+
+  preInstall = ''
+    mkdir -p $out/bin
+  '';
+
+  meta = {
+    description = "Bywater BASIC Interpreter";
+    mainProgram = "bwbasic";
+    license = lib.licenses.gpl2Only;
+    maintainers = with lib.maintainers; [ irenes ];
+    platforms = lib.platforms.all;
+    homepage = "https://sourceforge.net/projects/bwbasic/";
+  };
+})

pkgs/by-name/bw/bwm_ng/package.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  stdenv,
+  autoreconfHook,
+  fetchurl,
+  fetchpatch,
+  ncurses,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bwm-ng";
+  version = "0.6.3";
+
+  src = fetchurl {
+    url = "https://www.gropp.org/bwm-ng/${pname}-${version}.tar.gz";
+    sha256 = "0ikzyvnb73msm9n7ripg1dsw9av1i0c7q2hi2173xsj8zyv559f1";
+  };
+
+  patches = [
+    # Pull upstream fix for ncurses-6.3 support.
+    (fetchpatch {
+      name = "ncurses-6.3.patch";
+      url = "https://github.com/vgropp/bwm-ng/commit/6a2087db6cc7ac5b5f667fcd17c262c079e8dcf2.patch";
+      sha256 = "1l5dii9d52v0x0sq458ybw7m9p8aan2vl94gwx5s8mgxsnbcmzzx";
+      # accidentally committed changes
+      excludes = [
+        "config.h.in~"
+        "configure.in"
+        "configure~"
+      ];
+    })
+  ];
+
+  nativeBuildInputs = [
+    autoreconfHook
+  ];
+
+  buildInputs = [
+    ncurses
+  ];
+
+  meta = with lib; {
+    description = "Small and simple console-based live network and disk io bandwidth monitor";
+    mainProgram = "bwm-ng";
+    homepage = "http://www.gropp.org/?id=projects&sub=bwm-ng";
+    license = licenses.gpl2Plus;
+    platforms = platforms.unix;
+    maintainers = [ ];
+    longDescription = ''
+      bwm-ng supports:
+       - /proc/net/dev, netstat, getifaddr, sysctl, kstat, /proc/diskstats /proc/partitions, IOKit,
+         devstat and libstatgrab
+       - unlimited number of interfaces/devices
+       - interfaces/devices are added or removed dynamically from list
+       - white-/blacklist of interfaces/devices
+       - output of KB/s, Kb/s, packets, errors, average, max and total sum
+       - output in curses, plain console, CSV or HTML
+    '';
+  };
+}

pkgs/by-name/bw/bws/package.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+  pkg-config,
+  oniguruma,
+  openssl,
+  stdenv,
+  python3,
+  perl,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "bws";
+  version = "1.0.0";
+
+  src = fetchFromGitHub {
+    owner = "bitwarden";
+    repo = "sdk";
+    rev = "bws-v${version}";
+    hash = "sha256-acS4yKppvIBiwBMoa5Ero4G9mUf8OLG/TbrZOolAwuc=";
+  };
+
+  cargoHash = "sha256-SJn00C7vkNoghdVPUszep40RSL8fD+/ELUeuf9GBD7c=";
+
+  nativeBuildInputs = [
+    installShellFiles
+    pkg-config
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    perl
+  ];
+
+  buildInputs = [
+    oniguruma
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    openssl
+  ];
+
+  env = {
+    PYO3_PYTHON = "${python3}/bin/python3";
+    RUSTONIG_SYSTEM_LIBONIG = true;
+  };
+
+  cargoBuildFlags = [
+    "--package"
+    "bws"
+  ];
+
+  cargoTestFlags = [
+    "--package"
+    "bws"
+  ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd bws \
+      --bash <($out/bin/bws completions bash) \
+      --fish <($out/bin/bws completions fish) \
+      --zsh <($out/bin/bws completions zsh)
+  '';
+
+  meta = {
+    changelog = "https://github.com/bitwarden/sdk/blob/${src.rev}/crates/bws/CHANGELOG.md";
+    description = "Bitwarden Secrets Manager CLI";
+    homepage = "https://bitwarden.com/help/secrets-manager-cli/";
+    license = lib.licenses.unfree; # BITWARDEN SOFTWARE DEVELOPMENT KIT LICENSE AGREEMENT
+    mainProgram = "bws";
+    maintainers = with lib.maintainers; [ dit7ya ];
+  };
+}