push sheeet

pkgs/by-name/ee/ee/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenv,
+  nix-update-script,
+  fetchgit,
+  ncurses,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "ee";
+  version = "1.5.2";
+
+  src = fetchgit {
+    url = "https://git.freebsd.org/src.git";
+    tag = "release/14.3.0";
+    outputHash = "sha256-nMhHXeoam9VtUuhhi0eoGZfcW9zZhpYQKVYbkAbfgc0=";
+    rootDir = "contrib/ee";
+  };
+
+  passthru.updateScript = nix-update-script { };
+
+  buildInputs = [ ncurses ];
+
+  postPatch = ''
+    substituteInPlace create.make --replace-fail "/usr/include/curses.h" "${ncurses.dev}/include/ncurses.h"
+    substituteInPlace create.make --replace-fail "-lcurses" "-lncurses"
+  '';
+
+  NIX_CFLAGS_COMPILE = "-DHAS_UNISTD=1 -DHAS_STDLIB=1 -DHAS_SYS_WAIT=1";
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    cp ee $out/bin/ee
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "classic curses text editor";
+    homepage = "https://man.freebsd.org/cgi/man.cgi?ee";
+    longDescription = ''
+      An easy to use text editor. Intended to be usable with little or no
+      instruction. Provides a terminal (curses based) interface. Features
+      pop-up menus. Born in HP-UX, included in FreeBSD.
+    '';
+    license = lib.licenses.bsd2;
+    platforms = lib.platforms.unix;
+    mainProgram = "ee";
+  };
+})

pkgs/by-name/ee/eepers/package.nix

@@ -0,0 +1,81 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  gnat,
+  raylib,
+  alsa-lib,
+  wayland,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "eepers";
+  version = "1.3";
+
+  src = fetchFromGitHub {
+    owner = "tsoding";
+    repo = "eepers";
+    tag = "v${version}";
+    hash = "sha256-KG7ci327qlTtlN4yV54P8Q34ExFLJfTGMTZxN3RtZbc=";
+  };
+
+  postPatch = ''
+    substituteInPlace eepers.adb \
+      --replace-fail "assets/" "$out/assets/"
+  '';
+
+  buildInputs = [
+    gnat
+    raylib
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+
+    gnatmake -f -O3 \
+      -Wall \
+      -Wextra \
+      -gnat2012 \
+      -o eepers-linux eepers.adb \
+      -bargs \
+      -largs -lraylib -lm \
+      -pthread
+
+    runHook postBuild
+  '';
+
+  postFixup = ''
+    patchelf $out/bin/eepers \
+      --add-needed libwayland-client.so \
+      --add-needed libwayland-cursor.so \
+      --add-needed libwayland-egl.so \
+      --add-needed libasound.so \
+      --add-rpath ${
+        lib.makeLibraryPath [
+          alsa-lib
+          wayland
+        ]
+      }
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    cp ./eepers-linux $out/bin/eepers
+
+    cp -r ./assets $out/
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Simple Turn-based Game";
+    homepage = "https://github.com/tsoding/eepers";
+    changelog = "https://github.com/tsoding/eepers/blob/${src.rev}/CHANGELOG.txt";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ GaetanLepage ];
+    mainProgram = "eepers";
+    platforms = lib.platforms.all;
+  };
+}