push sheeet

pkgs/by-name/cg/cg3/package.nix

@@ -0,0 +1,70 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  runCommand,
+  dieHook,
+  cmake,
+  icu,
+  boost,
+  pkg-config,
+  sqlite,
+  cg3,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cg3";
+  version = "1.5.1";
+
+  src = fetchFromGitHub {
+    owner = "GrammarSoft";
+    repo = "cg3";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-R3ePghkr4m6FmiHfhPVdLRAJaipIBhGLOX0Hz1nNPv4=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    icu
+    boost
+    sqlite
+  ];
+
+  doCheck = true;
+
+  postFixup = ''
+    substituteInPlace "$out"/lib/pkgconfig/cg3.pc \
+      --replace-fail '=''${prefix}//' '=/'
+  '';
+
+  passthru.tests.minimal =
+    runCommand "cg3-test"
+      {
+        buildInputs = [
+          cg3
+          dieHook
+        ];
+      }
+      ''
+        echo 'DELIMITERS = "."; ADD (tag) (*);' >grammar.cg3
+        printf '"<a>"\n\t"a" tag\n\n' >want.txt
+        printf '"<a>"\n\t"a"\n\n' | vislcg3 -g grammar.cg3 >got.txt
+        diff -s want.txt got.txt || die "Grammar application did not produce expected parse"
+        touch $out
+      '';
+
+  # TODO, consider optionals:
+  # - Enable tcmalloc unless darwin?
+  # - Enable python bindings?
+  meta = {
+    homepage = "https://github.com/GrammarSoft/cg3";
+    description = "Constraint Grammar interpreter, compiler and applicator vislcg3";
+    maintainers = with lib.maintainers; [ unhammer ];
+    license = lib.licenses.gpl3Plus;
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/cg/cgal/5.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  cmake,
+  boost,
+  gmp,
+  mpfr,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cgal";
+  version = "5.6.2";
+
+  src = fetchurl {
+    url = "https://github.com/CGAL/cgal/releases/download/v${version}/CGAL-${version}.tar.xz";
+    hash = "sha256-RY9g346PHy/a2TyPJOGqj0sJXMYaFPrIG5BoDXMGpC4=";
+  };
+
+  # note: optional component libCGAL_ImageIO would need zlib and opengl;
+  #   there are also libCGAL_Qt{3,4} omitted ATM
+  buildInputs = [
+    boost
+    gmp
+    mpfr
+  ];
+  nativeBuildInputs = [ cmake ];
+
+  patches = [ ./cgal_path.patch ];
+
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Computational Geometry Algorithms Library";
+    homepage = "http://cgal.org";
+    license = with licenses; [
+      gpl3Plus
+      lgpl3Plus
+    ];
+    platforms = platforms.all;
+    maintainers = [ maintainers.raskin ];
+  };
+}

pkgs/by-name/cg/cgal/cgal_path.patch

@@ -0,0 +1,15 @@
+--- Installation/cmake/modules/CGALConfig_install.cmake.in.original	2019-07-10 10:39:12.377022659 -0700
++++ Installation/cmake/modules/CGALConfig_install.cmake.in	2019-07-10 10:47:24.310154928 -0700
+@@ -45,9 +45,9 @@
+ set(CGAL_SHARED_LINKER_FLAGS_DEBUG_INIT   "@CMAKE_SHARED_LINKER_FLAGS_DEBUG@" )
+ set(CGAL_BUILD_TYPE_INIT                  "@CMAKE_BUILD_TYPE@" )
+
+-set(CGAL_INCLUDE_DIRS  "${CGAL_INSTALL_PREFIX}/@CGAL_INSTALL_INC_DIR@" )
+-set(CGAL_MODULES_DIR   "${CGAL_INSTALL_PREFIX}/@CGAL_INSTALL_CMAKE_DIR@" )
+-set(CGAL_LIBRARIES_DIR "${CGAL_INSTALL_PREFIX}/@CGAL_INSTALL_LIB_DIR@" )
++set(CGAL_INCLUDE_DIRS  "@CGAL_INSTALL_INC_DIR@" )
++set(CGAL_MODULES_DIR   "@CGAL_INSTALL_CMAKE_DIR@" )
++set(CGAL_LIBRARIES_DIR "@CGAL_INSTALL_LIB_DIR@" )
+
+ # If CGAL_ImageIO is built, tell if it was linked with Zlib.
+ set(CGAL_ImageIO_USE_ZLIB                 "@CGAL_ImageIO_USE_ZLIB@" )

pkgs/by-name/cg/cgal/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  cmake,
+  boost,
+  gmp,
+  mpfr,
+  testers,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cgal";
+  version = "6.0.2";
+
+  src = fetchurl {
+    url = "https://github.com/CGAL/cgal/releases/download/v${finalAttrs.version}/CGAL-${finalAttrs.version}.tar.xz";
+    sha256 = "sha256-8wxb58JaKj6iS8y6q1z2P6/aY8AnnzTX5/izISgh/tY=";
+  };
+
+  patches = [ ./cgal_path.patch ];
+
+  nativeBuildInputs = [ cmake ];
+
+  # note: optional component libCGAL_ImageIO would need zlib and opengl;
+  #   there are also libCGAL_Qt{3,4} omitted ATM
+  buildInputs = [
+    gmp
+    mpfr
+  ];
+
+  propagatedBuildInputs = [
+    boost
+  ];
+
+  doCheck = false;
+
+  passthru = {
+    tests = {
+      cmake-config = testers.hasCmakeConfigModules {
+        moduleNames = [ "CGAL" ];
+        package = finalAttrs.finalPackage;
+      };
+    };
+  };
+
+  meta = {
+    description = "Computational Geometry Algorithms Library";
+    homepage = "http://cgal.org";
+    license = with lib.licenses; [
+      gpl3Plus
+      lgpl3Plus
+    ];
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [
+      raskin
+      drew-dirac
+      ylannl
+    ];
+  };
+})

pkgs/by-name/cg/cgdb/gcc14.patch

@@ -0,0 +1,13 @@
+diff --git a/configure b/configure
+index c564dc1..e13c67c 100755
+--- a/configure
++++ b/configure
+@@ -6512,7 +6512,7 @@ else
+ #include <stdlib.h>
+ #include <readline/readline.h>
+ 
+-main()
++int main()
+ {
+ 	FILE *fp;
+ 	fp = fopen("conftest.rlv", "w");

pkgs/by-name/cg/cgdb/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  flex,
+  ncurses,
+  readline,
+  texinfo,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cgdb";
+  version = "0.8.0";
+
+  src = fetchurl {
+    url = "https://cgdb.me/files/cgdb-${finalAttrs.version}.tar.gz";
+    sha256 = "sha256-DTi1JNN3JXsQa61thW2K4zBBQOHuJAhTQ+bd8bZYEfE=";
+  };
+
+  patches = [
+    ./gcc14.patch
+  ];
+
+  buildInputs = [
+    ncurses
+    readline
+  ];
+
+  nativeBuildInputs = [
+    flex
+    texinfo
+  ];
+
+  strictDeps = true;
+
+  meta = with lib; {
+    description = "Curses interface to gdb";
+    mainProgram = "cgdb";
+
+    homepage = "https://cgdb.github.io/";
+
+    license = licenses.gpl2Plus;
+
+    platforms = with platforms; linux ++ cygwin;
+    maintainers = [ ];
+  };
+})

pkgs/by-name/cg/cgif/package.nix

@@ -0,0 +1,32 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  lib,
+  meson,
+  ninja,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cgif";
+  version = "0.5.0";
+
+  src = fetchFromGitHub {
+    owner = "dloebl";
+    repo = "cgif";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-i8xngmVhRCGkczY3NzomLkXj+iqPb81lvLn6dXsByYs=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+  ];
+
+  meta = {
+    homepage = "https://github.com/dloebl/cgif";
+    description = "GIF encoder written in C";
+    license = lib.licenses.mit;
+    maintainers = [ ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/cg/cgiserver/package.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  buildGoModule,
+  fetchzip,
+  zstd,
+}:
+
+buildGoModule rec {
+  pname = "cgiserver";
+  version = "1.0.0";
+
+  src = fetchzip {
+    url = "https://src.anomalous.eu/cgiserver/snapshot/cgiserver-${version}.tar.zst";
+    nativeBuildInputs = [ zstd ];
+    hash = "sha256-uIrOZbHzxAdUJF12MBOzRUA6mSPvOKJ/K9ZwwLVId5E=";
+  };
+
+  vendorHash = "sha256-mygMtVbNWwtIkxTGxMnuAMUU0mp49NZ50B9d436nWgI=";
+
+  meta = with lib; {
+    homepage = "https://src.anomalous.eu/cgiserver/about/";
+    description = "Lightweight web server for sandboxing CGI applications";
+    mainProgram = "cgiserver";
+    maintainers = with maintainers; [ qyliss ];
+    license = licenses.osl3;
+  };
+}

pkgs/by-name/cg/cgl/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  clp,
+  coin-utils,
+  osi,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cgl";
+  version = "0.60.9";
+
+  src = fetchFromGitHub {
+    owner = "coin-or";
+    repo = "Cgl";
+    rev = "releases/${finalAttrs.version}";
+    hash = "sha256-E84yCrgpRMjt7owPLPk1ATW+aeHNw8V24DHgkb6boIE=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    clp
+    coin-utils
+    osi
+  ];
+
+  meta = with lib; {
+    description = "Cut Generator Library";
+    homepage = "https://github.com/coin-or/Cgl";
+    license = licenses.epl20;
+    maintainers = with maintainers; [ wegank ];
+    platforms = platforms.unix;
+  };
+})

pkgs/by-name/cg/cglm/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cglm";
+  version = "0.9.6";
+
+  src = fetchFromGitHub {
+    owner = "recp";
+    repo = "cglm";
+    rev = "v${version}";
+    sha256 = "sha256-caDw9Sqf4hS2JNbNxG/xaFIvO6oIlvT+hZQhdX37BKw=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace '\$'{prefix}/'$'{CMAKE_INSTALL_LIBDIR} '$'{CMAKE_INSTALL_FULL_LIBDIR} \
+      --replace '\$'{prefix}/'$'{CMAKE_INSTALL_INCLUDEDIR} '$'{CMAKE_INSTALL_FULL_INCLUDEDIR}
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/recp/cglm";
+    description = "Highly Optimized Graphics Math (glm) for C";
+    license = licenses.mit;
+    maintainers = [ ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/cg/cgminer/package.nix

@@ -0,0 +1,79 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  libtool,
+  autoconf,
+  automake,
+  curl,
+  ncurses,
+  ocl-icd,
+  opencl-headers,
+  libusb1,
+  xorg,
+  jansson,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cgminer";
+  version = "4.11.1";
+
+  src = fetchFromGitHub {
+    owner = "ckolivas";
+    repo = "cgminer";
+    rev = "v${version}";
+    sha256 = "0l1ms3nxnjzh4mpiadikvngcr9k3jnjqy3yna207za0va0c28dj5";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    autoconf
+    automake
+  ];
+  buildInputs = [
+    libtool
+    curl
+    ncurses
+    ocl-icd
+    opencl-headers
+    xorg.libX11
+    xorg.libXext
+    xorg.libXinerama
+    jansson
+    libusb1
+  ];
+
+  configureScript = "./autogen.sh";
+  configureFlags = [
+    "--enable-scrypt"
+    "--enable-opencl"
+    "--enable-bitforce"
+    "--enable-icarus"
+    "--enable-modminer"
+    "--enable-ztex"
+    "--enable-avalon"
+    "--enable-klondike"
+    "--enable-keccak"
+    "--enable-bflsc"
+  ];
+
+  # Workaround build failure on -fno-common toolchains like upstream
+  # gcc-10. Otherwise build fails as:
+  #   ld: cgminer-driver-modminer.o:/build/source/miner.h:285:
+  #     multiple definition of `bitforce_drv'; cgminer-cgminer.o:/build/source/miner.h:285:
+  #     first defined here
+  env.NIX_CFLAGS_COMPILE = "-fcommon";
+
+  meta = with lib; {
+    description = "CPU/GPU miner in c for bitcoin";
+    mainProgram = "cgminer";
+    homepage = "https://github.com/ckolivas/cgminer";
+    license = licenses.gpl3;
+    maintainers = with maintainers; [
+      offline
+      mmahut
+    ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/cg/cgns/package.nix

@@ -0,0 +1,77 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  gfortran,
+  tk,
+  hdf5,
+  xorg,
+  libGLU,
+  withTools ? false,
+  testers,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cgns";
+  version = "4.5.0";
+
+  src = fetchFromGitHub {
+    owner = "cgns";
+    repo = "cgns";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-lPbXIC+O4hTtacxUcyNjZUWpEwo081MjEWhfIH3MWus=";
+  };
+
+  postPatch = ''
+    substituteInPlace src/cgnstools/tkogl/tkogl.c \
+      --replace-fail "<tk-private/generic/tkInt.h>" "<tkInt.h>"
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    gfortran
+  ];
+
+  buildInputs = [
+    hdf5
+  ]
+  ++ lib.optionals withTools [
+    tk
+    xorg.libXmu
+    libGLU
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "CGNS_ENABLE_FORTRAN" true)
+    (lib.cmakeBool "CGNS_ENABLE_LEGACY" true)
+    (lib.cmakeBool "CGNS_ENABLE_HDF5" true)
+    (lib.cmakeBool "HDF5_NEED_MPI" hdf5.mpiSupport)
+    (lib.cmakeBool "CGNS_BUILD_CGNSTOOLS" withTools)
+    (lib.cmakeBool "CGNS_ENABLE_TESTS" finalAttrs.finalPackage.doCheck)
+    (lib.cmakeBool "CGNS_BUILD_SHARED" (!stdenv.hostPlatform.isStatic))
+  ];
+
+  doCheck = true;
+
+  enableParallelChecking = false;
+
+  # Remove broken .desktop files
+  postFixup = ''
+    rm -f $out/bin/*.desktop
+  '';
+
+  passthru.tests.cmake-config = testers.hasCmakeConfigModules {
+    moduleNames = [ "cgns" ];
+    package = finalAttrs.finalPackage;
+  };
+
+  meta = {
+    description = "CFD General Notation System standard library";
+    homepage = "https://cgns.github.io";
+    downloadPage = "https://github.com/cgns/cgns";
+    changelog = "https://github.com/cgns/cgns/releases/tag/${finalAttrs.src.tag}";
+    license = with lib.licenses; [ zlib ];
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ qbisi ];
+  };
+})

pkgs/by-name/cg/cgoban/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  temurin-jre-bin-17,
+  fetchurl,
+  makeWrapper,
+}:
+stdenv.mkDerivation {
+  pname = "cgoban";
+  version = "3.5.144";
+
+  nativeBuildInputs = [
+    temurin-jre-bin-17
+    makeWrapper
+  ];
+
+  src = fetchurl {
+    url = "https://web.archive.org/web/20240314222506/https://files.gokgs.com/javaBin/cgoban.jar";
+    hash = "sha256-ehN/aQU23ZEtDh/+r3H2PDPBrWhgoMfgEfKq5q08kFY=";
+  };
+
+  dontConfigure = true;
+  dontUnpack = true;
+  dontBuild = true;
+  dontPatchELF = true;
+
+  installPhase = ''
+    runHook preInstall
+    install -D $src $out/lib/cgoban.jar
+    makeWrapper ${temurin-jre-bin-17}/bin/java $out/bin/cgoban --add-flags "-jar $out/lib/cgoban.jar"
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Client for the KGS Go Server";
+    mainProgram = "cgoban";
+    homepage = "https://www.gokgs.com/";
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    license = licenses.free;
+    maintainers = with maintainers; [ savannidgerinel ];
+    platforms = temurin-jre-bin-17.meta.platforms;
+  };
+}

pkgs/by-name/cg/cgreen/package.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cgreen";
+  version = "1.6.4";
+
+  src = fetchFromGitHub {
+    owner = "cgreen-devs";
+    repo = "cgreen";
+    rev = finalAttrs.version;
+    sha256 = "sha256-W4MdB3acZcxavjRupJa4eXAv9g4QgYXFAQWOLoHrQZ8=";
+  };
+
+  postPatch = ''
+    for F in tools/discoverer_acceptance_tests.c tools/discoverer.c; do
+      substituteInPlace "$F" --replace "/usr/bin/nm" "nm"
+    done
+  '';
+
+  nativeBuildInputs = [ cmake ];
+
+  meta = {
+    homepage = "https://github.com/cgreen-devs/cgreen";
+    description = "Modern Unit Test and Mocking Framework for C and C++";
+    mainProgram = "cgreen-runner";
+    license = lib.licenses.isc;
+    maintainers = [ ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/cg/cgt-calc/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  fetchFromGitHub,
+  python3Packages,
+  withTeXLive ? true,
+  texliveSmall,
+}:
+python3Packages.buildPythonApplication rec {
+  pname = "cgt-calc";
+  version = "1.13.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "KapJI";
+    repo = "capital-gains-calculator";
+    rev = "v${version}";
+    hash = "sha256-y/Y05wG89nccXyxfjqazyPJhd8dOkfwRJre+Rzx97Hw=";
+  };
+
+  build-system = with python3Packages; [
+    poetry-core
+  ];
+
+  dependencies = with python3Packages; [
+    defusedxml
+    jinja2
+    pandas
+    requests
+    types-requests
+    yfinance
+  ];
+
+  makeWrapperArgs = lib.optionals withTeXLive [
+    "--prefix"
+    "PATH"
+    ":"
+    "${lib.getBin texliveSmall}/bin"
+  ];
+
+  meta = with lib; {
+    description = "UK capital gains tax calculator";
+    homepage = "https://github.com/KapJI/capital-gains-calculator";
+    license = licenses.mit;
+    mainProgram = "cgt-calc";
+    maintainers = with maintainers; [ ambroisie ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/cg/cgterm/package.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  SDL,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cg-term";
+  version = "1.7b2";
+
+  src = fetchFromGitHub {
+    owner = "MagerValp";
+    repo = "CGTerm";
+    rev = "01e35d64c29bccee52211b0afc66035a10e4792a"; # no tags
+    hash = "sha256-Gk7t9wnVCRWwnqcItS3j031VqJnBqk6rHw1SABtzqfE=";
+  };
+
+  buildInputs = [
+    SDL
+  ];
+
+  makeFlags = [
+    "CC:=$(CC)"
+    "PREFIX=$(out)"
+  ];
+
+  meta = with lib; {
+    description = "C/G telnet client for C64 BBS's";
+    homepage = "https://github.com/MagerValp/CGTerm";
+    license = licenses.bsd2;
+    maintainers = with maintainers; [ matthewcroughan ];
+    mainProgram = "cg-term";
+    platforms = platforms.all;
+  };
+})

pkgs/by-name/cg/cgui/package.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  texinfo,
+  allegro,
+  perl,
+  libX11,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cgui";
+  version = "2.1.0";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/project/cgui/${version}/${pname}-${version}.tar.gz";
+    sha256 = "1pp1hvidpilq37skkmbgba4lvzi01rasy04y0cnas9ck0canv00s";
+  };
+
+  buildInputs = [
+    texinfo
+    allegro
+    perl
+    libX11
+  ];
+
+  configurePhase = ''
+    runHook preConfigure
+
+    sh fix.sh unix
+
+    runHook postConfigure
+  '';
+
+  hardeningDisable = [ "format" ];
+
+  makeFlags = [ "SYSTEM_DIR=$(out)" ];
+
+  meta = with lib; {
+    description = "Multiplatform basic GUI library";
+    maintainers = [ maintainers.raskin ];
+    platforms = platforms.linux;
+    license = licenses.free;
+  };
+}