push sheeet

pkgs/by-name/ca/caprine-bin/build-from-appimage.nix

@@ -0,0 +1,43 @@
+{
+  fetchurl,
+  appimageTools,
+  xorg,
+  pname,
+  version,
+  sha256,
+  metaCommon ? { },
+}:
+
+let
+  src = fetchurl {
+    url = "https://github.com/sindresorhus/caprine/releases/download/v${version}/Caprine-${version}.AppImage";
+    name = "Caprine-${version}.AppImage";
+    inherit sha256;
+  };
+  extracted = appimageTools.extractType2 { inherit pname version src; };
+in
+(appimageTools.wrapType2 {
+  inherit pname version src;
+
+  passthru = {
+    inherit pname version src;
+  };
+
+  profile = ''
+    export LC_ALL=C.UTF-8
+  '';
+
+  extraInstallCommands = ''
+    mkdir -p $out/share
+    "${xorg.lndir}/bin/lndir" -silent "${extracted}/usr/share" "$out/share"
+    ln -s ${extracted}/caprine.png $out/share/icons/caprine.png
+    mkdir $out/share/applications
+    cp ${extracted}/caprine.desktop $out/share/applications/
+    substituteInPlace $out/share/applications/caprine.desktop \
+        --replace AppRun caprine
+  '';
+
+  meta = metaCommon // {
+    platforms = [ "x86_64-linux" ];
+  };
+})

pkgs/by-name/ca/caprine-bin/build-from-dmg.nix

@@ -0,0 +1,35 @@
+{
+  stdenvNoCC,
+  lib,
+  fetchurl,
+  undmg,
+  pname,
+  version,
+  sha256,
+  metaCommon ? { },
+}:
+
+stdenvNoCC.mkDerivation {
+  inherit pname version;
+
+  src = fetchurl {
+    url = "https://github.com/sindresorhus/caprine/releases/download/v${version}/Caprine-${version}.dmg";
+    name = "Caprine-${version}.dmg";
+    inherit sha256;
+  };
+
+  sourceRoot = "Caprine.app";
+
+  nativeBuildInputs = [ undmg ];
+
+  installPhase = ''
+    mkdir -p "$out/Applications/Caprine.app"
+    cp -R . "$out/Applications/Caprine.app"
+    mkdir "$out/bin"
+    ln -s "$out/Applications/Caprine.app/Contents/MacOS/Caprine" "$out/bin/caprine"
+  '';
+
+  meta = metaCommon // {
+    platforms = with lib.platforms; darwin;
+  };
+}

pkgs/by-name/ca/caprine-bin/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  callPackage,
+  stdenvNoCC,
+}:
+let
+  pname = "caprine";
+  version = "2.59.1";
+  metaCommon = with lib; {
+    description = "Elegant Facebook Messenger desktop app";
+    homepage = "https://sindresorhus.com/caprine";
+    license = licenses.mit;
+    maintainers = with maintainers; [ ShamrockLee ];
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+  };
+  x86_64-appimage = callPackage ./build-from-appimage.nix {
+    inherit pname version metaCommon;
+    sha256 = "sha256-stMv4KQoWPmK5jcfdhamC27Rb51zjbeEn40u6YUvXz4=";
+  };
+  x86_64-dmg = callPackage ./build-from-dmg.nix {
+    inherit pname version metaCommon;
+    sha256 = "sha256-WMT4yrLjDSMsI/lFbYODu3/0whcF+++4ShoChfMyLfQ=";
+  };
+in
+(if stdenvNoCC.hostPlatform.isDarwin then x86_64-dmg else x86_64-appimage).overrideAttrs
+  (oldAttrs: {
+    passthru = (oldAttrs.passthru or { }) // {
+      inherit x86_64-appimage x86_64-dmg;
+    };
+    meta = oldAttrs.meta // {
+      platforms = x86_64-appimage.meta.platforms ++ x86_64-dmg.meta.platforms;
+      mainProgram = "caprine";
+    };
+  })