push sheeet

pkgs/by-name/ch/chafa/package.nix

@@ -0,0 +1,88 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  installShellFiles,
+  autoconf,
+  automake,
+  libtool,
+  pkg-config,
+  which,
+  libavif,
+  libjxl,
+  librsvg,
+  libxslt,
+  libxml2,
+  docbook_xml_dtd_412,
+  docbook_xsl,
+  glib,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  version = "1.16.2";
+  pname = "chafa";
+
+  src = fetchFromGitHub {
+    owner = "hpjansson";
+    repo = "chafa";
+    tag = finalAttrs.version;
+    hash = "sha256-bIFPnbciaog9piqBMSpe9zLwH7irp5CW1WG5frAMqpI=";
+  };
+
+  outputs = [
+    "bin"
+    "dev"
+    "man"
+    "out"
+  ];
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+    libtool
+    pkg-config
+    which
+    libxslt
+    libxml2
+    docbook_xml_dtd_412
+    docbook_xsl
+    installShellFiles
+  ];
+
+  buildInputs = [
+    glib
+    libavif
+    libjxl
+    librsvg
+  ];
+
+  patches = [ ./xmlcatalog_patch.patch ];
+
+  preConfigure = ''
+    substituteInPlace ./autogen.sh --replace pkg-config '$PKG_CONFIG'
+    NOCONFIGURE=1 ./autogen.sh
+  '';
+
+  configureFlags = [
+    "--enable-man"
+    "--with-xml-catalog=${docbook_xml_dtd_412}/xml/dtd/docbook/catalog.xml"
+  ];
+
+  postInstall = ''
+    installShellCompletion --cmd chafa \
+      --fish tools/completions/fish-completion.fish \
+      --zsh tools/completions/zsh-completion.zsh
+  '';
+
+  meta = {
+    description = "Terminal graphics for the 21st century";
+    homepage = "https://hpjansson.org/chafa/";
+    license = lib.licenses.lgpl3Plus;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [
+      mog
+      prince213
+    ];
+    mainProgram = "chafa";
+  };
+})

pkgs/by-name/ch/chafa/xmlcatalog_patch.patch

@@ -0,0 +1,23 @@
+diff --git a/configure.ac b/configure.ac
+index 0055a70..fd4a905 100644
+--- a/configure.ac
++++ b/configure.ac
+@@ -111,18 +111,6 @@ AS_IF([ test "$enable_man" != no ], [
+   ])
+ ])
+ 
+-AS_IF([test "$enable_man" != no], [
+-  dnl check for DocBook XSL stylesheets in the local catalog
+-  JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
+-     [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
+-  AS_IF([ test "$have_docbook_style" != yes ], [
+-    AS_IF([ test "$enable_man" = yes ], [
+-      AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
+-    ])
+-    enable_man=no
+-  ])
+-])
+-
+ AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
+ 
+ AC_MSG_CHECKING([whether to generate man pages])