push sheeet

pkgs/by-name/ds/dscanner/dub-lock.json

@@ -0,0 +1,32 @@
+{
+  "dependencies": {
+    "dcd": {
+      "version": "0.16.0-beta.2",
+      "sha256": "0756q02q1jbimrqn814b3j7q042vlxb7vva1rq823jx148r23d4d"
+    },
+    "dsymbol": {
+      "version": "0.13.0",
+      "sha256": "1lpwdri2bv5avs3hr0j1i00kjwdbs9nkc13wzlmjalfzjhqqqvci"
+    },
+    "emsi_containers": {
+      "version": "0.9.0",
+      "sha256": "1viz1fjh6jhfvl0d25bb1q7aclm1hrs0d7hhcx1d9c0gg5k6lcpm"
+    },
+    "inifiled": {
+      "version": "1.3.3",
+      "sha256": "01hw0lb9n6vwmx6vj5nq2awg54l5pvngqhzxfj2kmg99az84dg6d"
+    },
+    "libddoc": {
+      "version": "0.8.0",
+      "sha256": "0vxhkd92rxrkrz0svapdnkzh1bdqhws6wakhjj7szmkvykjgwksc"
+    },
+    "libdparse": {
+      "version": "0.23.2",
+      "sha256": "0bcaasam3iiqisilyx4ysxahjmgifn7i8ny155nwg64bjjibd8dk"
+    },
+    "stdx-allocator": {
+      "version": "2.77.5",
+      "sha256": "1g8382wr49sjyar0jay8j7y2if7h1i87dhapkgxphnizp24d7kaj"
+    }
+  }
+}

pkgs/by-name/ds/dscanner/fix_version.patch

@@ -0,0 +1,12 @@
+diff --git a/dub.json b/dub.json
+index 72cb269..1ea3903 100644
+--- a/dub.json
++++ b/dub.json
+@@ -21,7 +21,4 @@
+   "stringImportPaths" : [
+     "bin"
+   ],
+-  "preBuildCommands" : [
+-    "\"$DC\" -run \"$PACKAGE_DIR/dubhash.d\""
+-  ]
+ }

pkgs/by-name/ds/dscanner/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  buildDubPackage,
+  fetchFromGitHub,
+  versionCheckHook,
+}:
+
+buildDubPackage rec {
+  pname = "dscanner";
+  version = "0.15.2";
+
+  src = fetchFromGitHub {
+    owner = "dlang-community";
+    repo = "D-Scanner";
+    tag = "v${version}";
+    hash = "sha256-7lZhYlK07VWpSRnzawJ2RL69/U/AH/qPyQY4VfbnVn4=";
+  };
+
+  preBuild = ''
+    mkdir -p bin/
+    echo "v${version}" > bin/dubhash.txt
+  '';
+
+  patches = [
+    ./fix_version.patch
+  ];
+
+  dubLock = ./dub-lock.json;
+
+  doCheck = true;
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 bin/dscanner -t $out/bin
+    runHook postInstall
+  '';
+
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+
+  doInstallCheck = true;
+
+  meta = {
+    description = "Swiss-army knife for D source code";
+    changelog = "https://github.com/dlang-community/D-Scanner/releases/tag/v${version}";
+    homepage = "https://github.com/dlang-community/D-Scanner";
+    mainProgram = "dscanner";
+    maintainers = with lib.maintainers; [ ipsavitsky ];
+    license = lib.licenses.boost;
+  };
+}

pkgs/by-name/ds/dsda-doom/package.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  SDL2,
+  SDL2_mixer,
+  SDL2_image,
+  fluidsynth,
+  portmidi,
+  libopenmpt,
+  libvorbis,
+  libmad,
+  libGLU,
+  libzip,
+  alsa-lib,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "dsda-doom";
+  version = "0.29.3";
+
+  src = fetchFromGitHub {
+    owner = "kraflab";
+    repo = "dsda-doom";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Nsz9bj+AJomkYOiy5cli+NLmrJKNjYOiXjEZDXnnFNo=";
+  };
+
+  sourceRoot = "${finalAttrs.src.name}/prboom2";
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [
+    alsa-lib
+    libopenmpt
+    fluidsynth
+    libGLU
+    libmad
+    libvorbis
+    libzip
+    portmidi
+    SDL2
+    SDL2_image
+    SDL2_mixer
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://github.com/kraflab/dsda-doom";
+    changelog = "https://github.com/kraflab/dsda-doom/releases/tag/v${finalAttrs.version}";
+    description = "Advanced Doom source port with a focus on speedrunning, successor of PrBoom+";
+    mainProgram = "dsda-doom";
+    license = lib.licenses.gpl2Plus;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ Gliczy ];
+  };
+})

pkgs/by-name/ds/dsda-launcher/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  qt6,
+  nix-update-script,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "dsda-launcher";
+  version = "1.4";
+
+  src = fetchFromGitHub {
+    owner = "Pedro-Beirao";
+    repo = "dsda-launcher";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-OMgxhb+9GdLK00nl/df9QiYYewr+YEjdX2KjQWvu1mk=";
+  };
+
+  nativeBuildInputs = [ qt6.wrapQtAppsHook ];
+
+  buildInputs = [
+    qt6.qtbase
+    qt6.qtwayland
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+    mkdir -p "./src/build"
+    cd "./src/build"
+    qmake6 ..
+    make
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    cp ./dsda-launcher $out/bin
+    install -Dm444 ../icons/dsda-Launcher.desktop $out/share/applications/dsda-Launcher.desktop
+    install -Dm444 ../icons/dsda-launcher.png $out/share/pixmaps/dsda-launcher.png
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://github.com/Pedro-Beirao/dsda-launcher";
+    description = "Launcher GUI for the dsda-doom source port";
+    mainProgram = "dsda-launcher";
+    license = lib.licenses.gpl3;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ Gliczy ];
+  };
+})

pkgs/by-name/ds/dsdcc/package.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  mbelib,
+  serialdv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "dsdcc";
+  version = "1.9.6";
+
+  src = fetchFromGitHub {
+    owner = "f4exb";
+    repo = "dsdcc";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-4wSf4pOEheuhW4ReEDo5i3poiHMC0wgSUk2lXBYWjOs=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    mbelib
+    serialdv
+  ];
+
+  cmakeFlags = [
+    "-DUSE_MBELIB=ON"
+  ];
+
+  postFixup = ''
+    substituteInPlace "$out"/lib/pkgconfig/libdsdcc.pc \
+      --replace '=''${exec_prefix}//' '=/'
+  '';
+
+  meta = {
+    description = "Digital Speech Decoder (DSD) rewritten as a C++ library";
+    homepage = "https://github.com/f4exb/dsdcc";
+    license = lib.licenses.gpl3;
+    mainProgram = "dsdccx";
+    maintainers = with lib.maintainers; [ alexwinter ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/ds/dsf2flac/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  boost,
+  flac,
+  id3lib,
+  pkg-config,
+  taglib,
+  zlib,
+}:
+
+stdenv.mkDerivation {
+  pname = "dsf2flac";
+  version = "0-unstable-2025-01-31";
+
+  src = fetchFromGitHub {
+    owner = "hank";
+    repo = "dsf2flac";
+    rev = "39d43901ce27d0cc53b5a4eb277a65082e9906f0";
+    hash = "sha256-I8BupNE49+9oExR/GhoZUVbCHhDJEz3hhvQnbi8ZVGs=";
+  };
+
+  buildInputs = [
+    boost
+    flac
+    id3lib
+    taglib
+    zlib
+  ];
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+  ];
+
+  enableParallelBuilding = true;
+
+  preConfigure = ''
+    export LIBS="$LIBS -lz -lboost_timer"
+  '';
+
+  configureFlags = [ "--with-boost-libdir=${boost.out}/lib" ];
+
+  meta = {
+    description = "DSD to FLAC transcoding tool";
+    homepage = "https://github.com/hank/dsf2flac";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ artemist ];
+    platforms = [ "x86_64-linux" ];
+    mainProgram = "dsf2flac";
+  };
+}

pkgs/by-name/ds/dsnet/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  buildGoModule,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "dsnet";
+  version = "0.8.1";
+
+  src = fetchFromGitHub {
+    owner = "naggie";
+    repo = "dsnet";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-CKDtILZMWFeSU5nTSguM2fi0BCFdvR2LqELIZ6LYOMk=";
+  };
+  vendorHash = "sha256-Q2Ipj9yZ+/GUBEmDvgwFLLww7EXnbvdvj/shGQnh1G8=";
+
+  subPackages = [ "cmd" ];
+
+  postInstall = ''
+    mv $out/bin/cmd $out/bin/dsnet
+  '';
+
+  # The ldflags reduce the executable size by stripping some debug stuff.
+  # The other variables are set so that the output of dsnet version shows the
+  # git ref and the release version from github.
+  # Ref <https://github.com/NixOS/nixpkgs/pull/87383#discussion_r432097657>
+  ldflags = [
+    "-w"
+    "-s"
+    "-X github.com/naggie/dsnet.VERSION=${finalAttrs.src.tag}"
+    "-X github.com/naggie/dsnet.GIT_COMMIT=${finalAttrs.src.tag}"
+  ];
+
+  meta = {
+    description = "Fast command to manage a centralised Wireguard VPN";
+    homepage = "https://github.com/naggie/dsnet";
+    changelog = "https://github.com/naggie/dsnet/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.naggie ];
+    mainProgram = "dsnet";
+  };
+
+})

pkgs/by-name/ds/dsniff/package.nix

@@ -0,0 +1,116 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitLab,
+  autoreconfHook,
+  libpcap,
+  db,
+  glib,
+  libnet,
+  libnids,
+  symlinkJoin,
+  openssl,
+  rpcsvc-proto,
+  libtirpc,
+  libnsl,
+  libnl,
+}:
+
+let
+  /*
+    dsniff's build system unconditionally wants static libraries and does not
+    support multi output derivations. We do some overriding to give it
+    satisfaction.
+  */
+  staticdb = symlinkJoin {
+    inherit (db) name;
+    paths = with db.overrideAttrs { dontDisableStatic = true; }; [
+      out
+      dev
+    ];
+    postBuild = ''
+      rm $out/lib/*.so*
+    '';
+  };
+  pcap = symlinkJoin {
+    inherit (libpcap) name;
+    paths = [ (libpcap.overrideAttrs { dontDisableStatic = true; }) ];
+    postBuild = ''
+      cp -rs $out/include/pcap $out/include/net
+      # prevent references to libpcap
+      rm $out/lib/*.so*
+    '';
+  };
+  net = symlinkJoin {
+    inherit (libnet) name;
+    paths = [ (libnet.overrideAttrs { dontDisableStatic = true; }) ];
+    postBuild = ''
+      # prevent dynamic linking, now that we have a static library
+      rm $out/lib/*.so*
+    '';
+  };
+  nids = libnids.overrideAttrs {
+    dontDisableStatic = true;
+  };
+  ssl = symlinkJoin {
+    inherit (openssl) name;
+    paths = with openssl.override { static = true; }; [
+      out
+      dev
+    ];
+  };
+in
+stdenv.mkDerivation rec {
+  pname = "dsniff";
+  version = "2.4b1";
+  # upstream is so old that nearly every distribution packages the beta version.
+  # Also, upstream only serves the latest version, so we use debian's sources.
+  # this way we can benefit the numerous debian patches to be able to build
+  # dsniff with recent libraries.
+  src = fetchFromGitLab {
+    domain = "salsa.debian.org";
+    owner = "pkg-security-team";
+    repo = "dsniff";
+    rev = "debian/${version}+debian-34";
+    sha256 = "sha256-CY0+G09KZXtAwKuaYh5/qcmZjuNhdGis3zCG14hWtqw=";
+    name = "dsniff.tar.gz";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    rpcsvc-proto
+  ];
+  buildInputs = [
+    glib
+    pcap
+    libtirpc
+    libnsl
+    libnl
+  ];
+  NIX_CFLAGS_LINK = "-lglib-2.0 -lpthread -ltirpc -lnl-3 -lnl-genl-3";
+  env.NIX_CFLAGS_COMPILE = toString [ "-I${libtirpc.dev}/include/tirpc" ];
+  postPatch = ''
+    for patch in debian/patches/*.patch; do
+      patch < $patch
+    done;
+  '';
+  configureFlags = [
+    "--with-db=${staticdb}"
+    "--with-libpcap=${pcap}"
+    "--with-libnet=${net}"
+    "--with-libnids=${nids}"
+    "--with-openssl=${ssl}"
+  ];
+
+  meta = with lib; {
+    description = "Collection of tools for network auditing and penetration testing";
+    longDescription = ''
+      dsniff, filesnarf, mailsnarf, msgsnarf, urlsnarf, and webspy passively monitor a network for interesting data (passwords, e-mail, files, etc.). arpspoof, dnsspoof, and macof facilitate the interception of network traffic normally unavailable to an attacker (e.g, due to layer-2 switching). sshmitm and webmitm implement active monkey-in-the-middle attacks against redirected SSH and HTTPS sessions by exploiting weak bindings in ad-hoc PKI.
+    '';
+    homepage = "https://www.monkey.org/~dugsong/dsniff/";
+    license = licenses.bsd3;
+    maintainers = [ maintainers.symphorien ];
+    # bsd and solaris should work as well
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/ds/dsp/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  fftw,
+  zita-convolver,
+  fftwFloat,
+  libsndfile,
+  ffmpeg,
+  alsa-lib,
+  libao,
+  libmad,
+  ladspaH,
+  libtool,
+  libpulseaudio,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "dsp";
+  version = "2.0";
+
+  src = fetchFromGitHub {
+    owner = "bmc0";
+    repo = "dsp";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-WUH4+5v1wv6EXTOuRq9iVVZsXMt5DVrtgX8vLE7a8s8=";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    fftw
+    zita-convolver
+    fftwFloat
+    libsndfile
+    ffmpeg
+    alsa-lib
+    libao
+    libmad
+    ladspaH
+    libtool
+    libpulseaudio
+  ];
+
+  meta = {
+    homepage = "https://github.com/bmc0/dsp";
+    description = "Audio processing program with an interactive mode";
+    license = lib.licenses.isc;
+    maintainers = with lib.maintainers; [ aaronjheng ];
+    platforms = lib.platforms.linux;
+    mainProgram = "dsp";
+  };
+})

pkgs/by-name/ds/dspam/mariadb.patch

@@ -0,0 +1,42 @@
+diff -ur dspam-3.10.2.orig/configure dspam-3.10.2/configure
+--- dspam-3.10.2.orig/configure	2012-04-24 02:53:49.000000000 +0900
++++ dspam-3.10.2/configure	2019-05-24 01:59:06.557890494 +0900
+@@ -13280,7 +13280,7 @@
+     #include <mysql.h>
+     #include <mysqld_error.h>
+     #include <errmsg.h>
+-    #if defined(PROTOCOL_VERSION) && defined(ER_LOCK_DEADLOCK) && defined(ER_LOCK_WAIT_TIMEOUT) && defined(ER_LOCK_OR_ACTIVE_TRANSACTION) && defined(CR_ERROR_FIRST)
++    #if defined(PROTOCOL_VERSION) && defined(ER_LOCK_DEADLOCK) && defined(ER_LOCK_WAIT_TIMEOUT) && defined(ER_LOCK_OR_ACTIVE_TRANSACTION) && defined(CR_MIN_ERROR)
+     /* Success */
+     #else
+     #error Unsupported version of MySQL
+@@ -13293,7 +13293,7 @@
+ 
+                 { { $as_echo "$as_me:${as_lineno-$LINENO}: error: in \`$ac_pwd':" >&5
+ $as_echo "$as_me: error: in \`$ac_pwd':" >&2;}
+-as_fn_error $? "Unsupported version of MySQL (no PROTOCOL_VERSION or ER_LOCK_DEADLOCK or ER_LOCK_WAIT_TIMEOUT or ER_LOCK_OR_ACTIVE_TRANSACTION or CR_ERROR_FIRST defined)
++as_fn_error $? "Unsupported version of MySQL (no PROTOCOL_VERSION or ER_LOCK_DEADLOCK or ER_LOCK_WAIT_TIMEOUT or ER_LOCK_OR_ACTIVE_TRANSACTION or CR_MIN_ERROR defined)
+ See \`config.log' for more details" "$LINENO" 5; }
+                 mysql_headers_success=no
+ 
+diff -ur dspam-3.10.2.orig/m4/mysql_drv.m4 dspam-3.10.2/m4/mysql_drv.m4
+--- dspam-3.10.2.orig/m4/mysql_drv.m4	2011-08-17 07:38:30.000000000 +0900
++++ dspam-3.10.2/m4/mysql_drv.m4	2019-05-24 02:00:08.301217506 +0900
+@@ -80,7 +80,7 @@
+     #include <mysql.h>
+     #include <mysqld_error.h>
+     #include <errmsg.h>
+-    #if defined(PROTOCOL_VERSION) && defined(ER_LOCK_DEADLOCK) && defined(ER_LOCK_WAIT_TIMEOUT) && defined(ER_LOCK_OR_ACTIVE_TRANSACTION) && defined(CR_ERROR_FIRST)
++    #if defined(PROTOCOL_VERSION) && defined(ER_LOCK_DEADLOCK) && defined(ER_LOCK_WAIT_TIMEOUT) && defined(ER_LOCK_OR_ACTIVE_TRANSACTION) && defined(CR_MIN_ERROR)
+     /* Success */
+     #else
+     #error Unsupported version of MySQL 
+@@ -88,7 +88,7 @@
+             ]])],
+             [],
+             [
+-                AC_MSG_FAILURE([Unsupported version of MySQL (no PROTOCOL_VERSION or ER_LOCK_DEADLOCK or ER_LOCK_WAIT_TIMEOUT or ER_LOCK_OR_ACTIVE_TRANSACTION or CR_ERROR_FIRST defined)])
++                AC_MSG_FAILURE([Unsupported version of MySQL (no PROTOCOL_VERSION or ER_LOCK_DEADLOCK or ER_LOCK_WAIT_TIMEOUT or ER_LOCK_OR_ACTIVE_TRANSACTION or CR_MIN_ERROR defined)])
+                 mysql_headers_success=no
+             ])
+ fi

pkgs/by-name/ds/dspam/package.nix

@@ -0,0 +1,154 @@
+{
+  stdenv,
+  lib,
+  fetchurl,
+  makeWrapper,
+  gawk,
+  gnused,
+  gnugrep,
+  coreutils,
+  which,
+  perlPackages,
+  withMySQL ? false,
+  zlib,
+  mariadb-connector-c,
+  withPgSQL ? false,
+  libpq,
+  withSQLite ? false,
+  sqlite,
+  withDB ? false,
+  db,
+}:
+
+let
+  drivers = lib.concatStringsSep "," (
+    [ "hash_drv" ]
+    ++ lib.optional withMySQL "mysql_drv"
+    ++ lib.optional withPgSQL "pgsql_drv"
+    ++ lib.optional withSQLite "sqlite3_drv"
+    ++ lib.optional withDB "libdb4_drv"
+  );
+  maintenancePath = lib.makeBinPath [
+    gawk
+    gnused
+    gnugrep
+    coreutils
+    which
+  ];
+
+in
+stdenv.mkDerivation rec {
+  pname = "dspam";
+  version = "3.10.2";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/dspam/dspam/${pname}-${version}/${pname}-${version}.tar.gz";
+    sha256 = "1acklnxn1wvc7abn31l3qdj8q6k13s51k5gv86vka7q20jb5cxmf";
+  };
+  patches = [
+    # https://gist.github.com/WhiteAnthrax/613136c76882e0ead3cb3bdad6b3d551
+    ./mariadb.patch
+  ];
+
+  buildInputs = [
+    perlPackages.perl
+  ]
+  ++ lib.optionals withMySQL [
+    zlib
+    mariadb-connector-c.out
+  ]
+  ++ lib.optional withPgSQL libpq
+  ++ lib.optional withSQLite sqlite
+  ++ lib.optional withDB db;
+  nativeBuildInputs = [
+    libpq.pg_config
+    makeWrapper
+  ];
+  # patch out libmysql >= 5 check, since mariadb-connector is at 3.x
+  postPatch = ''
+    sed -i 's/atoi(m) >= 5/1/g' configure m4/mysql_drv.m4
+  '';
+
+  configureFlags = [
+    "--with-storage-driver=${drivers}"
+    "--sysconfdir=/etc/dspam"
+    "--localstatedir=/var"
+    "--with-dspam-home=/var/lib/dspam"
+    "--with-logdir=/var/log/dspam"
+    "--with-logfile=/var/log/dspam/dspam.log"
+
+    "--enable-daemon"
+    "--enable-clamav"
+    "--enable-syslog"
+    "--enable-large-scale"
+    "--enable-virtual-users"
+    "--enable-split-configuration"
+    "--enable-preferences-extension"
+    "--enable-long-usernames"
+    "--enable-external-lookup"
+  ]
+  ++ lib.optionals withMySQL [
+    "--with-mysql-includes=${mariadb-connector-c.dev}/include/mysql"
+    "--with-mysql-libraries=${mariadb-connector-c.out}/lib/mysql"
+  ];
+
+  # Workaround build failure on -fno-common toolchains like upstream
+  # gcc-10. Otherwise build fails as:
+  #   ld: .libs/hash_drv.o:/build/dspam-3.10.2/src/util.h:96: multiple definition of `verified_user';
+  #     .libs/libdspam.o:/build/dspam-3.10.2/src/util.h:96: first defined here
+  env.NIX_CFLAGS_COMPILE = "-fcommon";
+
+  # Lots of things are hardwired to paths like sysconfdir. That's why we install with both "prefix" and "DESTDIR"
+  # and fix directory structure manually after that.
+  installFlags = [ "DESTDIR=$(out)" ];
+
+  postInstall = ''
+    cp -r $out/$out/* $out
+    rm -rf $out/$(echo "$out" | cut -d "/" -f2)
+    rm -rf $out/var
+
+    wrapProgram $out/bin/dspam_notify \
+      --set PERL5LIB "${perlPackages.makePerlPath [ perlPackages.libnet ]}"
+
+    # Install SQL scripts
+    mkdir -p $out/share/dspam/sql
+    # MySQL
+    cp src/tools.mysql_drv/mysql_*.sql $out/share/dspam/sql
+    for i in src/tools.mysql_drv/{purge*.sql,virtual*.sql}; do
+      cp "$i" $out/share/dspam/sql/mysql_$(basename "$i")
+    done
+    # PostgreSQL
+    cp src/tools.pgsql_drv/pgsql_*.sql $out/share/dspam/sql
+    for i in src/tools.pgsql_drv/{purge*.sql,virtual*.sql}; do
+      cp "$i" $out/share/dspam/sql/pgsql_$(basename "$i")
+    done
+    # SQLite
+    for i in src/tools.sqlite_drv/purge*.sql; do
+      cp "$i" $out/share/dspam/sql/sqlite_$(basename "$i")
+    done
+
+    # Install maintenance script
+    install -Dm755 contrib/dspam_maintenance/dspam_maintenance.sh $out/bin/dspam_maintenance
+    sed -i \
+      -e "2iexport PATH=$out/bin:${maintenancePath}:\$PATH" \
+      -e 's,/usr/[a-z0-9/]*,,g' \
+      -e 's,^DSPAM_CONFIGDIR=.*,DSPAM_CONFIGDIR=/etc/dspam,' \
+      -e "s,^DSPAM_HOMEDIR=.*,DSPAM_HOMEDIR=/var/lib/dspam," \
+      -e "s,^DSPAM_PURGE_SCRIPT_DIR=.*,DSPAM_PURGE_SCRIPT_DIR=$out/share/dspam/sql," \
+      -e "s,^DSPAM_BIN_DIR=.*,DSPAM_BIN_DIR=$out/bin," \
+      -e "s,^MYSQL_BIN_DIR=.*,MYSQL_BIN_DIR=/run/current-system/sw/bin," \
+      -e "s,^PGSQL_BIN_DIR=.*,PGSQL_BIN_DIR=/run/current-system/sw/bin," \
+      -e "s,^SQLITE_BIN_DIR=.*,SQLITE_BIN_DIR=/run/current-system/sw/bin," \
+      -e "s,^SQLITE3_BIN_DIR=.*,SQLITE3_BIN_DIR=/run/current-system/sw/bin," \
+      -e 's,^DSPAM_CRON_LOCKFILE=.*,DSPAM_CRON_LOCKFILE=/run/dspam/dspam_maintenance.pid,' \
+      $out/bin/dspam_maintenance
+  '';
+
+  meta = with lib; {
+    homepage = "https://dspam.sourceforge.net/";
+    description = "Community Driven Antispam Filter";
+    license = licenses.agpl3Plus;
+    platforms = platforms.linux;
+    maintainers = [ ];
+  };
+}

pkgs/by-name/ds/dsq/package.nix

@@ -0,0 +1,67 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildGoModule,
+  nix-update-script,
+  testers,
+  python3,
+  curl,
+  jq,
+  p7zip,
+  dsq,
+}:
+
+buildGoModule rec {
+  pname = "dsq";
+  version = "0.23.0";
+
+  src = fetchFromGitHub {
+    owner = "multiprocessio";
+    repo = "dsq";
+    rev = "v${version}";
+    hash = "sha256-FZBJe+2y4HV3Pgeap4yvD0a8M/j+6pAJEFpoQVVE1ec=";
+  };
+
+  vendorHash = "sha256-MbBR+OC1OGhZZGcZqc+Jzmabdc5ZfFEwzqP5YMrj6mY=";
+
+  ldflags = [
+    "-X"
+    "main.Version=${version}"
+  ];
+
+  nativeCheckInputs = [
+    python3
+    curl
+    jq
+    p7zip
+  ];
+
+  preCheck = ''
+    substituteInPlace scripts/test.py \
+      --replace 'dsq latest' 'dsq ${version}'
+  '';
+
+  checkPhase = ''
+    runHook preCheck
+
+    7z e testdata/taxi.csv.7z
+    cp "$GOPATH/bin/dsq" .
+    python3 scripts/test.py
+
+    runHook postCheck
+  '';
+
+  passthru = {
+    updateScript = nix-update-script { };
+
+    tests.version = testers.testVersion { package = dsq; };
+  };
+
+  meta = with lib; {
+    mainProgram = "dsq";
+    description = "Commandline tool for running SQL queries against JSON, CSV, Excel, Parquet, and more";
+    homepage = "https://github.com/multiprocessio/dsq";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ liff ];
+  };
+}

pkgs/by-name/ds/dsremote/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  libsForQt5,
+}:
+stdenv.mkDerivation {
+  pname = "dsremote";
+  version = "0-unstable-2025-07-07";
+
+  src = fetchFromGitLab {
+    owner = "Teuniz";
+    repo = "DSRemote";
+    rev = "b290debcfecd4fecf2069fb958bd43fe9e5ce5e1";
+    hash = "sha256-7a13T8MwIFDhrXe7xqB84D6MwfTYs1gJj6VWs4JbzEM=";
+  };
+
+  nativeBuildInputs = [
+    libsForQt5.qmake
+    libsForQt5.qt5.wrapQtAppsHook
+    libsForQt5.qt5.qtbase
+  ];
+
+  hardeningDisable = [ "fortify" ];
+
+  postPatch = ''
+    substituteInPlace dsremote.pro \
+      --replace-fail "/usr/" "$out/" \
+      --replace-fail "/etc/" "$out/etc/"
+  '';
+
+  meta = {
+    description = "Rigol DS1000Z remote control and waveform viewer";
+    homepage = "https://www.teuniz.net/DSRemote";
+    license = lib.licenses.gpl3Plus;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ mksafavi ];
+    mainProgram = "dsremote";
+  };
+}

pkgs/by-name/ds/dssat/package.nix

@@ -0,0 +1,74 @@
+{
+  stdenv,
+  lib,
+  cmake,
+  glibc,
+  gfortran,
+  makeWrapper,
+  fetchFromGitHub,
+  fetchpatch,
+  dos2unix,
+  dataRepo ? fetchFromGitHub {
+    owner = "DSSAT";
+    repo = "dssat-csm-data";
+    rev = "v4.8.2.8";
+    hash = "sha256-hbSBKEvdSd1lfbemfp4Lk4/JcGMXGVjm1x7P7lmmuA0=";
+  },
+}:
+let
+  # Temporary patch to fix 80 chars limit on paths
+  # https://github.com/DSSAT/dssat-csm-os/pull/417/
+  charLimitPatch = fetchpatch {
+    url = "https://github.com/DSSAT/dssat-csm-os/pull/417/commits/9215012a297c074f392b5e7eb90b8c20495f13f7.patch";
+    hash = "sha256-WwJR5lnWtR3aYWZmk8pBC0/qaRqY0UrWHIaYp2ajImE=";
+  };
+in
+stdenv.mkDerivation (final: {
+  pname = "dssat";
+  version = "4.8.2.12";
+
+  src = fetchFromGitHub {
+    owner = "DSSAT";
+    repo = "dssat-csm-os";
+    tag = "v${final.version}";
+    hash = "sha256-8OaTM7IXFZjlelx5O4O+bVNQj4dIhGzIk2iCfpqI8uA=";
+  };
+
+  # maintainers are on windows and have CRLF endings in their files
+  # And github returns a patch file in unix format only.
+  patchPhase = ''
+    runHook prePatch
+    cp ${charLimitPatch} ./limit-path.patch
+    unix2dos ./limit-path.patch
+    patch --binary -p1 < ./limit-path.patch
+    runHook postPatch
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    dos2unix
+    gfortran
+    makeWrapper
+  ];
+
+  buildInputs = lib.optionals stdenv.hostPlatform.isLinux [ glibc.static ];
+
+  cmakeFlags = [ "-DCMAKE_INSTALL_PREFIX=${placeholder "out"}/share/dssat/" ];
+
+  postInstall = ''
+    mkdir -p $out/share/dssat/Data
+    cp -r $src/Data/* $out/share/dssat/Data/
+    cp -r ${dataRepo}/* $out/share/dssat/Data/
+    makeWrapper $out/share/dssat/dscsm048 $out/bin/dscsm048
+  '';
+
+  meta = {
+    homepage = "https://github.com/DSSAT/dssat-csm-os";
+    description = "Cropping System Model";
+    mainProgram = "dscsm048";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ pcboy ];
+    platforms = lib.platforms.unix;
+    broken = stdenv.hostPlatform.isAarch64 && stdenv.hostPlatform.isLinux;
+  };
+})

pkgs/by-name/ds/dsseries/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  rpmextract,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libsane-dsseries";
+  version = "1.0.5-1";
+
+  src = fetchurl {
+    url = "https://download.brother.com/welcome/dlf100974/${pname}-${version}.x86_64.rpm";
+    sha256 = "1wfdbfbf51cc7njzikdg48kwpnpc0pg5s6p0s0y3z0q7y59x2wbq";
+  };
+
+  nativeBuildInputs = [ rpmextract ];
+
+  unpackCmd = ''
+    mkdir ${pname}-${version} && pushd ${pname}-${version}
+    rpmextract $curSrc
+    popd
+  '';
+
+  patchPhase = ''
+    substituteInPlace etc/udev/rules.d/50-Brother_DSScanner.rules \
+      --replace 'GROUP="users"' 'GROUP="scanner", ENV{libsane_matched}="yes"'
+
+    mkdir -p etc/sane.d/dll.d
+    echo "dsseries" > etc/sane.d/dll.d/dsseries.conf
+  '';
+
+  installPhase = ''
+    mkdir -p $out
+    cp -dr etc $out
+    cp -dr usr/lib64 $out/lib
+  '';
+
+  preFixup = ''
+    for f in `find $out/lib/sane/ -type f`; do
+      # Make it possible to find libstdc++.so.6
+      patchelf --set-rpath ${lib.getLib stdenv.cc.cc}/lib:$out/lib/sane $f
+
+      # Horrible kludge: The driver hardcodes /usr/lib/sane/ as a dlopen path.
+      # We can directly modify the binary to force a relative lookup instead.
+      # The new path is NULL-padded to the same length as the original path.
+      sed -i "s|/usr/lib/sane/%s|%s\x00\x00\x00\x00\x00\x00\x00\x00\x00\x00\x00\x00\x00\x00|g" $f
+    done
+  '';
+
+  meta = {
+    description = "Brother DSSeries SANE backend driver";
+    homepage = "http://www.brother.com";
+    platforms = lib.platforms.linux;
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    license = lib.licenses.unfree;
+    maintainers = with lib.maintainers; [ callahad ];
+  };
+}

pkgs/by-name/ds/dssi/dssi-liblo.patch

@@ -0,0 +1,22 @@
+diff --git a/jack-dssi-host/jack-dssi-host.c b/jack-dssi-host/jack-dssi-host.c
+index f32ae69..119fe5a 100644
+--- a/jack-dssi-host/jack-dssi-host.c
++++ b/jack-dssi-host/jack-dssi-host.c
+@@ -119,7 +119,7 @@ LADSPA_Data get_port_default(const LADSPA_Descriptor *plugin, int port);
+ void osc_error(int num, const char *m, const char *path);
+ 
+ int osc_message_handler(const char *path, const char *types, lo_arg **argv, int
+-		      argc, void *data, void *user_data) ;
++		      argc, struct lo_message_ *data, void *user_data) ;
+ int osc_debug_handler(const char *path, const char *types, lo_arg **argv, int
+ 		      argc, void *data, void *user_data) ;
+ 
+@@ -1919,7 +1919,7 @@ int osc_debug_handler(const char *path, const char *types, lo_arg **argv,
+ }
+ 
+ int osc_message_handler(const char *path, const char *types, lo_arg **argv,
+-                        int argc, void *data, void *user_data)
++                        int argc, struct lo_message_ *data, void *user_data)
+ {
+     int i;
+     d3h_instance_t *instance = NULL;

pkgs/by-name/ds/dssi/package.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  ladspaH,
+  libjack2,
+  liblo,
+  alsa-lib,
+  libX11,
+  libsndfile,
+  libSM,
+  libsamplerate,
+  libtool,
+  autoconf,
+  automake,
+  xorgproto,
+  libICE,
+  pkg-config,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "dssi";
+  version = "1.1.1";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/project/dssi/dssi/${version}/${pname}-${version}.tar.gz";
+    sha256 = "0kl1hzhb7cykzkrqcqgq1dk4xcgrcxv0jja251aq4z4l783jpj7j";
+  };
+
+  patches = [
+    ./dssi-liblo.patch
+  ];
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+    pkg-config
+  ];
+  buildInputs = [
+    ladspaH
+    libjack2
+    liblo
+    alsa-lib
+    libX11
+    libsndfile
+    libSM
+    libsamplerate
+    libtool
+    xorgproto
+    libICE
+  ];
+
+  meta = with lib; {
+    description = "Plugin SDK for virtual instruments";
+    maintainers = with maintainers; [
+      raskin
+    ];
+    platforms = platforms.linux;
+    license = licenses.lgpl21;
+    downloadPage = "https://sourceforge.net/projects/dssi/files/dssi/";
+  };
+}

pkgs/by-name/ds/dssp/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenv,
+  cmake,
+  eigen,
+  fetchFromGitHub,
+  libcifpp,
+  libmcfp,
+  zlib,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "dssp";
+  version = "4.5.0";
+
+  src = fetchFromGitHub {
+    owner = "PDB-REDO";
+    repo = "dssp";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-UE97bdSx41K962TqXLlKsp8oDnBBX7uXqsfIzhWjsTI=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [
+    eigen
+    libcifpp
+    libmcfp
+    zlib
+  ];
+
+  meta = {
+    description = "Calculate the most likely secondary structure assignment given the 3D structure of a protein";
+    mainProgram = "mkdssp";
+    homepage = "https://github.com/PDB-REDO/dssp";
+    changelog = "https://github.com/PDB-REDO/dssp/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [ natsukium ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/ds/dstask/package.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "dstask";
+  version = "0.26";
+
+  src = fetchFromGitHub {
+    owner = "naggie";
+    repo = "dstask";
+    rev = "v${version}";
+    sha256 = "sha256-xZFQQDK+yGAv4IbuNe2dvNa3GDASeJY2mOYw94goAIM=";
+  };
+
+  # Set vendorHash to null because dstask vendors its dependencies (meaning
+  # that third party dependencies are stored in the repository).
+  #
+  # Ref <https://github.com/NixOS/nixpkgs/pull/87383#issuecomment-633204382>
+  # and <https://github.com/NixOS/nixpkgs/blob/d4226e3a4b5fcf988027147164e86665d382bbfa/pkgs/development/go-modules/generic/default.nix#L18>
+  vendorHash = null;
+
+  doCheck = false;
+
+  # The ldflags reduce the executable size by stripping some debug stuff.
+  # The other variables are set so that the output of dstask version shows the
+  # git ref and the release version from github.
+  # Ref <https://github.com/NixOS/nixpkgs/pull/87383#discussion_r432097657>
+  ldflags = [
+    "-w"
+    "-s"
+    "-X github.com/naggie/dstask.VERSION=${version}"
+    "-X github.com/naggie/dstask.GIT_COMMIT=v${version}"
+  ];
+
+  meta = with lib; {
+    description = "Command line todo list with super-reliable git sync";
+    homepage = src.meta.homepage;
+    license = licenses.mit;
+    maintainers = with maintainers; [ stianlagstad ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/ds/dstep/dub-lock.json

@@ -0,0 +1,3 @@
+{
+  "dependencies": {}
+}

pkgs/by-name/ds/dstep/package.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  buildDubPackage,
+  fetchFromGitHub,
+  clang,
+  ldc,
+  which,
+}:
+buildDubPackage rec {
+  pname = "dstep";
+  version = "1.0.4";
+
+  src = fetchFromGitHub {
+    owner = "jacob-carlborg";
+    repo = "dstep";
+    rev = "v${version}";
+    hash = "sha256-ZFz2+GtBk3StqXo/9x47xrDFdz5XujHR62hj0p3AjcY=";
+  };
+
+  dubLock = ./dub-lock.json;
+
+  nativeBuildInputs = [
+    ldc
+    which
+    clang
+  ];
+
+  preConfigure = ''
+    ./configure --llvm-path ${lib.getLib clang.cc}
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 bin/dstep -t $out/bin
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Tool for converting C and Objective-C headers to D modules";
+    homepage = "https://github.com/jacob-carlborg/dstep";
+    license = licenses.boost;
+    mainProgram = "dstep";
+    maintainers = with maintainers; [ imrying ];
+  };
+}

pkgs/by-name/ds/dstp/package.nix

@@ -0,0 +1,30 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "dstp";
+  version = "0.4.23";
+
+  src = fetchFromGitHub {
+    owner = "ycd";
+    repo = "dstp";
+    rev = "v${version}";
+    sha256 = "sha256-QODp9IbIc2Z7N/xfRd0UV9r8t6RndOjdGe9hQXJyiN0=";
+  };
+
+  vendorHash = "sha256-EE3xSRu7zAuQjaXCdTD924K6OamEkdxHYEaM0rW/O+o=";
+
+  # Tests require network connection, but is not allowed by nix
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Run common networking tests against your site";
+    mainProgram = "dstp";
+    homepage = "https://github.com/ycd/dstp";
+    license = licenses.mit;
+    maintainers = with maintainers; [ jlesquembre ];
+  };
+}

pkgs/by-name/ds/dsvpn/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "dsvpn";
+  version = "0.1.4";
+
+  src = fetchFromGitHub {
+    owner = "jedisct1";
+    repo = "dsvpn";
+    rev = version;
+    sha256 = "1gbj3slwmq990qxsbsaxasi98alnnzv3adp6f8w8sxd4gi6qxhdh";
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 -t $out/bin dsvpn
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Dead Simple VPN";
+    homepage = "https://github.com/jedisct1/dsvpn";
+    license = licenses.mit;
+    maintainers = [ ];
+    platforms = platforms.unix;
+    mainProgram = "dsvpn";
+  };
+}