push sheeet

pkgs/by-name/dg/dgen-sdl/package.nix

@@ -0,0 +1,75 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  libarchive,
+  SDL,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "dgen-sdl";
+  version = "1.33";
+
+  src = fetchurl {
+    url = "https://sourceforge.net/projects/dgen/files/dgen/${version}/${pname}-${version}.tar.gz";
+    hash = "sha256-meLAYBfCKHPHf4gYbrzAmGckTrbgQsdjuwlLArje9h4=";
+  };
+
+  buildInputs = [
+    SDL
+    libarchive
+  ];
+
+  configureFlags = [
+    (lib.enableFeature (!stdenv.hostPlatform.isDarwin) "sdltest")
+    "--enable-debug-vdp"
+    "--enable-debugger"
+    "--enable-joystick"
+    "--enable-pico" # experimental
+    "--enable-vgmdump"
+    "--with-cyclone=no" # Needs ASM support
+    "--with-cz80"
+    "--with-drz80=no" # Needs ASM support
+    "--with-dz80"
+    "--with-musa"
+    "--with-mz80"
+    "--with-star=no" # Needs ASM support
+  ];
+
+  env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.cc.isClang "-Wno-reserved-user-defined-literal";
+
+  meta = with lib; {
+    homepage = "https://dgen.sourceforge.net/";
+    description = "Sega Genesis/Mega Drive emulator";
+    longDescription = ''
+      DGen/SDL is a free, open source emulator for Sega Genesis/Mega Drive
+      systems. DGen was originally written by Dave, then ported to SDL by Joe
+      Groff and Phil K. Hornung in 1998.
+
+      It features:
+
+      - Game Genie/Hex codes support
+      - PAL/NTSC, fullscreen modes
+      - Joypad/joystick support
+      - Mouse support
+      - Highly configurable controls
+      - OpenGL textured video output
+      - Portable (64‐bit, endian safe), runs in Windows using MinGW
+      - Screenshots, demos recording and playback
+      - Musashi (generic) and StarScream (x86‐only) CPU cores
+      - Cyclone 68000 and DrZ80 (both ARM‐only) CPU cores
+      - CZ80 (generic) and MZ80 (generic and x86‐only versions)
+      - 16‐bit, 8000 to 48000Hz sound output
+      - Support for 8, 15, 16, 24 and 32 bpp modes
+      - Archived/compressed ROMs support
+      - M68K debugger (contributed by Edd Barrett)
+      - Z80 debugger
+      - hqx and scale2x upscaling filters
+      - VGM dumping
+    '';
+    license = licenses.mit;
+    maintainers = [ ];
+    platforms = with platforms; unix;
+  };
+}
+# TODO: implement configure options

pkgs/by-name/dg/dgoss/package.nix

@@ -0,0 +1,51 @@
+{
+  bash,
+  coreutils,
+  gnused,
+  goss,
+  lib,
+  resholve,
+  which,
+}:
+
+resholve.mkDerivation rec {
+  pname = "dgoss";
+  version = goss.version;
+  src = goss.src;
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  installPhase = ''
+    sed -i '2i GOSS_PATH=${goss}/bin/goss' extras/dgoss/dgoss
+    install -D extras/dgoss/dgoss $out/bin/dgoss
+  '';
+
+  solutions = {
+    default = {
+      scripts = [ "bin/dgoss" ];
+      interpreter = "${bash}/bin/bash";
+      inputs = [
+        coreutils
+        gnused
+        which
+      ];
+      keep = {
+        "$CONTAINER_RUNTIME" = true;
+      };
+    };
+  };
+
+  meta = {
+    homepage = "https://github.com/goss-org/goss/blob/v${version}/extras/dgoss/README.md";
+    changelog = "https://github.com/goss-org/goss/releases/tag/v${version}";
+    description = "Convenience wrapper around goss that aims to bring the simplicity of goss to docker containers";
+    license = lib.licenses.asl20;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [
+      hyzual
+      anthonyroussel
+    ];
+    mainProgram = "dgoss";
+  };
+}

pkgs/by-name/dg/dgraph/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+  jemalloc,
+  nodejs,
+}:
+
+buildGoModule rec {
+  pname = "dgraph";
+  version = "24.1.4";
+
+  src = fetchFromGitHub {
+    owner = "dgraph-io";
+    repo = "dgraph";
+    rev = "v${version}";
+    sha256 = "sha256-tvzX5pkaad/DrJkFIIjxAIJME9KHi/2KONw6fXcml18=";
+  };
+
+  vendorHash = "sha256-eOo2ihaabdhDRATIc5C4YEMBcA0Xl5xzBKW5GJhrTOA=";
+
+  doCheck = false;
+
+  ldflags = [
+    "-X github.com/dgraph-io/dgraph/x.dgraphVersion=${version}-oss"
+  ];
+
+  tags = [
+    "oss"
+  ];
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  # todo those dependencies are required in the makefile, but verify how they are used
+  # actually
+  buildInputs = [
+    jemalloc
+    nodejs
+  ];
+
+  subPackages = [ "dgraph" ];
+
+  postInstall = ''
+    for shell in bash zsh; do
+      $out/bin/dgraph completion $shell > dgraph.$shell
+      installShellCompletion dgraph.$shell
+    done
+  '';
+
+  meta = with lib; {
+    homepage = "https://dgraph.io/";
+    description = "Fast, Distributed Graph DB";
+    maintainers = with maintainers; [ sigma ];
+    # Apache 2.0 because we use only build "oss"
+    license = licenses.asl20;
+    mainProgram = "dgraph";
+  };
+}