push sheeet

pkgs/by-name/ca/caprine/001-disable-auto-update.patch

@@ -0,0 +1,39 @@
+From 5da393e32336534222c77659ff138a4e512e6a1f Mon Sep 17 00:00:00 2001
+From: Austin Horstman <khaneliman12@gmail.com>
+Date: Wed, 4 Dec 2024 13:23:15 -0600
+Subject: [PATCH] Disable autoUpdate
+
+---
+ source/index.ts | 12 ------------
+ 1 file changed, 12 deletions(-)
+
+diff --git a/source/index.ts b/source/index.ts
+index b8511949a..205c513fe 100644
+--- a/source/index.ts
++++ b/source/index.ts
+@@ -14,7 +14,6 @@ import {
+ 	nativeTheme,
+ } from 'electron';
+ import {ipcMain as ipc} from 'electron-better-ipc';
+-import {autoUpdater} from 'electron-updater';
+ import electronDl from 'electron-dl';
+ import electronContextMenu from 'electron-context-menu';
+ import electronLocalshortcut from 'electron-localshortcut';
+@@ -65,17 +64,6 @@ if (!config.get('hardwareAcceleration')) {
+ 	app.disableHardwareAcceleration();
+ }
+
+-if (!is.development && config.get('autoUpdate')) {
+-	(async () => {
+-		const FOUR_HOURS = 1000 * 60 * 60 * 4;
+-		setInterval(async () => {
+-			await autoUpdater.checkForUpdatesAndNotify();
+-		}, FOUR_HOURS);
+-
+-		await autoUpdater.checkForUpdatesAndNotify();
+-	})();
+-}
+-
+ let mainWindow: BrowserWindow;
+ let isQuitting = false;
+ let previousMessageCount = 0;

pkgs/by-name/ca/caprine/package.nix

@@ -0,0 +1,98 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  buildNpmPackage,
+  makeDesktopItem,
+  copyDesktopItems,
+  electron,
+  nix-update-script,
+}:
+
+buildNpmPackage rec {
+  pname = "caprine";
+  version = "2.60.3";
+
+  src = fetchFromGitHub {
+    owner = "sindresorhus";
+    repo = "caprine";
+    rev = "v${version}";
+    hash = "sha256-yfCilJ62m7nKe8B+4puwAbNgr2g1P7HaKIhFINdv0/k=";
+  };
+
+  ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
+
+  npmDepsHash = "sha256-hNOAplCSXrO4NZqDTkmhf0oZVeGRUHr2Y/Qdx2RIV9c=";
+
+  nativeBuildInputs = [ copyDesktopItems ];
+
+  postBuild = ''
+    cp -r ${electron.dist} electron-dist
+    chmod -R u+w electron-dist
+
+    npm exec electron-builder -- \
+        --dir \
+        -c.npmRebuild=true \
+        -c.asarUnpack="**/*.node" \
+        -c.electronDist=electron-dist \
+        -c.electronVersion=${electron.version}
+  '';
+
+  patches = [ ./001-disable-auto-update.patch ];
+
+  installPhase = ''
+    runHook preInstall
+
+    ${lib.optionalString stdenv.hostPlatform.isLinux ''
+      mkdir -p $out/share/caprine
+      cp -r dist/*-unpacked/{locales,resources{,.pak}} $out/share/caprine
+
+      makeWrapper ${lib.getExe electron} $out/bin/caprine \
+          --add-flags $out/share/caprine/resources/app.asar \
+          --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations --enable-wayland-ime=true}}" \
+          --set-default ELECTRON_IS_DEV 0 \
+          --inherit-argv0
+
+      install -Dm644 build/icon.png $out/share/icons/hicolor/512x512/apps/caprine.png
+    ''}
+
+    ${lib.optionalString stdenv.hostPlatform.isDarwin ''
+      mkdir -p $out/Applications
+      cp -r dist/mac*/"Caprine.app" $out/Applications
+      makeWrapper "$out/Applications/Caprine.app/Contents/MacOS/Caprine" $out/bin/caprine
+    ''}
+
+    runHook postInstall
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "caprine";
+      exec = "caprine %U";
+      icon = "caprine";
+      desktopName = "Caprine";
+      comment = meta.description;
+      categories = [
+        "Network"
+        "InstantMessaging"
+        "Chat"
+      ];
+      mimeTypes = [ "x-scheme-handler/caprine" ];
+      terminal = false;
+    })
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    changelog = "https://github.com/sindresorhus/caprine/releases/tag/${src.rev}";
+    description = "Elegant Facebook Messenger desktop app";
+    homepage = "https://github.com/sindresorhus/caprine";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      astronaut0212
+      khaneliman
+    ];
+    inherit (electron.meta) platforms;
+  };
+}