push sheeet

pkgs/by-name/el/elasticmq-server-bin/elasticmq-test.nix

@@ -0,0 +1,60 @@
+{
+  elasticmq-server,
+  python3Packages,
+  runCommand,
+  writeText,
+}:
+
+runCommand "${elasticmq-server.name}-tests"
+  (
+    let
+      commonPy = ''
+        import boto3
+        client = boto3.resource(
+          "sqs",
+          endpoint_url="http://localhost:9324",
+          region_name="elasticmq",
+          aws_secret_access_key="x",
+          aws_access_key_id="x",
+          use_ssl=False,
+        )
+        queue = client.get_queue_by_name(QueueName="foobar")
+      '';
+    in
+    {
+      buildInputs = with python3Packages; [
+        python
+        boto3
+      ];
+      emqConfig = writeText "emq-test.conf" ''
+        generate-node-address = true
+
+        queues {
+          foobar {}
+        }
+      '';
+      putMessagePy = writeText "put_message.py" ''
+        ${commonPy}
+        queue.send_message(MessageBody="bazqux")
+      '';
+      checkMessagePy = writeText "check_message.py" ''
+        ${commonPy}
+        messages = queue.receive_messages()
+        print(f"Received {messages!r}")
+        assert len(messages) == 1
+        assert messages[0].body == "bazqux"
+      '';
+    }
+  )
+  ''
+    JAVA_TOOL_OPTIONS="-Dconfig.file=$emqConfig" ${elasticmq-server}/bin/elasticmq-server &
+    SERVER_PID=$!
+    sleep 10
+
+    python $putMessagePy
+    python $checkMessagePy
+    touch $out
+
+    # needed on darwin
+    kill $SERVER_PID
+  ''

pkgs/by-name/el/elasticmq-server-bin/package.nix

@@ -0,0 +1,55 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  jdk8,
+  jre8,
+  makeBinaryWrapper,
+  runCommand,
+  python3Packages,
+  writeText,
+}:
+let
+  jre = jre8; # TODO: remove override https://github.com/NixOS/nixpkgs/pull/89731
+  jdk = jdk8; # TODO: remove override https://github.com/NixOS/nixpkgs/pull/89731
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "elasticmq-server";
+  version = "1.6.14";
+
+  src = fetchurl {
+    url = "https://s3-eu-west-1.amazonaws.com/softwaremill-public/elasticmq-server-${finalAttrs.version}.jar";
+    sha256 = "sha256-HVllLHz6zutonaLFwgyQKYSZxfp5QMslxf/PlzGWyG4=";
+  };
+
+  # don't do anything?
+  unpackPhase = "${jdk}/bin/jar xf $src favicon.png";
+
+  nativeBuildInputs = [ makeBinaryWrapper ];
+
+  installPhase = ''
+    mkdir -p $out/bin $out/share/elasticmq-server
+
+    cp $src $out/share/elasticmq-server/elasticmq-server.jar
+
+    # TODO: how to add extraArgs? current workaround is to use JAVA_TOOL_OPTIONS environment to specify properties
+    makeWrapper ${jre}/bin/java $out/bin/elasticmq-server \
+      --add-flags "-jar $out/share/elasticmq-server/elasticmq-server.jar"
+  '';
+
+  passthru.tests.elasticmqTest = import ./elasticmq-test.nix {
+    inherit runCommand python3Packages writeText;
+    elasticmq-server = finalAttrs.finalPackage;
+  };
+
+  meta = with lib; {
+    description = "Message queueing system with Java, Scala and Amazon SQS-compatible interfaces";
+    homepage = "https://github.com/softwaremill/elasticmq";
+    changelog = "https://github.com/softwaremill/elasticmq/releases/tag/v${finalAttrs.version}";
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    license = licenses.asl20;
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ peterromfeldhk ];
+    mainProgram = "elasticmq-server";
+  };
+})