push sheeet

pkgs/by-name/ck/ckan/package.nix

@@ -0,0 +1,93 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  makeWrapper,
+  mono,
+  gtk2,
+  curl,
+  imagemagick,
+  copyDesktopItems,
+  makeDesktopItem,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ckan";
+  version = "1.36.0";
+
+  src = fetchurl {
+    url = "https://github.com/KSP-CKAN/CKAN/releases/download/v${version}/ckan.exe";
+    hash = "sha256-Tw8s86FtBz/92uq2imFZm4n88NCCpePTpydoAoYsE3U=";
+  };
+
+  icon = fetchurl {
+    url = "https://raw.githubusercontent.com/KSP-CKAN/CKAN/450e2f960e1a3fee4ab7cf74ad56bddc5296fc7e/assets/ckan-256.png";
+    hash = "sha256-BJvuOz8NWmzpYzzhveeq6rcuqXIxQqxtBIcRvobx+TY=";
+  };
+
+  dontUnpack = true;
+
+  nativeBuildInputs = [
+    copyDesktopItems
+    imagemagick
+    makeWrapper
+  ];
+
+  buildInputs = [ mono ];
+
+  libraries = lib.makeLibraryPath [
+    gtk2
+    curl
+  ];
+
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+    for size in 16 24 48 64 96 128 256; do
+      mkdir -p $out/share/icons/hicolor/"$size"x"$size"/apps
+      magick -background none ${icon} -resize "$size"x"$size" $out/share/icons/hicolor/"$size"x"$size"/apps/${pname}.png
+    done
+    install -m 644 -D $src $out/bin/ckan.exe
+    makeWrapper ${mono}/bin/mono $out/bin/ckan \
+      --add-flags $out/bin/ckan.exe \
+      --set LD_LIBRARY_PATH $libraries
+    runHook postInstall
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "ckan";
+      comment = "The Comprehensive Kerbal Archive Network Client";
+      desktopName = "CKAN";
+      categories = [
+        "Game"
+        "PackageManager"
+      ];
+      exec = "ckan";
+      icon = "ckan";
+      keywords = [
+        "Kerbal Space Program"
+        "KSP"
+        "Mod"
+      ];
+      extraConfig.X-GNOME-SingleWindow = "true";
+    })
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = with lib; {
+    description = "Mod manager for Kerbal Space Program";
+    mainProgram = "ckan";
+    homepage = "https://github.com/KSP-CKAN/CKAN";
+    license = licenses.mit;
+    maintainers = with maintainers; [
+      Baughn
+      ymarkus
+      nullcube
+    ];
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/ck/ckbcomp/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  perl,
+  xkeyboard_config,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ckbcomp";
+  version = "1.242";
+
+  src = fetchFromGitLab {
+    domain = "salsa.debian.org";
+    owner = "installer-team";
+    repo = "console-setup";
+    rev = version;
+    sha256 = "sha256-5PV1Mbg7ZGQsotwnBVz8DI77Y8ULCnoTANqBLlP3YrE=";
+  };
+
+  buildInputs = [ perl ];
+
+  patchPhase = ''
+    substituteInPlace Keyboard/ckbcomp --replace "/usr/share/X11/xkb" "${xkeyboard_config}/share/X11/xkb"
+    substituteInPlace Keyboard/ckbcomp --replace "rules = 'xorg'" "rules = 'base'"
+  '';
+
+  dontBuild = true;
+
+  installPhase = ''
+    install -Dm0555 -t $out/bin Keyboard/ckbcomp
+    install -Dm0444 -t $out/share/man/man1 man/ckbcomp.1
+  '';
+
+  meta = with lib; {
+    description = "Compiles a XKB keyboard description to a keymap suitable for loadkeys";
+    homepage = "https://salsa.debian.org/installer-team/console-setup";
+    license = licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ dezgeg ];
+    platforms = platforms.unix;
+    mainProgram = "ckbcomp";
+  };
+}

pkgs/by-name/ck/ckdl/package.nix

@@ -0,0 +1,65 @@
+{
+  pkgs,
+  lib,
+  cmake,
+  ninja,
+  sphinx,
+  python3Packages,
+}:
+
+pkgs.stdenv.mkDerivation {
+  pname = "ckdl";
+  version = "1.0";
+
+  src = pkgs.fetchFromGitHub {
+    owner = "tjol";
+    repo = "ckdl";
+    tag = "1.0";
+    hash = "sha256-qEfRZzoUQZ8umdWgx+N4msjPBbuwDtkN1kNDfZicRjY=";
+  };
+
+  outputs = [
+    "bin"
+    "dev"
+    "lib"
+    "doc"
+    "out"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+    sphinx
+    python3Packages.furo
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_TESTS" true)
+  ];
+
+  postPatch = ''
+    cd doc
+    make singlehtml
+    mkdir -p $doc/share/doc
+    mv _build/singlehtml $doc/share/doc/ckdl
+
+    cd ..
+  '';
+
+  postInstall = ''
+    mkdir -p $bin/bin
+
+    # some tools that are important for debugging.
+    # idk why they are not copied to bin by cmake, but I’m too tired to figure it out
+    install src/utils/ckdl-tokenize $bin/bin
+    install src/utils/ckdl-parse-events $bin/bin
+    install src/utils/ckdl-cat $bin/bin
+    touch $out
+  '';
+
+  meta = {
+    description = "C library that implements reading and writing the KDL Document Language";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.all;
+  };
+}

pkgs/by-name/ck/cksfv/package.nix

@@ -0,0 +1,24 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cksfv";
+  version = "1.3.15";
+
+  src = fetchurl {
+    url = "https://zakalwe.fi/~shd/foss/cksfv/files/cksfv-${version}.tar.bz2";
+    sha256 = "0k06aq94cn5xp4knjw0p7gz06hzh622ql2xvnrlr3q8rcmdvwwx1";
+  };
+
+  meta = with lib; {
+    homepage = "https://zakalwe.fi/~shd/foss/cksfv/";
+    description = "Tool for verifying files against a SFV checksum file";
+    maintainers = [ ];
+    platforms = platforms.all;
+    license = licenses.gpl2Plus;
+    mainProgram = "cksfv";
+  };
+}