push sheeet

pkgs/by-name/cb/cbatticon/package.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  gettext,
+  glib,
+  gtk3,
+  libnotify,
+  wrapGAppsHook3,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cbatticon";
+  version = "1.6.13";
+
+  src = fetchFromGitHub {
+    owner = "valr";
+    repo = "cbatticon";
+    rev = version;
+    sha256 = "sha256-VQjJujF9lnVvQxV+0YqodLgnI9F90JKDAGBu5nM/Q/c=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    gettext
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    glib
+    gtk3
+    libnotify
+  ];
+
+  patchPhase = ''
+    sed -i -e 's/ -Wno-format//g' Makefile
+  '';
+
+  makeFlags = [ "PREFIX=${placeholder "out"}" ];
+
+  meta = with lib; {
+    description = "Lightweight and fast battery icon that sits in the system tray";
+    mainProgram = "cbatticon";
+    homepage = "https://github.com/valr/cbatticon";
+    license = licenses.gpl2;
+    platforms = platforms.linux;
+    maintainers = [ ];
+  };
+}

pkgs/by-name/cb/cbc/package.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  bzip2,
+  cgl,
+  clp,
+  pkg-config,
+  zlib,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cbc";
+  version = "2.10.12";
+
+  src = fetchFromGitHub {
+    owner = "coin-or";
+    repo = "Cbc";
+    tag = "releases/${finalAttrs.version}";
+    sha256 = "sha256-0Sz4/7CRKrArIUy/XxGIP7WMmICqDJ0VxZo62thChYQ=";
+  };
+
+  # or-tools has a hard dependency on Cbc static libraries, so we build both
+  configureFlags = [
+    "-C"
+    "--enable-static"
+  ]
+  ++ lib.optionals stdenv.cc.isClang [ "CXXFLAGS=-std=c++14" ];
+
+  nativeBuildInputs = [ pkg-config ];
+
+  enableParallelBuilding = true;
+
+  hardeningDisable = [ "format" ];
+
+  buildInputs = [
+    bzip2
+    zlib
+  ];
+
+  # cbc lists cgl and clp in its .pc requirements, so it needs to be propagated.
+  propagatedBuildInputs = [
+    cgl
+    clp
+  ];
+
+  # FIXME: move share/coin/Data to a separate output?
+
+  meta = {
+    homepage = "https://projects.coin-or.org/Cbc";
+    license = lib.licenses.epl10;
+    maintainers = [ ];
+    platforms = lib.platforms.linux ++ lib.platforms.darwin;
+    description = "Mixed integer programming solver";
+  };
+})

pkgs/by-name/cb/cbconvert/gui.nix

@@ -0,0 +1,49 @@
+{
+  buildGoModule,
+  cbconvert,
+  gtk3,
+  pkg-config,
+  versionCheckHook,
+  wrapGAppsHook3,
+}:
+
+buildGoModule rec {
+  pname = "cbconvert-gui";
+
+  inherit (cbconvert)
+    patches
+    src
+    tags
+    version
+    ;
+
+  nativeBuildInputs = [
+    pkg-config
+    wrapGAppsHook3
+  ];
+  buildInputs = cbconvert.buildInputs ++ [ gtk3 ];
+
+  vendorHash = "sha256-oMW5zfAw2VQSVaB+Z1pE51OtNIFr+PnRMM+oBYNLWxk=";
+  modRoot = "cmd/cbconvert-gui";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.appVersion=${version}"
+  ];
+
+  postInstall = ''
+    install -D --mode=0644 --target-directory=$out/share/icons/hicolor/256x256/apps dist/linux/io.github.gen2brain.cbconvert.png
+    install -D --mode=0644 --target-directory=$out/share/applications/ dist/linux/io.github.gen2brain.cbconvert.desktop
+    install -D --mode=0644 --target-directory=$out/share/metainfo dist/linux/io.github.gen2brain.cbconvert.metainfo.xml
+    install -D --mode=0644 --target-directory=$out/share/thumbnailers dist/linux/io.github.gen2brain.cbconvert.thumbnailer
+  '';
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "version";
+
+  meta = cbconvert.meta // {
+    mainProgram = "cbconvert-gui";
+  };
+}

pkgs/by-name/cb/cbconvert/package.nix

@@ -0,0 +1,62 @@
+{
+  buildGoModule,
+  bzip2,
+  callPackage,
+  fetchFromGitHub,
+  lib,
+  libunarr,
+  mupdf-headless,
+  nix-update-script,
+  versionCheckHook,
+  zlib,
+}:
+
+buildGoModule rec {
+  pname = "cbconvert";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "gen2brain";
+    repo = "cbconvert";
+    rev = "v${version}";
+    hash = "sha256-C2Eox6fpKS0fPB7KFgBn62HKbWYacSVMJK0CkT6+FBU=";
+  };
+
+  vendorHash = "sha256-uV8aIUKy9HQdZvR3k8CTTrHsh9TyBw21gFTdjR1XJlg=";
+  modRoot = "cmd/cbconvert";
+
+  # The extlib tag forces the github.com/gen2brain/go-unarr module to use external libraries instead of bundled ones.
+  tags = [ "extlib" ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.appVersion=${version}"
+  ];
+
+  buildInputs = [
+    bzip2
+    libunarr
+    mupdf-headless
+    zlib
+  ];
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "version";
+
+  passthru = {
+    gui = callPackage ./gui.nix { };
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Comic Book converter";
+    homepage = "https://github.com/gen2brain/cbconvert";
+    changelog = "https://github.com/gen2brain/cbconvert/releases/tag/v${version}";
+    license = with lib.licenses; [ gpl3Only ];
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ jwillikers ];
+    mainProgram = "cbconvert";
+  };
+}

pkgs/by-name/cb/cbeams/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  python3Packages,
+  fetchPypi,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "cbeams";
+  version = "1.0.3";
+  pyproject = true;
+
+  disabled = !python3Packages.isPy3k;
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-8Q2sWsAc39Mu34K1wWOKOJERKzBStE4GmtuzOs2T7Kk=";
+  };
+
+  build-system = [ python3Packages.setuptools ];
+
+  postPatch = ''
+    substituteInPlace cbeams/terminal.py \
+      --replace-fail "blessings" "blessed"
+  '';
+
+  pythonRemoveDeps = [ "blessings" ];
+
+  dependencies = with python3Packages; [
+    blessed
+    docopt
+  ];
+
+  doCheck = false; # no tests
+
+  meta = {
+    homepage = "https://github.com/tartley/cbeams";
+    description = "Command-line program to draw animated colored circles in the terminal";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [
+      oxzi
+      sigmanificient
+    ];
+  };
+}

pkgs/by-name/cb/cbfmt/package.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  testers,
+  cbfmt,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "cbfmt";
+  version = "0.2.0";
+
+  src = fetchFromGitHub {
+    owner = "lukas-reineke";
+    repo = "cbfmt";
+    rev = "v${version}";
+    sha256 = "sha256-/ZvL1ZHXcmE1n+hHvJeSqmnI9nSHJ+zM9lLNx0VQfIE=";
+  };
+
+  cargoHash = "sha256-C1FpwC1JsKOkS59xAcwqpmZ2g7rr+HHRdADURLs+9co=";
+
+  passthru.tests.version = testers.testVersion {
+    package = cbfmt;
+  };
+
+  meta = with lib; {
+    description = "Tool to format codeblocks inside markdown and org documents";
+    mainProgram = "cbfmt";
+    homepage = "https://github.com/lukas-reineke/cbfmt";
+    license = licenses.mit;
+    maintainers = [ maintainers.stehessel ];
+  };
+}

pkgs/by-name/cb/cbftp/package.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  ncurses,
+  openssl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cbftp";
+  version = "1173";
+
+  src = fetchurl {
+    url = "https://cbftp.eu/${pname}-r${version}.tar.gz";
+    hash = "sha256-DE6fnLzWsx6Skz2LRJAaijjIqrYFB8/HPp45P5CcEc8=";
+  };
+
+  buildInputs = [
+    ncurses
+    openssl
+  ];
+
+  dontConfigure = true;
+
+  makeFlags = lib.optional stdenv.hostPlatform.isDarwin "OPTFLAGS=-O0";
+
+  installPhase = ''
+    runHook preInstall
+
+    install -D bin/* -t $out/bin/
+    install -D API README -t $out/share/doc/${pname}/
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://cbftp.eu/";
+    description = "Advanced multi-purpose FTP/FXP client";
+    longDescription = ''
+      Cbftp is an advanced multi-purpose FTP/FXP client that focuses on
+      efficient large-scale data spreading, while also supporting most regular
+      FTP/FXP use cases in a modern way. It runs in a terminal and provides a
+      semi-graphical user interface through ncurses.
+    '';
+    license = licenses.mit;
+    maintainers = [ ];
+    platforms = with platforms; unix;
+  };
+}

pkgs/by-name/cb/cbmbasic/package.nix

@@ -0,0 +1,69 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  runCommand,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cbmbasic";
+  version = "0-unstable-2022-12-18";
+
+  src = fetchFromGitHub {
+    owner = "mist64";
+    repo = "cbmbasic";
+    rev = "352a313313dd0a15a47288c8f8031b54ac8c92a2";
+    hash = "sha256-aA/ivRap+aDd2wi6KWXam9eP/21lOn6OWTeZ4i/S9Bs=";
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin/
+    mv cbmbasic $out/bin/
+
+    runHook postInstall
+  '';
+
+  # NOTE: cbmbasic uses microsoft style linebreaks `\r\n`, and testing has to
+  # accommodate that, else you get very cryptic diffs
+  passthru = {
+    tests.run =
+      runCommand "cbmbasic-test-run"
+        {
+          nativeBuildInputs = [ finalAttrs.finalPackage ];
+        }
+        ''
+          echo '#!${lib.getExe finalAttrs.finalPackage}' > helloI.bas;
+          echo 'PRINT"Hello, World!"' >> helloI.bas;
+          chmod +x helloI.bas
+
+          diff -U3 --color=auto <(./helloI.bas) <(echo -e "Hello, World!\r");
+
+          echo '#!/usr/bin/env cbmbasic' > hello.bas;
+          echo 'PRINT"Hello, World!"' >> hello.bas;
+          chmod +x hello.bas
+
+          diff -U3 --color=auto <(cbmbasic ./hello.bas) <(echo -e "Hello, World!\r");
+
+          touch $out;
+        '';
+  };
+
+  meta = with lib; {
+    description = "Portable version of Commodore's version of Microsoft BASIC 6502 as found on the Commodore 64";
+    longDescription = ''
+      "Commodore BASIC" (cbmbasic) is a 100% compatible version of Commodore's
+      version of Microsoft BASIC 6502 as found on the Commodore 64. You can use
+      it in interactive mode or pass a BASIC file as a command line parameter.
+
+      This source does not emulate 6502 code; all code is completely native. On
+      a 1 GHz CPU you get about 1000x speed compared to a 1 MHz 6502.
+    '';
+    homepage = "https://github.com/mist64/cbmbasic";
+    license = licenses.bsd2;
+    maintainers = [ maintainers.cafkafk ];
+    mainProgram = "cbmbasic";
+    platforms = platforms.all;
+  };
+})

pkgs/by-name/cb/cbmc-viewer/package.nix

@@ -0,0 +1,30 @@
+{
+  lib,
+  python3Packages,
+  fetchPypi,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "cbmc-viewer";
+  version = "3.8";
+  pyproject = true;
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-JFL06z7lJWZxTALovDBVwNJWenWPUQV9J0qZz3Ek6gI=";
+  };
+
+  propagatedBuildInputs = with python3Packages; [
+    setuptools
+    jinja2
+    voluptuous
+  ];
+
+  meta = {
+    description = "Produces browsable summary of CBMC model checker output";
+    homepage = "https://github.com/model-checking/cbmc-viewer";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ jacg ];
+    mainProgram = "cbmc-viewer";
+  };
+}

pkgs/by-name/cb/cbmc/0001-Do-not-download-sources-in-cmake.patch

@@ -0,0 +1,26 @@
+From 7b49a436bd5cc903b86b01f1a0f046ab8ec99fdb Mon Sep 17 00:00:00 2001
+From: wxt <3264117476@qq.com>
+Date: Mon, 11 Nov 2024 11:07:37 +0800
+Subject: [PATCH] Do not download sources in cmake
+
+---
+ CMakeLists.txt | 3 +--
+ 1 file changed, 1 insertion(+), 2 deletions(-)
+
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 2c1289a..8128362 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -116,8 +116,7 @@ if(DEFINED CMAKE_USE_CUDD)
+     include("${CMAKE_CURRENT_SOURCE_DIR}/cmake/DownloadProject.cmake")
+     message(STATUS "Downloading Cudd-3.0.0")
+     download_project(PROJ cudd
+-            URL https://sourceforge.net/projects/cudd-mirror/files/cudd-3.0.0.tar.gz/download
+-            URL_MD5 4fdafe4924b81648b908881c81fe6c30
++            SOURCE_DIR @cudd@
+             )
+ 
+     if(NOT EXISTS ${cudd_SOURCE_DIR}/Makefile)
+-- 
+2.47.0
+

pkgs/by-name/cb/cbmc/0002-Do-not-download-sources-in-cmake.patch

@@ -0,0 +1,53 @@
+From c6b6438d3c87ce000b4e80b2eda2389e9473d24c Mon Sep 17 00:00:00 2001
+From: wxt <3264117476@qq.com>
+Date: Mon, 11 Nov 2024 11:35:03 +0800
+Subject: [PATCH] Do not download sources in cmake
+
+---
+ src/solvers/CMakeLists.txt | 9 +++------
+ 1 file changed, 3 insertions(+), 6 deletions(-)
+
+diff --git a/src/solvers/CMakeLists.txt b/src/solvers/CMakeLists.txt
+index ab8d111..d7165e2 100644
+--- a/src/solvers/CMakeLists.txt
++++ b/src/solvers/CMakeLists.txt
+@@ -102,10 +102,9 @@ foreach(SOLVER ${sat_impl})
+         message(STATUS "Building solvers with glucose")
+ 
+         download_project(PROJ glucose
+-            URL https://github.com/BrunoDutertre/glucose-syrup/archive/0bb2afd3b9baace6981cbb8b4a1c7683c44968b7.tar.gz
++            SOURCE_DIR @srcglucose@
+             PATCH_COMMAND patch -p1 -i ${CBMC_SOURCE_DIR}/scripts/glucose-syrup-patch
+             COMMAND cmake -E copy ${CBMC_SOURCE_DIR}/scripts/glucose_CMakeLists.txt CMakeLists.txt
+-            URL_MD5 7c539c62c248b74210aef7414787323a
+         )
+ 
+         add_subdirectory(${glucose_SOURCE_DIR} ${glucose_BINARY_DIR})
+@@ -121,11 +120,10 @@ foreach(SOLVER ${sat_impl})
+         message(STATUS "Building solvers with cadical")
+ 
+         download_project(PROJ cadical
+-            URL https://github.com/arminbiere/cadical/archive/rel-2.0.0.tar.gz
++            SOURCE_DIR @srccadical@
+             PATCH_COMMAND patch -p1 -i ${CBMC_SOURCE_DIR}/scripts/cadical-2.0.0-patch
+             COMMAND cmake -E copy ${CBMC_SOURCE_DIR}/scripts/cadical_CMakeLists.txt CMakeLists.txt
+             COMMAND ./configure
+-            URL_MD5 9fc2a66196b86adceb822a583318cc35
+         )
+ 
+         add_subdirectory(${cadical_SOURCE_DIR} ${cadical_BINARY_DIR})
+@@ -144,10 +142,9 @@ foreach(SOLVER ${sat_impl})
+         message(STATUS "Building with IPASIR solver linking against: CaDiCaL")
+ 
+         download_project(PROJ cadical
+-            URL https://github.com/arminbiere/cadical/archive/rel-2.0.0.tar.gz
++            SOURCE_DIR @srccadical@
+             PATCH_COMMAND patch -p1 -i ${CBMC_SOURCE_DIR}/scripts/cadical-2.0.0-patch
+             COMMAND ./configure
+-            URL_MD5 9fc2a66196b86adceb822a583318cc35
+         )
+ 
+         message(STATUS "Building CaDiCaL")
+-- 
+2.47.0
+

pkgs/by-name/cb/cbmc/package.nix

@@ -0,0 +1,124 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  bison,
+  cadical,
+  cmake,
+  flex,
+  makeWrapper,
+  perl,
+  replaceVars,
+  cudd,
+  nix-update-script,
+  fetchpatch,
+  versionCheckHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cbmc";
+  version = "6.7.1";
+
+  src = fetchFromGitHub {
+    owner = "diffblue";
+    repo = "cbmc";
+    tag = "cbmc-${finalAttrs.version}";
+    hash = "sha256-GUY4Evya0GQksl0R4b01UDSvoxUEOOeq4oOIblmoF5o=";
+  };
+
+  srcglucose = fetchFromGitHub {
+    owner = "brunodutertre";
+    repo = "glucose-syrup";
+    rev = "0bb2afd3b9baace6981cbb8b4a1c7683c44968b7";
+    hash = "sha256-+KrnXEJe7ApSuj936T615DaXOV+C2LlRxc213fQI+Q4=";
+  };
+
+  srccadical =
+    (cadical.override {
+      version = "2.0.0";
+    }).src;
+
+  nativeBuildInputs = [
+    bison
+    cmake
+    flex
+    perl
+    makeWrapper
+  ];
+
+  patches = [
+    (replaceVars ./0001-Do-not-download-sources-in-cmake.patch {
+      cudd = cudd.src;
+    })
+    ./0002-Do-not-download-sources-in-cmake.patch
+  ];
+
+  postPatch = ''
+    # fix library_check.sh interpreter error
+    patchShebangs .
+
+    mkdir -p srccadical
+    cp -r ${finalAttrs.srccadical}/* srccadical
+
+    mkdir -p srcglucose
+    cp -r ${finalAttrs.srcglucose}/* srcglucose
+    find -exec chmod +w {} \;
+
+    substituteInPlace src/solvers/CMakeLists.txt \
+     --replace-fail "@srccadical@" "$PWD/srccadical" \
+     --replace-fail "@srcglucose@" "$PWD/srcglucose"
+  ''
+  + lib.optionalString (!stdenv.cc.isGNU) ''
+    # goto-gcc rely on gcc
+    substituteInPlace "regression/CMakeLists.txt" \
+      --replace-fail "add_subdirectory(goto-gcc)" ""
+  '';
+
+  postInstall = ''
+    # goto-cc expects ls_parse.py in PATH
+    mkdir -p $out/share/cbmc
+    mv $out/bin/ls_parse.py $out/share/cbmc/ls_parse.py
+    chmod +x $out/share/cbmc/ls_parse.py
+    wrapProgram $out/bin/goto-cc \
+      --prefix PATH : "$out/share/cbmc" \
+  '';
+
+  env.NIX_CFLAGS_COMPILE = toString (
+    lib.optionals stdenv.cc.isClang [
+      # fix "argument unused during compilation"
+      "-Wno-unused-command-line-argument"
+      # fix "variable 'plus_overflow' set but not used"
+      "-Wno-error=unused-but-set-variable"
+      # fix "passing no argument for the '...' parameter of a variadic macro is a C++20 extension"
+      "-Wno-error=c++20-extensions"
+    ]
+  );
+
+  # TODO: add jbmc support
+  cmakeFlags = [
+    "-DWITH_JBMC=OFF"
+    "-Dsat_impl=cadical"
+  ];
+
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+  doInstallCheck = true;
+  versionCheckProgram = "${placeholder "out"}/bin/cbmc";
+  versionCheckProgramArg = "--version";
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [
+      "--version-regex"
+      "cbmc-(.*)"
+    ];
+  };
+
+  meta = {
+    description = "Bounded Model Checker for C and C++ programs";
+    homepage = "http://www.cprover.org/cbmc/";
+    license = lib.licenses.bsdOriginal;
+    maintainers = with lib.maintainers; [ jiegec ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/cb/cbmp/package.nix

@@ -0,0 +1,41 @@
+{
+  buildNpmPackage,
+  fetchFromGitHub,
+  lib,
+}:
+
+buildNpmPackage rec {
+  pname = "cbmp";
+  version = "1.1.1";
+
+  # note: updating notes
+  # - use `prefetch-npm-deps` package for src hash
+  # - use `npm install --package-lock-only`
+  #   in the cbmp repo for package-lock generation
+  # - update npmDepsHash
+
+  src = fetchFromGitHub {
+    owner = "ful1e5";
+    repo = "cbmp";
+    rev = "v${version}";
+    hash = "sha256-vOEz2KGJLCiiX+Or9y0JE9UF7sYbwaSCVm5iBv4jIdI=";
+  };
+
+  npmDepsHash = "sha256-zfZAZqnkKwsGkwGgfPvb3me4tFgAofE5H3d23mdAtqY=";
+
+  env = {
+    PUPPETEER_SKIP_DOWNLOAD = true;
+  };
+
+  postPatch = ''
+    cp ${./package-lock.json} package-lock.json
+  '';
+
+  meta = {
+    description = "CLI App for converting cursor svg file to png";
+    homepage = "https://github.com/ful1e5/cbmp";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.mrtnvgr ];
+    mainProgram = "cbmp";
+  };
+}

pkgs/by-name/cb/cbonsai/package.nix

@@ -0,0 +1,41 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitLab,
+  ncurses,
+  pkg-config,
+  nix-update-script,
+  scdoc,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cbonsai";
+  version = "1.4.2";
+
+  src = fetchFromGitLab {
+    owner = "jallbrit";
+    repo = "cbonsai";
+    rev = "v${version}";
+    hash = "sha256-TZb/5DBdWcl54GoZXxz2xYy9dXq5lmJQsOA3C26tjEU=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    scdoc
+  ];
+  buildInputs = [ ncurses ];
+
+  makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
+  installFlags = [ "PREFIX=$(out)" ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = with lib; {
+    description = "Grow bonsai trees in your terminal";
+    mainProgram = "cbonsai";
+    homepage = "https://gitlab.com/jallbrit/cbonsai";
+    license = with licenses; [ gpl3Only ];
+    maintainers = with maintainers; [ manveru ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/cb/cbor-diag/Gemfile

@@ -0,0 +1,2 @@
+source 'https://rubygems.org'
+gem 'cbor-diag'

pkgs/by-name/cb/cbor-diag/Gemfile.lock

@@ -0,0 +1,27 @@
+GEM
+  remote: https://rubygems.org/
+  specs:
+    cbor-canonical (0.1.2)
+    cbor-deterministic (0.1.3)
+    cbor-diag (0.10.2)
+      cbor-canonical
+      cbor-deterministic
+      cbor-packed
+      json_pure
+      neatjson
+      treetop (~> 1)
+    cbor-packed (0.2.2)
+    json_pure (2.8.1)
+    neatjson (0.10.5)
+    polyglot (0.3.5)
+    treetop (1.6.14)
+      polyglot (~> 0.3)
+
+PLATFORMS
+  ruby
+
+DEPENDENCIES
+  cbor-diag
+
+BUNDLED WITH
+   2.7.1

pkgs/by-name/cb/cbor-diag/gemset.nix

@@ -0,0 +1,91 @@
+{
+  cbor-canonical = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "1fhj51s5d9b9spw096sb0p92bgilw9hrsay383563dh913j2jn11";
+      type = "gem";
+    };
+    version = "0.1.2";
+  };
+  cbor-deterministic = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "1w1mg4mn1dhlxlbijxpzja8m8ggrjs0hzkzvnaazw9zm1ji6dpba";
+      type = "gem";
+    };
+    version = "0.1.3";
+  };
+  cbor-diag = {
+    dependencies = [
+      "cbor-canonical"
+      "cbor-deterministic"
+      "cbor-packed"
+      "json_pure"
+      "neatjson"
+      "treetop"
+    ];
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "1w64msy9wdyagcl2rcr7lynmdrazjb8wr6406r47x6k007q8jpd3";
+      type = "gem";
+    };
+    version = "0.10.2";
+  };
+  cbor-packed = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "0sbbz0p17m77xqmh4fv4rwly1cj799hapdsg4h43kwsw8h0rnk8n";
+      type = "gem";
+    };
+    version = "0.2.2";
+  };
+  json_pure = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "1kks889ymaq5xqvj18qamar3il8m3dnnaf6cij0a0kwxp8lpk1va";
+      type = "gem";
+    };
+    version = "2.8.1";
+  };
+  neatjson = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "0wm1lq8yl6rzysh3wg6fa55w5534k6ppiz0qb7jyvdy582mk5i0s";
+      type = "gem";
+    };
+    version = "0.10.5";
+  };
+  polyglot = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "1bqnxwyip623d8pr29rg6m8r0hdg08fpr2yb74f46rn1wgsnxmjr";
+      type = "gem";
+    };
+    version = "0.3.5";
+  };
+  treetop = {
+    dependencies = [ "polyglot" ];
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "1m5fqy7vq6y7bgxmw7jmk7y6pla83m16p7lb41lbqgg53j8x2cds";
+      type = "gem";
+    };
+    version = "1.6.14";
+  };
+}

pkgs/by-name/cb/cbor-diag/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  bundlerApp,
+  bundlerUpdateScript,
+}:
+
+bundlerApp {
+  pname = "cbor-diag";
+
+  gemdir = ./.;
+
+  exes = [
+    "cbor2diag.rb"
+    "cbor2json.rb"
+    "cbor2pretty.rb"
+    "cbor2yaml.rb"
+    "cborseq2diag.rb"
+    "cborseq2json.rb"
+    "cborseq2neatjson.rb"
+    "cborseq2yaml.rb"
+    "diag2cbor.rb"
+    "diag2pretty.rb"
+    "json2cbor.rb"
+    "json2pretty.rb"
+    "pretty2cbor.rb"
+    "pretty2diag.rb"
+    "yaml2cbor.rb"
+  ];
+
+  passthru.updateScript = bundlerUpdateScript "cbor-diag";
+
+  meta = with lib; {
+    description = "CBOR diagnostic utilities";
+    homepage = "https://github.com/cabo/cbor-diag";
+    license = with licenses; asl20;
+    maintainers = with maintainers; [
+      fdns
+      nicknovitski
+      amesgen
+    ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/cb/cbrowser/backslashes-quotes.diff

@@ -0,0 +1,49 @@
+Based on this:
+http://sourceforge.net/tracker/?func=detail&aid=1493886&group_id=5152&atid=305152
+fix the infinite loops in quote highlight - ID: 1493886
+
+--- cbrowser-0.8-2/ftcllib.tcl	2000-07-04 01:17:43.000000000 +0200
++++ cbrowser-0.8/ftcllib.tcl	2006-05-24 00:39:18.833762522 +0200
+@@ -1290,13 +1290,39 @@
+   foreach {start end} [concat 1.0 [$widget tag ranges comment] end] {
+ 
+     while {[set temp [$widget search -regexp -- $pattern $start $end]] != ""} {
++      set startquote [$widget index "$temp + 1chars"]
+ 
+-      set endquote [$widget search -regexp -- {[^\\]\"} "$temp + 1chars" $end]
++      set temp [$widget index "$startquote + 1chars"]
++      while {1==1} {
++        set endquote [$widget search -regexp -- {\"} $temp $end]
++
++	# The program will not break if a /*C comment*/ is between C quotes.
++	if { $endquote == "" } {
++	  set endquote $startquote
++	  break
++	}
++
++        # look for double backslashes
++	if {[set temp2 [$widget search -regexp -- {\\\\} $temp $endquote]] != ""} {
++	  set temp "$temp2 + 2chars"
++	  continue
++	}
++        
++        # look for \"
++	if {[set temp2 [$widget search -regexp -- {\\\"} $temp $endquote]] != ""} {
++	  set temp "$temp2 + 2chars"
++	  continue
++	}
++
++	break
++      }
+ 
+       if {[strlen $endquote] > 0} {
+-        set start [$widget index "$endquote + 2chars"]
++        set start [$widget index "$endquote + 1chars"]
+ 
+-        $widget tag add quote "$temp + 1chars" $start
++        $widget tag add quote $startquote $start
++      } else {
++        set start [$widget index "$start + 1chars"]
+       }
+     }
+   }

pkgs/by-name/cb/cbrowser/package.nix

@@ -0,0 +1,43 @@
+{
+  fetchurl,
+  lib,
+  stdenv,
+  tk,
+  makeWrapper,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cbrowser";
+  version = "0.8";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/${pname}/${pname}-${version}.tar.gz";
+    sha256 = "1050mirjab23qsnq3lp3a9vwcbavmh9kznzjm7dr5vkx8b7ffcji";
+  };
+
+  patches = [ ./backslashes-quotes.diff ];
+
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [ tk ];
+
+  installPhase = ''
+    mkdir -p $out/bin $out/share/${pname}-${version}
+    cp -R * $out/share/${pname}-${version}/
+
+    makeWrapper $out/share/${pname}-${version}/cbrowser $out/bin/cbrowser \
+      --prefix PATH : ${tk}/bin
+  '';
+
+  meta = {
+    description = "Tcl/Tk GUI front-end to cscope";
+    mainProgram = "cbrowser";
+
+    license = lib.licenses.gpl2Plus;
+
+    homepage = "https://sourceforge.net/projects/cbrowser/";
+
+    maintainers = [ ];
+
+    platforms = with lib.platforms; linux;
+  };
+}

pkgs/by-name/cb/cbtemulator/package.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  runCommand,
+  cbtemulator,
+  google-cloud-bigtable-tool,
+}:
+
+buildGoModule rec {
+  pname = "cbtemulator";
+  version = "1.29.0";
+
+  src = fetchFromGitHub {
+    owner = "googleapis";
+    repo = "google-cloud-go";
+    rev = "bigtable/v${version}";
+    hash = "sha256-prDwy65pxWDrIJOURe2JHo4sY4yP8IE1Rp1pLUL/IAA=";
+  };
+
+  # There's a go.{mod,sum} in the root and in the "bigtable" subdir.
+  # We only ever use things in that subdir.
+  sourceRoot = "${src.name}/bigtable";
+  env.GOWORK = "off";
+
+  vendorHash = "sha256-EDfxT56LKEu/iXPp5RJXb4UIRV2jFFNxh3ZINPbwKTM=";
+
+  subPackages = [ "cmd/emulator" ];
+
+  postInstall = ''
+    mv $out/bin/emulator $out/bin/cbtemulator
+  '';
+
+  passthru = {
+    # Sets up a table and family, then inserts, and ensures it gets back the value.
+    tests.smoketest =
+      runCommand "cbtemulator-smoketest"
+        {
+          nativeBuildInputs = [ google-cloud-bigtable-tool ];
+        }
+        ''
+          # Start the emulator
+          ${lib.getExe cbtemulator} &
+          EMULATOR_PID=$!
+
+          cleanup() {
+            kill $EMULATOR_PID
+          }
+
+          trap cleanup EXIT
+
+          export BIGTABLE_EMULATOR_HOST=localhost:9000
+
+          cbt -instance instance-1 -project project-1 createtable table-1
+          cbt -instance instance-1 -project project-1 createfamily table-1 cf1
+          cbt -instance instance-1 -project project-1 ls table-1
+          cbt -instance instance-1 -project project-1 set table-1 key1 cf1:c1=value1
+
+          cbt -instance instance-1 -project project-1 read table-1 | grep -q value1
+
+          touch $out;
+        '';
+  };
+
+  meta = with lib; {
+    description = "In-memory Google Cloud Bigtable server";
+    homepage = "https://github.com/googleapis/google-cloud-go/blob/bigtable/v${version}/bigtable/cmd/emulator/cbtemulator.go";
+    license = licenses.asl20;
+    maintainers = [ maintainers.flokli ];
+    mainProgram = "cbtemulator";
+    platforms = platforms.all;
+  };
+}