push sheeet

pkgs/by-name/dr/drogon/fix_find_package.patch

@@ -0,0 +1,13 @@
+diff --git i/test.sh w/test.sh
+index 4796ff11..a6627fec 100755
+--- i/test.sh
++++ w/test.sh
+@@ -148,7 +148,7 @@ function do_drogon_ctl_test()
+                               -DCMAKE_POLICY_DEFAULT_CMP0091=NEW \
+                               -DCMAKE_CXX_STANDARD=17"
+     fi
+-    cmake .. $cmake_gen
++    cmake .. $cmake_gen -DDrogon_DIR=$out/lib/cmake/Drogon -DTrantor_DIR=$out/lib/cmake/Trantor
+ 
+     if [ $? -ne 0 ]; then
+         echo "Failed to run CMake for example project"

pkgs/by-name/dr/drogon/package.nix

@@ -0,0 +1,86 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  jsoncpp,
+  libossp_uuid,
+  zlib,
+  lib,
+  # optional but of negligible size
+  openssl,
+  brotli,
+  c-ares,
+  # optional databases
+  sqliteSupport ? true,
+  sqlite,
+  postgresSupport ? false,
+  libpq,
+  redisSupport ? false,
+  hiredis,
+  mysqlSupport ? false,
+  libmysqlclient,
+  mariadb,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "drogon";
+  version = "1.9.11";
+
+  src = fetchFromGitHub {
+    owner = "drogonframework";
+    repo = "drogon";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-eFOYmqfyb/yp83HRa0hWSMuROozR/nfnEp7k5yx8hj0=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_TESTING" finalAttrs.finalPackage.doInstallCheck)
+    (lib.cmakeBool "BUILD_EXAMPLES" false)
+  ];
+
+  propagatedBuildInputs = [
+    jsoncpp
+    libossp_uuid
+    zlib
+    openssl
+    brotli
+    c-ares
+  ]
+  ++ lib.optional sqliteSupport sqlite
+  ++ lib.optional postgresSupport libpq
+  ++ lib.optional redisSupport hiredis
+  # drogon uses mariadb for mysql (see https://github.com/drogonframework/drogon/wiki/ENG-02-Installation#Library-Dependencies)
+  ++ lib.optionals mysqlSupport [
+    libmysqlclient
+    mariadb
+  ];
+
+  patches = [
+    # this part of the test would normally fail because it attempts to configure a CMake project that uses find_package on itself
+    # this patch makes drogon and trantor visible to the test
+    ./fix_find_package.patch
+  ];
+
+  # modifying PATH here makes drogon_ctl visible to the test
+  installCheckPhase = ''
+    (
+      cd ..
+      PATH=$PATH:$out/bin $SHELL test.sh
+    )
+  '';
+
+  # this excludes you, pkgsStatic (cmake wants to run built binaries
+  # in the buildPhase)
+  doInstallCheck = stdenv.buildPlatform == stdenv.hostPlatform;
+
+  meta = with lib; {
+    homepage = "https://github.com/drogonframework/drogon";
+    description = "C++14/17 based HTTP web application framework";
+    license = licenses.mit;
+    maintainers = with maintainers; [ urlordjames ];
+    platforms = platforms.all;
+  };
+})