push sheeet

pkgs/by-name/ef/eff/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  fetchFromGitHub,
+  ocamlPackages,
+}:
+
+let
+  inherit (ocamlPackages) buildDunePackage js_of_ocaml menhir;
+in
+
+buildDunePackage rec {
+  pname = "eff";
+  version = "5.1";
+
+  src = fetchFromGitHub {
+    owner = "matijapretnar";
+    repo = "eff";
+    rev = "v${version}";
+    hash = "sha256-0U61y41CA0YaoNk9Hsj7j6eb2V6Ku3MAjW9lMEimiC0=";
+  };
+
+  nativeBuildInputs = [ menhir ];
+
+  buildInputs = [ js_of_ocaml ];
+
+  doCheck = true;
+
+  meta = with lib; {
+    homepage = "https://www.eff-lang.org";
+    description = "Functional programming language based on algebraic effects and their handlers";
+    mainProgram = "eff";
+    longDescription = ''
+      Eff is a functional language with handlers of not only exceptions,
+      but also of other computational effects such as state or I/O. With
+      handlers, you can simply implement transactions, redirections,
+      backtracking, multi-threading, and much more...
+    '';
+    license = licenses.bsd2;
+    maintainers = [ maintainers.jirkamarsik ];
+  };
+}

pkgs/by-name/ef/efficient-compression-tool/package.nix

@@ -0,0 +1,75 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  boost,
+  cmake,
+  nasm,
+  libpng,
+  nix-update-script,
+  versionCheckHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "efficient-compression-tool";
+  version = "0.9.5";
+
+  src = fetchFromGitHub {
+    owner = "fhanau";
+    repo = "Efficient-Compression-Tool";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-mlqRDYwgLiB/mRaXkkPTCLiDGxTXqEgu5Nz5jhr1Hsg=";
+    fetchSubmodules = true;
+  };
+
+  # devendor libpng
+  postPatch = ''
+    substituteInPlace src/CMakeLists.txt \
+      --replace-fail 'if(EXISTS "''${CMAKE_SOURCE_DIR}/../.git" AND NOT EXISTS "''${CMAKE_SOURCE_DIR}/../src/libpng/README")' 'if(False)' \
+      --replace-fail 'file(COPY ''${CMAKE_SOURCE_DIR}/pngusr.h DESTINATION ''${CMAKE_SOURCE_DIR}/libpng/)' ""
+    substituteInPlace src/optipng/CMakeLists.txt \
+      --replace-fail 'set(PNG_BUILD_ZLIB ON CACHE BOOL "use custom zlib within libpng" FORCE)' "" \
+      --replace-fail 'add_subdirectory(../libpng libpng EXCLUDE_FROM_ALL)' "" \
+      --replace-fail 'png_static)' 'png)'
+    substituteInPlace src/optipng/image.h src/optipng/trans.h \
+      --replace-fail '#include "../libpng/png.h"' '#include <png.h>'
+    substituteInPlace src/optipng/opngreduc/opngreduc.h \
+      --replace-fail '#include "../../libpng/png.h"' '#include <png.h>'
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    nasm
+  ];
+
+  buildInputs = [
+    boost
+    libpng
+  ];
+
+  cmakeDir = "../src";
+
+  cmakeFlags = [ "-DECT_FOLDER_SUPPORT=ON" ];
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgram = "${placeholder "out"}/bin/${finalAttrs.meta.mainProgram}";
+  versionCheckProgramArg = "-help";
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Fast and effective C++ file optimizer";
+    homepage = "https://github.com/fhanau/Efficient-Compression-Tool";
+    changelog = "https://github.com/fhanau/Efficient-Compression-Tool/releases/tag/${finalAttrs.version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [
+      jwillikers
+      lunik1
+    ];
+    platforms = lib.platforms.all;
+    mainProgram = "ect";
+  };
+})

pkgs/by-name/ef/effitask/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  openssl,
+  gtk3,
+  stdenv,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "effitask";
+  version = "1.4.2";
+
+  src = fetchFromGitHub {
+    owner = "sanpii";
+    repo = "effitask";
+    rev = version;
+    sha256 = "sha256-6BA/TCCqVh5rtgGkUgk8nIqUzozipC5rrkbXMDWYpdQ=";
+  };
+
+  cargoHash = "sha256-j9WCzsh6aitmJeeyLDm0YrZHEAZlCNfGWANM/nmuncw=";
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    openssl
+    gtk3
+  ];
+
+  # default installPhase don't install assets
+  installPhase = ''
+    runHook preInstall
+    make install PREFIX="$out" TARGET="target/${stdenv.hostPlatform.rust.rustcTarget}/release/effitask"
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Graphical task manager, based on the todo.txt format";
+    longDescription = ''
+      To use it as todo.sh add-on, create a symlink like this:
+      mkdir ~/.todo.actions.d/
+      ln -s $(which effitask) ~/.todo.actions.d/et
+
+      Or use it as standalone program by defining some environment variables
+      like described in the projects readme.
+    '';
+    homepage = "https://github.com/sanpii/effitask";
+    maintainers = with maintainers; [ davidak ];
+    license = with licenses; [ mit ];
+    mainProgram = "effitask";
+  };
+}

pkgs/by-name/ef/efibooteditor/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  qt6,
+  zlib,
+  cmake,
+  efivar,
+  pkg-config,
+  fetchFromGitHub,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "efibooteditor";
+  version = "1.5.3";
+
+  src = fetchFromGitHub {
+    owner = "Neverous";
+    repo = "efibooteditor";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-xD40ZzkpwerDYC8nzGVqEHLV0KWbxcc0ApquQjrPJTc=";
+  };
+
+  buildInputs = [ zlib ] ++ lib.optional stdenv.hostPlatform.isLinux efivar;
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    qt6.qttools
+    qt6.wrapQtAppsHook
+  ];
+
+  postPatch = ''
+    substituteInPlace misc/org.x.efibooteditor.policy \
+      --replace-fail /usr/bin $out/bin
+    substituteInPlace misc/EFIBootEditor.desktop \
+      --replace-fail "1.0" ${finalAttrs.version} \
+      --replace-fail \
+        'pkexec efibooteditor' \
+        'sh -c "pkexec env DISPLAY=$DISPLAY XAUTHORITY=$XAUTHORITY efibooteditor"'
+  '';
+
+  env.BUILD_VERSION = "v${finalAttrs.version}";
+  cmakeBuildType = "MinSizeRel";
+  cmakeFlags = [ "-DQT_VERSION_MAJOR=6" ];
+
+  postInstall = ''
+    install -Dm644 $src/LICENSE.txt $out/share/licenses/efibooteditor/LICENSE
+  '';
+
+  meta = {
+    description = "Boot Editor for (U)EFI based systems";
+    homepage = "https://github.com/Neverous/efibooteditor";
+    changelog = "https://github.com/Neverous/efibooteditor/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.lgpl3Plus;
+    platforms = lib.platforms.linux; # TODO build is broken on darwin
+    maintainers = with lib.maintainers; [ phanirithvij ];
+    mainProgram = "efibooteditor";
+  };
+})

pkgs/by-name/ef/efibootmgr/package.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch2,
+  efivar,
+  nix-update-script,
+  pkg-config,
+  popt,
+  testers,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "efibootmgr";
+  version = "18";
+
+  outputs = [
+    "out"
+    "man"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "rhboot";
+    repo = "efibootmgr";
+    tag = finalAttrs.version;
+    hash = "sha256-DYYQGALEn2+mRHgqCJsA7OQCF7xirIgQlWexZ9uoKcg=";
+  };
+
+  patches = [
+    (fetchpatch2 {
+      # https://github.com/rhboot/efibootmgr/issues/186
+      name = "efibootmgr_fix-editing-nonfinal-entry.patch";
+      url = "https://github.com/rhboot/efibootmgr/commit/3eac27c5fccf93d2d6e634d6fe2a76d06708ec6e.diff?full_index=1";
+      hash = "sha256-zXkmfW+BYv8jc/dibu0LEni06KyydVjfW/Lug0i+jUw=";
+    })
+  ];
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    efivar
+    popt
+  ];
+
+  makeFlags = [
+    "EFIDIR=nixos"
+    "PKG_CONFIG=${stdenv.cc.targetPrefix}pkg-config"
+  ];
+
+  installFlags = [ "prefix=${placeholder "out"}" ];
+
+  passthru = {
+    tests.version = testers.testVersion { package = finalAttrs.finalPackage; };
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Linux user-space application to modify the Intel Extensible Firmware Interface (EFI) Boot Manager";
+    homepage = "https://github.com/rhboot/efibootmgr";
+    changelog = "https://github.com/rhboot/efibootmgr/releases/tag/${finalAttrs.version}";
+    license = lib.licenses.gpl2Only;
+    maintainers = with lib.maintainers; [ getchoo ];
+    mainProgram = "efibootmgr";
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/ef/efitools/aarch64.patch

@@ -0,0 +1,16 @@
+diff --git a/Make.rules b/Make.rules
+index 903a5a4..59eca2f 100644
+--- a/Make.rules
++++ b/Make.rules
+@@ -51,11 +51,6 @@ ifeq ($(ARCH),arm)
+   FORMAT = -O binary
+ endif
+ 
+-ifeq ($(ARCH),aarch64)
+-  LDFLAGS += --defsym=EFI_SUBSYSTEM=0x0a
+-  FORMAT = -O binary
+-endif
+-
+ %.efi: %.so
+ 	$(OBJCOPY) -j .text -j .sdata -j .data -j .dynamic -j .dynsym \
+ 		   -j .rel -j .rela -j .rel.* -j .rela.* -j .rel* -j .rela* \

pkgs/by-name/ef/efitools/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  gnu-efi,
+  openssl,
+  sbsigntool,
+  perl,
+  perlPackages,
+  help2man,
+  fetchzip,
+}:
+stdenv.mkDerivation rec {
+  pname = "efitools";
+  version = "1.9.2";
+
+  buildInputs = [
+    gnu-efi
+    openssl
+    sbsigntool
+  ];
+
+  nativeBuildInputs = [
+    perl
+    perlPackages.FileSlurp
+    help2man
+  ];
+
+  src = fetchzip {
+    url = "https://git.kernel.org/pub/scm/linux/kernel/git/jejb/efitools.git/snapshot/efitools-v${version}.tar.gz";
+    sha256 = "0jabgl2pxvfl780yvghq131ylpf82k7banjz0ksjhlm66ik8gb1i";
+  };
+
+  # https://github.com/ncroxon/gnu-efi/issues/7#issuecomment-2122741592
+  patches = [
+    ./aarch64.patch
+  ];
+
+  postPatch = ''
+    sed -i -e 's#/usr/include/efi#${gnu-efi}/include/efi/#g' Make.rules
+    sed -i -e 's#/usr/lib64/gnuefi#${gnu-efi}/lib/#g' Make.rules
+    sed -i -e 's#$(DESTDIR)/usr#$(out)#g' Make.rules
+    sed -i '$asign-efi-sig-list.o flash-var.o: CFLAGS += -D_GNU_SOURCE' Makefile
+    substituteInPlace lib/console.c --replace "EFI_WARN_UNKOWN_GLYPH" "EFI_WARN_UNKNOWN_GLYPH"
+    patchShebangs .
+  '';
+
+  meta = with lib; {
+    description = "Tools for manipulating UEFI secure boot platforms";
+    homepage = "https://git.kernel.org/pub/scm/linux/kernel/git/jejb/efitools.git";
+    license = licenses.gpl2Only;
+    maintainers = [ maintainers.grahamc ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/ef/efivar/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  stdenv,
+  buildPackages,
+  fetchFromGitHub,
+  pkg-config,
+  popt,
+  mandoc,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "efivar";
+  version = "39";
+
+  outputs = [
+    "bin"
+    "out"
+    "dev"
+    "man"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "rhboot";
+    repo = "efivar";
+    rev = version;
+    hash = "sha256-s/1k5a3n33iLmSpKQT5u08xoj8ypjf2Vzln88OBrqf0=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    mandoc
+  ];
+  buildInputs = [ popt ];
+  depsBuildBuild = [ buildPackages.stdenv.cc ];
+
+  makeFlags = [
+    "prefix=$(out)"
+    "libdir=$(out)/lib"
+    "bindir=$(bin)/bin"
+    "mandir=$(man)/share/man"
+    "includedir=$(dev)/include"
+    "PCDIR=$(dev)/lib/pkgconfig"
+  ];
+
+  meta = with lib; {
+    description = "Tools and library to manipulate EFI variables";
+    homepage = "https://github.com/rhboot/efivar";
+    platforms = platforms.linux;
+    license = licenses.lgpl21Only;
+    # See https://github.com/NixOS/nixpkgs/issues/388309
+    broken = stdenv.hostPlatform.is32bit;
+  };
+}

pkgs/by-name/ef/eflite/format.patch

@@ -0,0 +1,11 @@
+--- eflite-0.4.1.orig/es.c	2017-03-02 14:38:36.009731423 +0100
++++ eflite-0.4.1/es.c	2017-03-02 14:39:06.285894934 +0100
+@@ -449,7 +449,7 @@
+   fclose(fp);
+   if (flags & LOG_STDERR)
+   {
+-    fprintf(stderr, buf);
++    fprintf(stderr, "%s", buf);
+     fprintf(stderr, "\n");
+   }
+ #endif

pkgs/by-name/ef/eflite/package.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  fetchpatch,
+  flite,
+  alsa-lib,
+  debug ? false,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "eflite";
+  version = "0.4.1";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/eflite/eflite/${finalAttrs.version}/eflite-${finalAttrs.version}.tar.gz";
+    hash = "sha256-ka2FhV5Vo/w7l6GlJdtf0dIR1UNCu/yI0QJoExBPFyE=";
+  };
+
+  buildInputs = [
+    flite
+    alsa-lib
+  ];
+
+  configureFlags = [
+    "flite_dir=${flite.dev}"
+    "--with-audio=alsa"
+    "--with-vox=cmu_us_kal16"
+  ];
+
+  patches = [
+    (fetchpatch {
+      url = "https://sources.debian.org/data/main/e/eflite/0.4.1-8/debian/patches/cvs-update";
+      sha256 = "0r631vzmky7b7qyhm152557y4fr0xqrpi3y4w66fcn6p4rj03j05";
+    })
+    (fetchpatch {
+      url = "https://sources.debian.org/data/main/e/eflite/0.4.1-8/debian/patches/buf-overflow";
+      sha256 = "071qk133kb7n7bq6kxgh3p9bba6hcl1ixsn4lx8vp8klijgrvkmx";
+    })
+    (fetchpatch {
+      url = "https://sources.debian.org/data/main/e/eflite/0.4.1-8/debian/patches/link";
+      sha256 = "0p833dp4pdsya72bwh3syvkq85927pm6snxvx13lvcppisbhj0fc";
+    })
+    ./format.patch
+  ];
+
+  CFLAGS = lib.optionalString debug " -DDEBUG=2";
+
+  meta = {
+    homepage = "https://eflite.sourceforge.net";
+    description = "Speech server for screen readers";
+    longDescription = ''
+      EFlite is a speech server for Emacspeak and other screen
+      readers that allows them to interface with Festival Lite,
+      a free text-to-speech engine developed at the CMU Speech
+      Center as an off-shoot of Festival.
+    '';
+    license = lib.licenses.gpl2;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ bot-wxt1221 ];
+    mainProgram = "eflite";
+  };
+})

pkgs/by-name/ef/efm-langserver/package.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "efm-langserver";
+  version = "0.0.54";
+
+  src = fetchFromGitHub {
+    owner = "mattn";
+    repo = "efm-langserver";
+    rev = "v${version}";
+    sha256 = "sha256-3ZrWc8/4aC5TOoL9vybkMZC9HkIL43TokebFcJYyrcI=";
+  };
+
+  vendorHash = "sha256-FOAKxKqhrUpfXkoasSd7v3kKAqV11p5ieZaMPni5Hx4=";
+  subPackages = [ "." ];
+
+  meta = with lib; {
+    description = "General purpose Language Server";
+    mainProgram = "efm-langserver";
+    maintainers = with maintainers; [ Philipp-M ];
+    homepage = "https://github.com/mattn/efm-langserver";
+    license = licenses.mit;
+  };
+}

pkgs/by-name/ef/efmt/package.nix

@@ -0,0 +1,30 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "efmt";
+  version = "0.19.1";
+
+  src = fetchFromGitHub {
+    owner = "sile";
+    repo = "efmt";
+    rev = version;
+    hash = "sha256-l+DiOMUTEF6btsgkfgDtY45fH6GyqKBqHjuTfCF/ybA=";
+  };
+
+  cargoHash = "sha256-NJ49DqJW0qgM1dPOzlwMP9+JEfa1/YxvgMm4WmJ0mFA=";
+
+  meta = {
+    description = "Erlang code formatter";
+    homepage = "https://github.com/sile/efmt";
+    license = with lib.licenses; [
+      asl20
+      mit
+    ];
+    maintainers = with lib.maintainers; [ haruki7049 ];
+    mainProgram = "efmt";
+  };
+}

pkgs/by-name/ef/efont-unicode/package.nix

@@ -0,0 +1,67 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  libfaketime,
+  xorg,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "efont-unicode";
+  version = "0.4.2";
+
+  src = fetchurl {
+    url = "http://openlab.ring.gr.jp/efont/dist/unicode-bdf/${pname}-bdf-${version}.tar.bz2";
+    sha256 = "sha256-fT7SsYlV3dCQrf0IZfiNI1grj3ngDgr8IkWdg+f9m3M=";
+  };
+
+  nativeBuildInputs = with xorg; [
+    libfaketime
+    bdftopcf
+    fonttosfnt
+    mkfontscale
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+
+    # convert bdf fonts to pcf
+    for f in *.bdf; do
+        bdftopcf -t -o "''${f%.bdf}.pcf" "$f"
+    done
+    gzip -n -9 *.pcf
+
+    # convert bdf fonts to otb
+    for f in *.bdf; do
+        faketime -f "1970-01-01 00:00:01" \
+        fonttosfnt -v -m 2 -o "''${f%.bdf}.otb" "$f"
+    done
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    dir=share/fonts/misc
+    install -D -m 644 -t "$out/$dir" *.otb *.pcf.gz
+    install -D -m 644 -t "$bdf/$dir" *.bdf
+    mkfontdir "$out/$dir"
+    mkfontdir "$bdf/$dir"
+
+    runHook postInstall
+  '';
+
+  outputs = [
+    "out"
+    "bdf"
+  ];
+
+  meta = with lib; {
+    description = "/efont/ Unicode bitmap font";
+    homepage = "http://openlab.ring.gr.jp/efont/unicode/";
+    license = licenses.bsd3;
+    platforms = platforms.all;
+    maintainers = [ maintainers.ncfavier ];
+  };
+}