push sheeet

pkgs/by-name/cw/cw/package.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "cw";
+  version = "4.1.1";
+
+  src = fetchFromGitHub {
+    owner = "lucagrulla";
+    repo = "cw";
+    rev = "v${version}";
+    sha256 = "sha256-JsWwvVEr7kSjUy0S6wVcn24Xyo4OHr5/uqmnjw6v+RI=";
+  };
+
+  vendorHash = "sha256-8L4q0IAvmNk5GCAC5agNfWFtokIkddO1Dec4m6/sWfg=";
+
+  meta = with lib; {
+    description = "Best way to tail AWS CloudWatch Logs from your terminal";
+    homepage = "https://github.com/lucagrulla/cw";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ onthestairs ];
+    mainProgram = "cw";
+  };
+}

pkgs/by-name/cw/cwe-client-cli/package.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  glib,
+  dbus,
+  openssl_3,
+}:
+rustPlatform.buildRustPackage rec {
+  pname = "cwe-client-cli";
+  version = "0.3.3";
+  src = fetchFromGitHub {
+    owner = "NotBalds";
+    repo = "cwe-client-cli";
+    rev = "v${version}";
+    hash = "sha256-3ehzERWV0/hV0Suy9LtCcp+xmaD13Chgu4a0gPT7cHs=";
+  };
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [
+    glib
+    dbus
+    openssl_3
+  ];
+
+  cargoHash = "sha256-ml6anuAJru2zVIHNf/z4gdQjplRrXL4FO44cxfaDRns=";
+
+  meta = {
+    description = "Simple command line client for CWE";
+    homepage = "https://github.com/NotBalds/cwe-client-cli";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ tbwanderer ];
+    mainProgram = "cwe-client-cli";
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/cw/cwebbin/package.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchurl,
+  tie,
+}:
+
+let
+  cweb = fetchurl {
+    url = "https://www.ctan.org/tex-archive/web/c_cpp/cweb/cweb-3.64ah.tgz";
+    sha256 = "1hdzxfzaibnjxjzgp6d2zay8nsarnfy9hfq55hz1bxzzl23n35aj";
+  };
+in
+stdenv.mkDerivation rec {
+  pname = "cwebbin";
+  version = "22p";
+
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "ascherer";
+    repo = "cwebbin";
+    rev = "2016-05-20-22p";
+    sha256 = "0zf93016hm9i74i2v384rwzcw16y3hg5vc2mibzkx1rzvqa50yfr";
+  };
+
+  prePatch = ''
+    tar xf ${cweb}
+  '';
+
+  # Remove references to __DATE__ and __TIME__
+  postPatch = ''
+    substituteInPlace wmerg-patch.ch --replace ' ("__DATE__", "__TIME__")' ""
+    substituteInPlace ctang-patch.ch --replace ' ("__DATE__", "__TIME__")' ""
+    substituteInPlace ctangle.cxx --replace ' ("__DATE__", "__TIME__")' ""
+    substituteInPlace cweav-patch.ch --replace ' ("__DATE__", "__TIME__")' ""
+  '';
+
+  nativeBuildInputs = [ tie ];
+
+  makefile = "Makefile.unix";
+
+  makeFlags = [
+    "MACROSDIR=$(out)/share/texmf/tex/generic/cweb"
+    "CWEBINPUTS=$(out)/lib/cweb"
+    "DESTDIR=$(out)/bin/"
+    "MANDIR=$(out)/share/man/man1"
+    "EMACSDIR=$(out)/share/emacs/site-lisp"
+    "CP=cp"
+    "RM=rm"
+    "PDFTEX=echo"
+    # requires __structuredAttrs = true
+    "CC=$(CXX) -std=c++14"
+  ];
+
+  buildFlags = [
+    "boot"
+    "cautiously"
+  ];
+
+  preInstall = ''
+    mkdir -p $out/share/man/man1 $out/share/texmf/tex/generic $out/share/emacs $out/lib
+  '';
+
+  meta = with lib; {
+    inherit (src.meta) homepage;
+    description = "Literate Programming in C/C++";
+    platforms = with platforms; unix;
+    maintainers = [ ];
+    license = licenses.abstyles;
+  };
+}

pkgs/by-name/cw/cwiid/fix-ar.diff

@@ -0,0 +1,26 @@
+diff --git a/common/include/lib.mak.in b/common/include/lib.mak.in
+index 3afbb14..b8df9d9 100644
+--- a/common/include/lib.mak.in
++++ b/common/include/lib.mak.in
+@@ -22,7 +22,7 @@ static: $(STATIC_LIB)
+ shared: $(SHARED_LIB)
+ 
+ $(STATIC_LIB): $(OBJECTS)
+-	ar rcs $(STATIC_LIB) $(OBJECTS)
++	$(AR) rcs $(STATIC_LIB) $(OBJECTS)
+ 
+ $(SHARED_LIB): $(OBJECTS)
+ 	$(CC) -shared -Wl,-soname,$(SO_NAME) $(LDFLAGS) -o $(SHARED_LIB) \
+diff --git a/configure.ac b/configure.ac
+index 82ca3e1..0a78283 100644
+--- a/configure.ac
++++ b/configure.ac
+@@ -15,6 +15,8 @@ if test "$YACC" != "bison -y"; then
+ 	AC_MSG_ERROR([bison not found])
+ fi
+ 
++AC_CHECK_TOOL([AR], [ar], [:])
++
+ AC_ARG_WITH(
+ 	[python],
+ 	[AS_HELP_STRING([--without-python],[compile without python support])],

pkgs/by-name/cw/cwiid/package.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  bison,
+  flex,
+  bluez,
+  pkg-config,
+  gtk2,
+}:
+
+stdenv.mkDerivation {
+  pname = "cwiid";
+  version = "unstable-2010-02-21";
+
+  src = fetchFromGitHub {
+    owner = "abstrakraft";
+    repo = "cwiid";
+    rev = "fadf11e89b579bcc0336a0692ac15c93785f3f82";
+    sha256 = "0qdb0x757k76nfj32xc2nrrdqd9jlwgg63vfn02l2iznnzahxp0h";
+  };
+
+  hardeningDisable = [ "format" ];
+
+  configureFlags = [ "--without-python" ];
+
+  prePatch = ''
+    sed -i -e '/$(LDCONFIG)/d' common/include/lib.mak.in
+  '';
+
+  patches = [
+    ./fix-ar.diff
+  ];
+
+  buildInputs = [
+    bluez
+    gtk2
+  ];
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+    bison
+    flex
+  ];
+
+  NIX_CFLAGS_COMPILE = "-Wno-error=incompatible-pointer-types";
+  NIX_LDFLAGS = "-lbluetooth";
+
+  postInstall = ''
+    # Some programs (for example, cabal-install) have problems with the double 0
+    sed -i -e "s/0.6.00/0.6.0/" $out/lib/pkgconfig/cwiid.pc
+  '';
+
+  meta = with lib; {
+    description = "Linux Nintendo Wiimote interface";
+    homepage = "http://cwiid.org";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ bennofs ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/cw/cwltool/package.nix

@@ -0,0 +1,110 @@
+{
+  lib,
+  fetchFromGitHub,
+  git,
+  nodejs,
+  python3,
+}:
+
+let
+  py = python3.override {
+    packageOverrides = final: prev: {
+      # Requires "pydot >= 1.4.1, <3",
+      pydot = prev.pydot.overridePythonAttrs (old: rec {
+        version = "2.0.0";
+        src = old.src.override {
+          inherit version;
+          hash = "sha256-YCRq8hUSP6Bi8hzXkb5n3aI6bygN8J9okZ5jeh5PMjU=";
+        };
+        doCheck = false;
+      });
+    };
+  };
+in
+with py.pkgs;
+
+py.pkgs.buildPythonApplication rec {
+  pname = "cwltool";
+  version = "3.1.20250110105449";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "common-workflow-language";
+    repo = "cwltool";
+    tag = version;
+    hash = "sha256-V0CQiNkIw81s6e9224qcfbsOqBvMo34q+lRURpRetKs=";
+  };
+
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace-fail "prov == 1.5.1" "prov" \
+      --replace-fail '"schema-salad >= 8.7, < 9",' '"schema-salad",' \
+      --replace-fail "PYTEST_RUNNER + " ""
+    substituteInPlace pyproject.toml \
+      --replace-fail "mypy==1.14.1" "mypy"
+  '';
+
+  build-system = with py.pkgs; [
+    setuptools
+    setuptools-scm
+  ];
+
+  nativeBuildInputs = [ git ];
+
+  dependencies = with py.pkgs; [
+    argcomplete
+    bagit
+    coloredlogs
+    cwl-utils
+    mypy
+    mypy-extensions
+    prov
+    psutil
+    pydot
+    rdflib
+    requests
+    rich-argparse
+    ruamel-yaml
+    schema-salad
+    shellescape
+    spython
+    toml
+    types-psutil
+    types-requests
+    typing-extensions
+  ];
+
+  nativeCheckInputs = with py.pkgs; [
+    mock
+    nodejs
+    pytest-mock
+    pytest-httpserver
+    pytest-xdist
+    pytestCheckHook
+  ];
+
+  disabledTests = [
+    "test_content_types"
+    "test_env_filtering"
+    "test_http_path_mapping"
+    "test_modification_date"
+  ];
+
+  disabledTestPaths = [
+    "tests/test_udocker.py"
+    "tests/test_provenance.py"
+  ];
+
+  pythonImportsCheck = [
+    "cwltool"
+  ];
+
+  meta = {
+    description = "Common Workflow Language reference implementation";
+    homepage = "https://www.commonwl.org";
+    changelog = "https://github.com/common-workflow-language/cwltool/releases/tag/${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ veprbl ];
+    mainProgram = "cwltool";
+  };
+}

pkgs/by-name/cw/cwm/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  libX11,
+  libXinerama,
+  libXrandr,
+  libXft,
+  bison,
+  pkg-config,
+}:
+
+stdenv.mkDerivation rec {
+
+  pname = "cwm";
+  version = "7.4";
+
+  src = fetchFromGitHub {
+    owner = "leahneukirchen";
+    repo = "cwm";
+    rev = "v${version}";
+    hash = "sha256-L3u4mH2UH2pTHhSPVr5dUi94b9DheslkIWL6EgQ05yA=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    pkg-config
+    bison
+  ];
+  buildInputs = [
+    libX11
+    libXinerama
+    libXrandr
+    libXft
+  ];
+
+  prePatch = ''sed -i "s@/usr/local@$out@" Makefile'';
+
+  meta = with lib; {
+    description = "Lightweight and efficient window manager for X11";
+    homepage = "https://github.com/leahneukirchen/cwm";
+    maintainers = with maintainers; [
+      _0x4A6F
+      mkf
+    ];
+    license = licenses.isc;
+    platforms = platforms.linux;
+    mainProgram = "cwm";
+  };
+}

pkgs/by-name/cw/cwtch-ui/package.nix

@@ -0,0 +1,55 @@
+{
+  cwtch,
+  fetchgit,
+  flutter329,
+  lib,
+  tor,
+}:
+let
+  runtimeBinDependencies = [
+    tor
+  ];
+in
+flutter329.buildFlutterApplication rec {
+  pname = "cwtch-ui";
+  version = "1.16.0";
+  # This Gitea instance has archive downloads disabled, so: fetchgit
+  src = fetchgit {
+    url = "https://git.openprivacy.ca/cwtch.im/cwtch-ui";
+    rev = "v${version}";
+    hash = "sha256-887BiDqu35kocQmren9/rRhLdMNEXPmzsQFAixUvTxo=";
+  };
+
+  pubspecLock = lib.importJSON ./pubspec.json;
+  gitHashes = {
+    flutter_gherkin = "sha256-Y8tR84kkczQPBwh7cGhPFAAqrMZKRfGp/02huPaaQZg=";
+  };
+
+  flutterBuildFlags = [
+    "--dart-define"
+    "BUILD_VER=${version}"
+    "--dart-define"
+    "BUILD_DATE=1980-01-01-00:00"
+  ];
+
+  # These things are added to LD_LIBRARY_PATH, but not PATH
+  runtimeDependencies = [ cwtch ];
+
+  extraWrapProgramArgs = "--prefix PATH : ${lib.makeBinPath runtimeBinDependencies}";
+
+  postInstall = ''
+    mkdir -p $out/share/applications
+    substitute linux/cwtch.template.desktop "$out/share/applications/cwtch.desktop" \
+      --replace-fail PREFIX "$out"
+  '';
+
+  meta = {
+    description = "Messaging app built on the cwtch decentralized, privacy-preserving, multi-party messaging protocol";
+    homepage = "https://cwtch.im/";
+    changelog = "https://docs.cwtch.im/changelog";
+    license = lib.licenses.mit;
+    mainProgram = "cwtch";
+    platforms = [ "x86_64-linux" ];
+    maintainers = [ lib.maintainers.gmacon ];
+  };
+}

pkgs/by-name/cw/cwtch/package.nix

@@ -0,0 +1,53 @@
+{
+  buildGoModule,
+  fetchgit,
+  lib,
+}:
+buildGoModule rec {
+  pname = "libcwtch";
+  version = "0.1.7";
+  # This Gitea instance has archive downloads disabled, so: fetchgit
+  src = fetchgit {
+    url = "https://git.openprivacy.ca/cwtch.im/autobindings.git";
+    rev = "v${version}";
+    hash = "sha256-QHEaf3xm6SIHLnQamf0cUrKJ/A1v0iFaaGsMg33uIBs=";
+  };
+
+  vendorHash = "sha256-pnAdUFG1G0Bi/e9KNVX0WwloJy8xQ25YVFnGerRGy9A=";
+  overrideModAttrs = (
+    old: {
+      preBuild = ''
+        make lib.go
+      '';
+    }
+  );
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace-fail '$(shell git describe --tags)' v${version} \
+      --replace-fail '$(shell git log -1 --format=%cd --date=format:%G-%m-%d-%H-%M)' 1980-01-01-00-00
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+    make libCwtch.so
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -D build/linux/libCwtch.h -t $out/include
+    # * will match either "amd64" or "arm64" depending on the platform.
+    install -D build/linux/*/libCwtch.so $out/lib/libCwtch.so
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Decentralized, privacy-preserving, multi-party messaging protocol";
+    homepage = "https://cwtch.im/";
+    changelog = "https://docs.cwtch.im/changelog";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.gmacon ];
+  };
+}