push sheeet

pkgs/by-name/e-/e-imzo-manager/package.nix

@@ -0,0 +1,82 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  cargo,
+  desktop-file-utils,
+  gnome-desktop,
+  meson,
+  ninja,
+  pkg-config,
+  polkit,
+  rustc,
+  rustPlatform,
+  wrapGAppsHook4,
+  gdk-pixbuf,
+  glib,
+  adwaita-icon-theme,
+  gtk4,
+  libadwaita,
+  openssl,
+  nix-update-script,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "e-imzo-manager";
+  version = "1.0.2";
+
+  src = fetchFromGitHub {
+    owner = "xinux-org";
+    repo = "e-imzo-manager";
+    tag = finalAttrs.version;
+    hash = "sha256-JXALTSgxIULDHdw90RjxlNQiLT+GKrzpkqPlMY0h+8c=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit (finalAttrs) pname version src;
+    hash = "sha256-x9V0FHrSpM1pIWjDjcTuhPz4p0blXxKDJVvT0I0Op9M=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    cargo
+    rustPlatform.cargoSetupHook
+    rustc
+    desktop-file-utils
+    wrapGAppsHook4
+  ];
+
+  buildInputs = [
+    gdk-pixbuf
+    glib
+    gnome-desktop
+    adwaita-icon-theme
+    gtk4
+    libadwaita
+    openssl
+    rustPlatform.bindgenHook
+    polkit
+  ];
+
+  propagatedUserEnvPkgs = [ polkit ];
+
+  postInstall = ''
+    gappsWrapperArgs+=(
+      --suffix PATH : ${lib.makeBinPath finalAttrs.propagatedUserEnvPkgs}
+    )
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://github.com/xinux-org/e-imzo-manager";
+    mainProgram = "E-IMZO-Manager";
+    description = "GTK application for managing E-IMZO keys";
+    license = with lib.licenses; [ agpl3Plus ];
+    platforms = lib.platforms.linux;
+    teams = [ lib.teams.uzinfocom ];
+  };
+})

pkgs/by-name/e-/e-imzo/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+  jre8,
+  curl,
+  ccid,
+  pcsclite,
+  pcsc-tools,
+  writeShellScript,
+}:
+let
+  exec = writeShellScript "e-imzo" ''
+    cd "$(dirname "$0")/../lib/e-imzo"
+
+    ${jre8}/bin/java -Dsun.security.smartcardio.library=${pcsclite.lib}/lib/libpcsclite.${stdenvNoCC.hostPlatform.extensions.sharedLibrary} -jar E-IMZO.jar
+
+    exit 0
+  '';
+in
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "e-imzo";
+  version = "4.73";
+
+  src = fetchurl {
+    url = "https://cdn.xinux.uz/e-imzo/E-IMZO-v${finalAttrs.version}.tar.gz";
+    hash = "sha256-pkBpU0pyI1kmISNShhB17psLHmTZn3JdHbnRZCgLuGc==";
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin $out/lib/e-imzo
+    install -m 755 -d $out/lib/e-imzo
+    install -m 644 ./E-IMZO.jar $out/lib/e-imzo/
+    install -m 644 ./E-IMZO.pem $out/lib/e-imzo/
+    install -m 644 ./truststore.jks $out/lib/e-imzo/
+    cp -r ./lib $out/lib/e-imzo/
+
+    install -m 755 "${exec}" $out/bin/e-imzo
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "For uzbek state web identity proving & key signing";
+    mainProgram = "e-imzo";
+    platforms = with lib.platforms; linux ++ darwin;
+    homepage = "https://e-imzo.soliq.uz";
+    license = lib.licenses.unfree;
+    sourceProvenance = with lib.sourceTypes; [ binaryBytecode ];
+    teams = [ lib.teams.uzinfocom ];
+  };
+})