push sheeet

pkgs/by-name/c3/c3-lsp/package.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "c3-lsp";
+  version = "0.4.0";
+
+  src = fetchFromGitHub {
+    owner = "pherrymason";
+    repo = "c3-lsp";
+    rev = "v${version}";
+    hash = "sha256-MScpFh4J4jVJI5WtW4tfNB18YDpxs+ass1HmXyOO5VM=";
+  };
+
+  sourceRoot = "${src.name}/server";
+
+  vendorHash = "sha256-eT+Qirl0R1+di3JvXxggGK/nK9+nqw+8QEur+ldJXSc=";
+
+  postInstall = ''
+    mv $out/bin/lsp $out/bin/c3-lsp
+  '';
+
+  meta = {
+    description = "Language Server for C3 Language";
+    homepage = "https://github.com/pherrymason/c3-lsp";
+    changelog = "https://github.com/pherrymason/c3-lsp/blob/${src.rev}/changelog.md";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ arthsmn ];
+    mainProgram = "c3-lsp";
+    platforms = lib.platforms.all;
+  };
+}

pkgs/by-name/c3/c3c/package.nix

@@ -0,0 +1,88 @@
+{
+  llvmPackages,
+  lib,
+  fetchFromGitHub,
+  cmake,
+  python3,
+  curl,
+  libxml2,
+  libffi,
+  xar,
+  versionCheckHook,
+  rev ? "unknown",
+  debug ? false,
+  checks ? true,
+}:
+let
+  inherit (lib.strings) optionalString;
+in
+llvmPackages.stdenv.mkDerivation (finalAttrs: {
+
+  pname = "c3c${optionalString debug "-debug"}";
+  version = "0.7.6";
+
+  src = fetchFromGitHub {
+    owner = "c3lang";
+    repo = "c3c";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-VZFMRu3iI3L57cQDLeS1I+1GiIWxAjUnO/cXbISB7M8=";
+  };
+
+  cmakeBuildType = if debug then "Debug" else "Release";
+
+  postPatch = ''
+    substituteInPlace git_hash.cmake \
+      --replace-fail "\''${GIT_HASH}" "${rev}"
+    substituteInPlace CMakeLists.txt \
+      --replace-fail "-Werror" ""
+  '';
+
+  nativeBuildInputs = [ cmake ];
+  cmakeFlags = [
+    "-DC3_ENABLE_CLANGD_LSP=${if debug then "ON" else "OFF"}"
+    "-DC3_LLD_DIR=${llvmPackages.lld.lib}/lib"
+    "-DLLVM_CRT_LIBRARY_DIR=${llvmPackages.compiler-rt}/lib/darwin"
+  ];
+
+  buildInputs = [
+    llvmPackages.llvm
+    llvmPackages.lld
+    llvmPackages.compiler-rt
+    curl
+    libxml2
+    libffi
+  ]
+  ++ lib.optionals llvmPackages.stdenv.hostPlatform.isDarwin [ xar ];
+
+  nativeCheckInputs = [ python3 ];
+
+  doCheck =
+    lib.elem llvmPackages.stdenv.system [
+      "x86_64-linux"
+      "x86_64-darwin"
+      "aarch64-darwin"
+    ]
+    && checks;
+
+  checkPhase = ''
+    runHook preCheck
+    ( cd ../resources/testproject; ../../build/c3c build --trust=full )
+    ( cd ../test; ../build/c3c compile-run -O1 src/test_suite_runner.c3 -- ../build/c3c test_suite )
+    runHook postCheck
+  '';
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  doInstallCheck = true;
+
+  meta = with lib; {
+    description = "Compiler for the C3 language";
+    homepage = "https://github.com/c3lang/c3c";
+    license = licenses.lgpl3Only;
+    maintainers = with maintainers; [
+      hucancode
+      anas
+    ];
+    platforms = platforms.all;
+    mainProgram = "c3c";
+  };
+})

pkgs/by-name/c3/c3d/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  itk,
+}:
+
+stdenv.mkDerivation {
+  pname = "c3d";
+  version = "1.4.1-unstable-2024-08-07";
+
+  src = fetchFromGitHub {
+    owner = "pyushkevich";
+    repo = "c3d";
+    rev = "9e6174153ab87eae014f5b802413478c8fbc9a1a";
+    hash = "sha256-s2/XRyKoiMnF6cRsxxNUSlNtksbOyKSlk8hAGxJELqw=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [ itk ];
+
+  cmakeFlags = [ "-DCONVERT3D_USE_ITK_REMOTE_MODULES=OFF" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/pyushkevich/c3d";
+    description = "Medical imaging processing tool";
+    maintainers = with maintainers; [ bcdarwin ];
+    platforms = platforms.unix;
+    license = licenses.gpl3;
+    broken = stdenv.hostPlatform.isAarch64;
+    # /build/source/itkextras/OneDimensionalInPlaceAccumulateFilter.txx:312:10: fatal error: xmmintrin.h: No such file or directory
+  };
+}