push sheeet

pkgs/by-name/dl/dl-librescore/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  buildNpmPackage,
+  fetchFromGitHub,
+  python3,
+  cctools,
+}:
+
+buildNpmPackage rec {
+  pname = "dl-librescore";
+  version = "0.35.29";
+
+  src = fetchFromGitHub {
+    owner = "LibreScore";
+    repo = "dl-librescore";
+    rev = "v${version}";
+    hash = "sha256-DwDlGTFdqAAsEWrhnieuaeYQ0N8COB/7b49xPJackJQ=";
+  };
+
+  npmDepsHash = "sha256-5Uc83VdqMwQaTSmzwpBh7x4IKoVPd9MYDXkDvR1fz6Q=";
+
+  # see https://github.com/LibreScore/dl-librescore/pull/32
+  # TODO can be removed with next update
+  postPatch = ''
+    substituteInPlace package-lock.json \
+      --replace 50c7a1508cd9358757c30794e14ba777e6faa8aa b4cb32eb1734a2f73ba2d92743647b1a91c0e2a8
+  '';
+
+  makeCacheWritable = true;
+
+  nativeBuildInputs = [
+    python3
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    cctools
+  ];
+
+  meta = {
+    description = "Download sheet music";
+    homepage = "https://github.com/LibreScore/dl-librescore";
+    license = lib.licenses.mit;
+    mainProgram = "dl-librescore";
+    maintainers = [ ];
+  };
+}

pkgs/by-name/dl/dl-poly-classic-mpi/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  gfortran,
+  mpi,
+}:
+
+stdenv.mkDerivation {
+  version = "1.10";
+  pname = "DL_POLY_Classic";
+
+  src = fetchurl {
+    url = "https://ccpforge.cse.rl.ac.uk/gf/download/frsrelease/574/8924/dl_class_1.10.tar.gz";
+    sha256 = "1r76zvln3bwycxlmqday0sqzv5j260y7mdh66as2aqny6jzd5ld7";
+  };
+
+  nativeBuildInputs = [ gfortran ];
+
+  buildInputs = [ mpi ];
+
+  configurePhase = ''
+    runHook preConfigure
+
+    cd source
+    cp -v ../build/MakePAR Makefile
+
+    runHook postConfigure
+  '';
+
+  # https://gitlab.com/DL_POLY_Classic/dl_poly/-/blob/master/README
+  env.NIX_CFLAGS_COMPILE = "-fallow-argument-mismatch";
+
+  buildPhase = ''
+    make dlpoly
+  '';
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp -v ../execute/DLPOLY.X $out/bin
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.ccp5.ac.uk/DL_POLY_C";
+    description = "DL_POLY Classic is a general purpose molecular dynamics simulation package";
+    mainProgram = "DLPOLY.X";
+    license = licenses.bsdOriginal;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.costrouc ];
+  };
+}

pkgs/by-name/dl/dleyna/package.nix

@@ -0,0 +1,57 @@
+{
+  stdenv,
+  lib,
+  docutils,
+  fetchFromGitLab,
+  meson,
+  ninja,
+  pkg-config,
+  gupnp_1_6,
+  gupnp-av,
+  gupnp-dlna,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "dleyna";
+  version = "0.8.3";
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  src = fetchFromGitLab {
+    domain = "gitlab.gnome.org";
+    owner = "World";
+    repo = "dLeyna";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-ti4yF8sALpWyrdQTt/jVrMKQ4PLhakEi620fJNMxT0c=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    docutils
+    pkg-config
+  ];
+
+  buildInputs = [
+    gupnp_1_6
+    gupnp-dlna
+    gupnp-av
+    gupnp-dlna
+  ];
+
+  mesonFlags = [
+    # Sphinx docs not installed, do not depend on sphinx
+    "-Ddocs=false"
+  ];
+
+  meta = {
+    description = "Library of utility functions that are used by the higher level dLeyna";
+    homepage = "https://gitlab.gnome.org/World/dLeyna";
+    maintainers = with lib.maintainers; [ jtojnar ];
+    platforms = lib.platforms.unix;
+    license = lib.licenses.lgpl21Only;
+  };
+})

pkgs/by-name/dl/dli/package.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule {
+  pname = "dli";
+  version = "0-unstable-2025-09-06";
+
+  src = fetchFromGitHub {
+    owner = "haylinmoore";
+    repo = "dli";
+    rev = "176302f80cf771a7a15d9df58c3296a979f18e28";
+    hash = "sha256-I8ozN5ucBhsArehSQibTLlYavq+4rBRUvU42Cli4KVo=";
+  };
+
+  vendorHash = "sha256-kgf/tt1Mr/3ja3or0zL/Mqnwy00XiGj7rdM/MnhjWZw=";
+
+  meta = {
+    description = "CLI based tool for managing DNS records";
+    homepage = "https://github.com/haylinmoore/dli";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.haylin ];
+    mainProgram = "dli";
+  };
+}

pkgs/by-name/dl/dlib/package.nix

@@ -0,0 +1,99 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  libpng,
+  libjpeg,
+  libwebp,
+  blas,
+  lapack,
+  config,
+  guiSupport ? false,
+  libX11,
+  enableShared ? !stdenv.hostPlatform.isStatic, # dlib has a build system that forces the user to choose between either shared or static libraries. See https://github.com/davisking/dlib/issues/923#issuecomment-2175865174
+  sse4Support ? stdenv.hostPlatform.sse4_1Support,
+  avxSupport ? stdenv.hostPlatform.avxSupport,
+  cudaSupport ? config.cudaSupport,
+  cudaPackages,
+}@inputs:
+(if cudaSupport then cudaPackages.backendStdenv else inputs.stdenv).mkDerivation rec {
+  pname = "dlib";
+  version = "20.0";
+
+  src = fetchFromGitHub {
+    owner = "davisking";
+    repo = "dlib";
+    tag = "v${version}";
+    sha256 = "sha256-VTX7s0p2AzlvPUsSMXwZiij+UY9g2y+a1YIge9bi0sw=";
+  };
+
+  postPatch = ''
+    rm -rf dlib/external
+  '';
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_SHARED_LIBS" enableShared)
+    (lib.cmakeBool "USE_SSE4_INSTRUCTIONS" sse4Support)
+    (lib.cmakeBool "USE_AVX_INSTRUCTIONS" avxSupport)
+    (lib.cmakeBool "DLIB_USE_CUDA" cudaSupport)
+  ]
+  ++ lib.optionals (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) [
+    (lib.cmakeBool "USE_NEON_INSTRUCTIONS" false)
+  ]
+  ++ lib.optionals cudaSupport [
+    (lib.cmakeFeature "DLIB_USE_CUDA_COMPUTE_CAPABILITIES" (
+      builtins.concatStringsSep "," (with cudaPackages.flags; map dropDots cudaCapabilities)
+    ))
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ]
+  ++ lib.optionals cudaSupport (
+    with cudaPackages;
+    [
+      cuda_nvcc
+    ]
+  );
+
+  buildInputs = [
+    libpng
+    libjpeg
+    libwebp
+    blas
+    lapack
+  ]
+  ++ lib.optionals guiSupport [ libX11 ]
+  ++ lib.optionals cudaSupport (
+    with cudaPackages;
+    [
+      cuda_cudart
+      cuda_nvcc
+      libcublas
+      libcurand
+      libcusolver
+      cudnn
+      cuda_cccl
+    ]
+  );
+
+  passthru = {
+    inherit
+      cudaSupport
+      cudaPackages
+      sse4Support
+      avxSupport
+      ;
+  };
+
+  meta = with lib; {
+    description = "General purpose cross-platform C++ machine learning library";
+    homepage = "http://www.dlib.net";
+    license = licenses.boost;
+    maintainers = with maintainers; [ christopherpoole ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/dl/dlx/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+}:
+
+stdenv.mkDerivation {
+  pname = "dlx";
+  version = "0-unstable-2012-07-08";
+
+  src = fetchzip {
+    url = "https://www.davidviner.com/zip/dlx/dlx.zip";
+    hash = "sha256-r4FlMbfsGH50V502EfqzRwAqVv4vpdyH3zFlZW2kCBQ=";
+  };
+
+  preBuild = ''
+    makeFlagsArray+=(
+      CC="${stdenv.cc.targetPrefix}cc"
+      LINK="${stdenv.cc.targetPrefix}cc"
+      CFLAGS="-O2 -Wno-implicit-function-declaration"
+    )
+  '';
+
+  hardeningDisable = [ "format" ];
+
+  installPhase = ''
+    mkdir -p $out/include/dlx $out/share/dlx/{examples,doc} $out/bin
+    mv masm mon dasm $out/bin/
+    mv *.i auto.a $out/include/dlx/
+    mv *.a *.m $out/share/dlx/examples/
+    mv README.txt MANUAL.TXT $out/share/dlx/doc/
+  '';
+
+  meta = {
+    homepage = "https://www.davidviner.com/dlx.html?name=DLX+Simulator";
+    description = "DLX simulator written in C";
+    license = lib.licenses.gpl2Only;
+    platforms = lib.platforms.linux;
+  };
+}