push sheeet

pkgs/by-name/er/er-patcher/package.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  python3,
+}:
+
+stdenvNoCC.mkDerivation rec {
+  pname = "er-patcher";
+  version = "1.12-3";
+
+  src = fetchFromGitHub {
+    owner = "gurrgur";
+    repo = "er-patcher";
+    rev = "v${version}";
+    sha256 = "sha256-D+XYZI3kmK5sb+i8RxtODTvbTgzhpDzwB/JM61ddcTA=";
+  };
+
+  buildInputs = [
+    python3
+  ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    install -Dm755 $src/er-patcher $out/bin/er-patcher
+    patchShebangs $out/bin/er-patcher
+  '';
+
+  meta = {
+    homepage = "https://github.com/gurrgur/er-patcher";
+    changelog = "https://github.com/gurrgur/er-patcher/releases/tag/v${version}";
+    description = "Enhancement patches for Elden Ring adding ultrawide support, custom frame rate limits and more";
+    longDescription = ''
+      A tool aimed at enhancing the experience when playing the game on linux through proton or natively on windows.
+      This tool is based on patching the game executable through hex-edits. However it is done in a safe and non-destructive way,
+      that ensures the patched executable is never run with EAC enabled (unless explicity told to do so). Use at your own risk!
+    '';
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.sigmasquadron ];
+    mainProgram = "er-patcher";
+  };
+}

pkgs/by-name/er/era/package.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  deno,
+  makeWrapper,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "era";
+  version = "0.1.3";
+
+  src = fetchFromGitHub {
+    owner = "kyoheiu";
+    repo = "era";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-OOPVLY9kg4TmKSrpHgsOmAmeDPbX5df0bX51lA6DvcY=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/{bin,lib}
+    cp -r $src/{src,LICENSE,README.md} $out/lib
+    makeWrapper ${lib.getExe deno} $out/bin/era \
+      --set DENO_NO_UPDATE_CHECK "1" \
+      --add-flags "run -A $out/lib/src/main.ts"
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Rainy clock in your terminal";
+    homepage = "https://github.com/kyoheiu/era";
+    changelog = "https://github.com/kyoheiu/era/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ natsukium ];
+    mainProgram = "era";
+    inherit (deno.meta) platforms;
+  };
+})

pkgs/by-name/er/erdtree/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "erdtree";
+  version = "3.1.2";
+
+  src = fetchFromGitHub {
+    owner = "solidiquis";
+    repo = "erdtree";
+    rev = "v${version}";
+    hash = "sha256-rm3j1exvdlJtMXgFeRmzr3YU/sLpQFL3PCa8kLVlinM=";
+  };
+
+  cargoHash = "sha256-qmSkMoTAwZz7Bn+r67tmh0SLvkM1EFAkySjLFzFFBv4=";
+
+  meta = with lib; {
+    description = "File-tree visualizer and disk usage analyzer";
+    homepage = "https://github.com/solidiquis/erdtree";
+    changelog = "https://github.com/solidiquis/erdtree/releases/tag/${src.rev}";
+    license = licenses.mit;
+    maintainers = with maintainers; [
+      figsoda
+      zendo
+    ];
+    mainProgram = "erd";
+  };
+}

pkgs/by-name/er/eresi/package.nix

@@ -0,0 +1,93 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  which,
+  openssl,
+  readline,
+  fetchpatch,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "eresi";
+  version = "0.83-a3-phoenix";
+
+  src = fetchFromGitHub {
+    owner = "thorkill";
+    repo = "eresi";
+    rev = version;
+    sha256 = "0a5a7mh2zw9lcdrl8n1mqccrc0xcgj7743l7l4kslkh722fxv625";
+  };
+
+  patches = [
+    (fetchpatch {
+      url = "https://github.com/thorkill/eresi/commit/a79406344cc21d594d27fa5ec5922abe9f7475e7.patch";
+      sha256 = "1mjjc6hj7r06iarvai7prcdvjk9g0k5vwrmkwcm7b8ivd5xzxp2z";
+    })
+
+    # Pull patch pending upstream inclusion for -fno-common toolchains:
+    #   https://github.com/thorkill/eresi/pull/166
+    (fetchpatch {
+      url = "https://github.com/thorkill/eresi/commit/bc5b9a75c326f277e5f89e01a3b8f7f0519a99f6.patch";
+      sha256 = "0lqwrnkkhhd3vi1r8ngvziyqkk09h98h93rrs3ndqi048a898ys1";
+    })
+
+    # Fix compilation for gcc14 and newer
+    #   https://github.com/thorkill/eresi/pull/167
+    (fetchpatch {
+      url = "https://github.com/thorkill/eresi/commit/f85397c4dce633764fab29b0642f59fc4764658a.patch";
+      sha256 = "sha256-mKmJHjyWwCNh/pueB94Ndhj/3uZLBZNn/m9gXenP5ns=";
+    })
+  ];
+
+  postPatch = ''
+    # Two occurences of fprintf() with only two arguments, which should really
+    # be fputs().
+    #
+    # Upstream pull request: https://github.com/thorkill/eresi/pull/162
+    #
+    sed -i -e 's/fprintf(\(stderr\), *\([a-z0-9]\+\))/fputs(\2, \1)/g' \
+      libe2dbg/common/common.c libe2dbg/user/threads.c
+
+    # We need to patch out a few ifs here, because it tries to create a series
+    # of configuration files in ~/.something. However, our builds are sandboxed
+    # and also don't contain a valid home, so let's NOP it out :-)
+    #
+    # The second fix we need to make is that we need to pretend being Gentoo
+    # because otherwise the build process tries to link against libtermcap,
+    # which I think is solely for historic reasons (nowadays Terminfo should
+    # have largely superseded it).
+    sed -i -e '/^if \[ ! -e/c if false; then' \
+           -e 's/^GENTOO=.*/GENTOO=1/' configure
+  '';
+
+  configureFlags = [
+    (if stdenv.hostPlatform.is64bit then "--enable-32-64" else "--enable-32")
+    "--enable-readline"
+  ];
+
+  # The configure script is not generated by autoconf but is hand-rolled, so it
+  # has --enable-static but no --disabled-static and also doesn't support the
+  # equals sign in --prefix.
+  prefixKey = "--prefix ";
+  dontDisableStatic = true;
+
+  nativeBuildInputs = [ which ];
+  buildInputs = [
+    openssl
+    readline
+  ];
+  enableParallelBuilding = true;
+  # ln: failed to create symbolic link '...-eresi-0.83-a3-phoenix//bin/elfsh': No such file or directory
+  # make: *** [Makefile:108: install64] Error 1
+  enableParallelInstalling = false;
+
+  installTargets = lib.singleton "install" ++ lib.optional stdenv.hostPlatform.is64bit "install64";
+
+  meta = {
+    description = "ERESI Reverse Engineering Software Interface";
+    license = lib.licenses.gpl2Only;
+    homepage = "https://github.com/thorkill/eresi"; # Formerly http://www.eresi-project.org/
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/er/erg/package.nix

@@ -0,0 +1,70 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  makeWrapper,
+  python3,
+  which,
+  stdenv,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "erg";
+  version = "0.6.53";
+
+  src = fetchFromGitHub {
+    owner = "erg-lang";
+    repo = "erg";
+    rev = "v${version}";
+    hash = "sha256-VPekgbD5vQ6JsyGT4WKayl1eB9SWGemf02rXpkP6fcU=";
+  };
+
+  cargoHash = "sha256-xRav27+T8iy7MrqtzTf1Fvxqi2pwR9E7jv5bmXfC5Cs=";
+
+  nativeBuildInputs = [
+    makeWrapper
+    python3
+    which
+  ];
+
+  buildFeatures = [ "full" ];
+
+  env = {
+    BUILD_DATE = "1970/01/01 00:00:00";
+    CASE_SENSITIVE = lib.boolToString (!stdenv.hostPlatform.isDarwin);
+    GIT_HASH_SHORT = src.rev;
+  };
+
+  # TODO(figsoda): fix tests
+  doCheck = false;
+
+  # the build script is impure and also assumes we are in a git repository
+  postPatch = ''
+    rm crates/erg_common/build.rs
+  '';
+
+  preBuild = ''
+    export HOME=$(mktemp -d)
+    export CARGO_ERG_PATH=$HOME/.erg
+  '';
+
+  postInstall = ''
+    mkdir -p $out/share
+    mv "$CARGO_ERG_PATH" $out/share/erg
+
+    wrapProgram $out/bin/erg \
+      --set-default ERG_PATH $out/share/erg
+  '';
+
+  meta = with lib; {
+    description = "Statically typed language that can deeply improve the Python ecosystem";
+    mainProgram = "erg";
+    homepage = "https://github.com/erg-lang/erg";
+    changelog = "https://github.com/erg-lang/erg/releases/tag/${src.rev}";
+    license = with licenses; [
+      asl20
+      mit
+    ];
+    maintainers = with maintainers; [ figsoda ];
+  };
+}

pkgs/by-name/er/ergo/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  makeWrapper,
+  jre,
+  nixosTests,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ergo";
+  version = "6.0.1";
+
+  src = fetchurl {
+    url = "https://github.com/ergoplatform/ergo/releases/download/v${version}/ergo-${version}.jar";
+    sha256 = "sha256-ByvHXgXFdoHbc+lWEK82I/I50Q1aoe3SSI2JeaTjEC4=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  dontUnpack = true;
+
+  installPhase = ''
+    makeWrapper ${jre}/bin/java $out/bin/ergo --add-flags "-jar $src"
+  '';
+
+  passthru.tests = { inherit (nixosTests) ergo; };
+
+  meta = with lib; {
+    description = "Open protocol that implements modern scientific ideas in the blockchain area";
+    homepage = "https://ergoplatform.org/en/";
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    license = licenses.cc0;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ mmahut ];
+    mainProgram = "ergo";
+  };
+}

pkgs/by-name/er/ergochat/package.nix

@@ -0,0 +1,35 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+  nixosTests,
+}:
+
+buildGoModule rec {
+  pname = "ergo";
+  version = "2.16.0";
+
+  src = fetchFromGitHub {
+    owner = "ergochat";
+    repo = "ergo";
+    rev = "v${version}";
+    sha256 = "sha256-AUXuH7YjC/yG5Ocs+kAOF8bAR4UVgfx96VDSHEqmqgg=";
+  };
+
+  vendorHash = null;
+
+  passthru.tests.ergochat = nixosTests.ergochat;
+
+  meta = {
+    changelog = "https://github.com/ergochat/ergo/blob/v${version}/CHANGELOG.md";
+    description = "Modern IRC server (daemon/ircd) written in Go";
+    mainProgram = "ergo";
+    homepage = "https://github.com/ergochat/ergo";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      lassulus
+      tv
+    ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/er/ergogen/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  buildNpmPackage,
+  fetchFromGitHub,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+buildNpmPackage (finalAttrs: {
+  pname = "ergogen";
+  version = "4.1.0";
+
+  forceGitDeps = true;
+
+  src = fetchFromGitHub {
+    owner = "ergogen";
+    repo = "ergogen";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Y4Ri5nLxbQ78LvyGARPxsvoZ9gSMxY14QuxZJg6Cu3Y=";
+  };
+
+  npmDepsHash = "sha256-BQbf/2lWLYnrSjwWjDo6QceFyR+J/vhDcVgCaytGfl0=";
+
+  makeCacheWritable = true;
+  dontNpmBuild = true;
+  npmPackFlags = [ "--ignore-scripts" ];
+  NODE_OPTIONS = "--openssl-legacy-provider";
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Ergonomic keyboard layout generator";
+    homepage = "https://ergogen.xyz";
+    mainProgram = "ergogen";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ Tygo-van-den-Hurk ];
+  };
+})

pkgs/by-name/er/ergoscf/math-constants.patch

@@ -0,0 +1,19 @@
+diff --git a/source/dft/functionals.h b/source/dft/functionals.h
+index fde49ba..f7a61fc 100644
+--- a/source/dft/functionals.h
++++ b/source/dft/functionals.h
+@@ -59,6 +59,14 @@
+ #define EXTERN_C
+ #endif
+ 
++#ifndef M_PI
++#define M_PI 3.14159265358979323846
++#endif
++
++#ifndef M_SQRT2
++#define M_SQRT2        1.41421356237309504880
++#endif
++
+ typedef ergo_real real;
+ 
+ #if defined(FUNC_PRECISION) && FUNC_PRECISION == 1

pkgs/by-name/er/ergoscf/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  blas,
+  lapack,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ergoscf";
+  version = "3.8.2";
+
+  src = fetchurl {
+    url = "http://www.ergoscf.org/source/tarfiles/ergo-${version}.tar.gz";
+    sha256 = "sha256-U0NVREEZ8HI0Q0ZcbwvZsYA76PWMh7bqgDG1uaUc01c=";
+  };
+
+  buildInputs = [
+    blas
+    lapack
+  ];
+
+  patches = [ ./math-constants.patch ];
+
+  postPatch = ''
+    patchShebangs ./test
+  '';
+
+  configureFlags = [
+    "--enable-linalgebra-templates"
+    "--enable-performance"
+  ]
+  ++ lib.optional stdenv.hostPlatform.isx86_64 "--enable-sse-intrinsics";
+
+  env = {
+    # Required for compilation with gcc-14
+    NIX_CFLAGS_COMPILE = "-Wno-error=implicit-function-declaration";
+    LDFLAGS = "-lblas -llapack";
+  };
+
+  enableParallelBuilding = true;
+
+  OMP_NUM_THREADS = 2; # required for check phase
+
+  # With "fortify3", there are test failures, such as:
+  # Testing cnof CAMB3LYP/6-31G using FMM
+  # *** buffer overflow detected ***: terminated
+  # ./test_fmm_camb3lyp.sh: line 81: 1061289 Aborted                 (core dumped) ./ergo <<EOINPUT > /dev/null
+  hardeningDisable = [ "fortify3" ];
+
+  doCheck = true;
+
+  meta = with lib; {
+    description = "Quantum chemistry program for large-scale self-consistent field calculations";
+    mainProgram = "ergo";
+    homepage = "http://www.ergoscf.org";
+    license = licenses.gpl3Plus;
+    maintainers = [ maintainers.markuskowa ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/er/ericw-tools/package.nix

@@ -0,0 +1,71 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  gtest,
+  fmt,
+  cmake,
+  ninja,
+  installShellFiles,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ericw-tools";
+  version = "0.18.1";
+
+  src = fetchFromGitHub {
+    owner = "ericwa";
+    repo = "ericw-tools";
+    rev = "v${version}";
+    sha256 = "11sap7qv0rlhw8q25azvhgjcwiql3zam09q0gim3i04cg6fkh0vp";
+  };
+  postUnpack = ''
+    pushd source/3rdparty
+    ln -s ${fmt.src} fmt
+    ln -s ${gtest.src} googletest
+    popd
+  '';
+
+  patches = [
+    (fetchpatch {
+      url = "https://github.com/ericwa/ericw-tools/commit/c9570260fa895dde5a21272d76f9a3b05d59efdd.patch";
+      hash = "sha256-dZr2LWuJBAIT//XHXYEz2vhaK2mxtxkSJ4IQla8OXKI=";
+    })
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+    installShellFiles
+  ];
+
+  outputs = [
+    "out"
+    "doc"
+    "man"
+  ];
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    for TOOL in bspinfo bsputil light qbsp vis ; do
+      cp -a $TOOL/$TOOL $out/bin/
+    done
+
+    installManPage ../man/*.?
+
+    mkdir -p $doc/share/doc/ericw-tools
+    cp -a ../README.md ../changelog.txt $doc/share/doc/ericw-tools/
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://ericwa.github.io/ericw-tools/";
+    description = "Map compile tools for Quake and Hexen 2";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ astro ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/er/erigon/package.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+let
+  pname = "erigon";
+  version = "3.0.4";
+in
+buildGoModule {
+  inherit pname version;
+
+  src = fetchFromGitHub {
+    owner = "ledgerwatch";
+    repo = "erigon";
+    tag = "v${version}";
+    hash = "sha256-MQpHRlKxWCBD2Tj9isxMKwvYBy9HtDkQPyKPse8uB3g=";
+    fetchSubmodules = true;
+  };
+
+  vendorHash = "sha256-ocnq97cMsiMgDTZhwZ/fiGzaHiSAiJckPwWZu2q3f58=";
+  proxyVendor = true;
+
+  # Build errors in mdbx when format hardening is enabled:
+  #   cc1: error: '-Wformat-security' ignored without '-Wformat' [-Werror=format-security]
+  hardeningDisable = [ "format" ];
+
+  # Fix error: 'Caught SIGILL in blst_cgo_init'
+  # https://github.com/bnb-chain/bsc/issues/1521
+  CGO_CFLAGS = "-O -D__BLST_PORTABLE__";
+  CGO_CFLAGS_ALLOW = "-O -D__BLST_PORTABLE__";
+
+  subPackages = [
+    "cmd/erigon"
+    "cmd/evm"
+    "cmd/rpcdaemon"
+    "cmd/rlpdump"
+  ];
+
+  # Matches the tags to upstream's release build configuration
+  # https://github.com/ledgerwatch/erigon/blob/0c0dbe5f3a81cf8f16da8e4838312ab80ebe5302/.goreleaser.yml
+  #
+  # Enabling silkworm also breaks the build as it requires dynamically linked libraries.
+  # If we need it in the future, we should consider packaging silkworm and silkworm-go
+  # as depenedencies explicitly.
+  tags = [
+    "nosqlite"
+    "noboltdb"
+    "nosilkworm"
+  ];
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [
+      # avoid testing‐releases
+      "--version-regex"
+      "^(\\d+\\.\\d+\\.\\d+)$"
+    ];
+  };
+
+  meta = with lib; {
+    homepage = "https://github.com/ledgerwatch/erigon/";
+    description = "Ethereum node implementation focused on scalability and modularity";
+    license = with licenses; [
+      lgpl3Plus
+      gpl3Plus
+    ];
+    maintainers = with maintainers; [
+      happysalada
+    ];
+  };
+}

pkgs/by-name/er/erlang-language-platform/hashes.json

@@ -0,0 +1,14 @@
+{
+  "elp-linux-aarch64-unknown-linux-gnu-otp-26.2": "sha256-xKl19cLz3Pm39QS8+9fOCGJHpxl4NoPYHIwTqKDq4Jc=",
+  "elp-linux-aarch64-unknown-linux-gnu-otp-27.3": "sha256-GNoV6Ihtro3ecl4cncyQKQez/5CBqj1E3JV1JK8l2V8=",
+  "elp-linux-aarch64-unknown-linux-gnu-otp-28": "sha256-DW00mSXJWIBfwsV9juMKaiFwNkezT1Ro+5zMaCwFRzE=",
+  "elp-linux-x86_64-unknown-linux-gnu-otp-26.2": "sha256-fQvlzwS7crDsqmSjsUlFXbqKnCKldOYuiQDmGojqJb8=",
+  "elp-linux-x86_64-unknown-linux-gnu-otp-27.3": "sha256-4pZtSVCDIiJ7k83go7WjJq4wxWbc9nG4hJoAgXDMOZM=",
+  "elp-linux-x86_64-unknown-linux-gnu-otp-28": "sha256-3hY+5TDBobRjKgfptvgHmdtuWm8UE7KoWFhsR2qmQhc=",
+  "elp-macos-aarch64-apple-darwin-otp-26.2": "sha256-38N+0msiPMv9eFTSzWdEqmczDp49JvTlu3kDedmC+Lw=",
+  "elp-macos-aarch64-apple-darwin-otp-27.3": "sha256-2uZyvyVwQULz+3HtvkIGvjO5Dm7qAAIbHE/VUcqcXkQ=",
+  "elp-macos-aarch64-apple-darwin-otp-28": "sha256-BosctdlXWTxkVyLX8awlJtyHAtfoVxFlvs7qrSlPTZc=",
+  "elp-macos-x86_64-apple-darwin-otp-26.2": "sha256-p0xotdrflT2CANJi4OaevJZT4nhFRAfdzrhQ/7M8ykA=",
+  "elp-macos-x86_64-apple-darwin-otp-27.3": "sha256-qTvsGRCVqqoSWK/t7MysE1wlD0PwtUQQ1N1Zols+Egk=",
+  "elp-macos-x86_64-apple-darwin-otp-28": "sha256-DSB8AXWM1KByuzg5HY2lh2x4zmeeR2nyiERR3Iovpns="
+}

pkgs/by-name/er/erlang-language-platform/package.nix

@@ -0,0 +1,73 @@
+{
+  stdenv,
+  lib,
+  fetchurl,
+  autoPatchelfHook,
+  erlang,
+}:
+let
+  # erlang-language-platform supports multiple OTP versions.
+  # here we search the release names from hashes.json to check support for our OTP.
+  # ELP releases only list the major and minor version so we do a prefix check.
+  arch = if stdenv.hostPlatform.isAarch64 then "aarch64" else "x86_64";
+  platform =
+    if stdenv.hostPlatform.isDarwin then
+      "elp-macos-${arch}-apple-darwin"
+    else
+      "elp-linux-${arch}-unknown-linux-gnu";
+  otp_version = "otp-${lib.versions.major erlang.version}";
+  release_major = "${platform}-${otp_version}";
+
+  hashes = builtins.fromJSON (builtins.readFile ./hashes.json);
+
+  release_name =
+    let
+      hash_names = builtins.attrNames hashes;
+      found_name = lib.lists.findFirst (name: lib.strings.hasPrefix release_major name) false hash_names;
+    in
+    if found_name != false then
+      found_name
+    else
+      throw "erlang-language-platform does not support OTP major/minor version ${otp_version}";
+
+in
+stdenv.mkDerivation rec {
+  pname = "erlang-language-platform";
+  version = "2025-07-21";
+
+  src = fetchurl {
+    url = "https://github.com/WhatsApp/erlang-language-platform/releases/download/${version}/${release_name}.tar.gz";
+    hash = hashes.${release_name};
+  };
+
+  nativeBuildInputs = lib.optionals stdenv.hostPlatform.isElf [ autoPatchelfHook ];
+
+  buildInputs = lib.optionals stdenv.hostPlatform.isElf [ (lib.getLib stdenv.cc.cc) ];
+
+  sourceRoot = ".";
+
+  installPhase = ''
+    runHook preInstall
+    install -m755 -D elp $out/bin/elp
+    runHook postInstall
+  '';
+
+  passthru.updateScript = ./update.sh;
+
+  meta = {
+    description = "IDE-first library for the semantic analysis of Erlang code, including LSP server, linting and refactoring tools";
+    homepage = "https://github.com/WhatsApp/erlang-language-platform/";
+    license = with lib.licenses; [
+      mit
+      asl20
+    ];
+    platforms = [
+      "aarch64-linux"
+      "x86_64-linux"
+      "aarch64-darwin"
+      "x86_64-darwin"
+    ];
+    maintainers = with lib.maintainers; [ offsetcyan ];
+    sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
+  };
+}

pkgs/by-name/er/erlang-language-platform/update.sh

@@ -0,0 +1,24 @@
+#! /usr/bin/env nix-shell
+#! nix-shell -i bash -p curl jq common-updater-scripts
+# shellcheck shell=bash
+
+set -euo pipefail
+
+curl_github() {
+    curl -L ${GITHUB_TOKEN:+" -u \":$GITHUB_TOKEN\""} "$@"
+}
+
+release_json=$(curl_github https://api.github.com/repos/WhatsApp/erlang-language-platform/releases/latest)
+version=$(echo "$release_json" | jq -r '.tag_name')
+releases=$(echo "$release_json" | jq -r '.assets[] | select(.browser_download_url | test(".tar.gz$")) | .name + ":" + .browser_download_url')
+
+update-source-version erlang-language-platform "$version" --file=./pkgs/by-name/er/erlang-language-platform/package.nix
+
+for release in $releases; do
+  IFS=: read -r name url <<< "$release"
+  hash_name=$(echo "$name" | sed 's/.tar.gz$//')
+  hash_prefetched=$(nix-prefetch-url --type sha256 "$url")
+  hash_sri=$(nix hash to-sri --type sha256 "$hash_prefetched")
+  echo "$hash_name" "$hash_sri"
+done |
+  jq -sR 'rtrimstr("\n") | split("\n") | map(split(" ") | {(.[0]): .[1]}) | add' > hashes.json

pkgs/by-name/er/erofs-utils/package.nix

@@ -0,0 +1,71 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  autoreconfHook,
+  pkg-config,
+  fuse,
+  util-linux,
+  xxHash,
+  lz4,
+  xz,
+  zlib,
+  zstd,
+  libdeflate,
+  libselinux,
+  fuseSupport ? stdenv.hostPlatform.isLinux,
+  selinuxSupport ? false,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "erofs-utils";
+  version = "1.8.10";
+  outputs = [
+    "out"
+    "man"
+  ];
+
+  enableParallelBuilding = true;
+  strictDeps = true;
+
+  src = fetchurl {
+    url = "https://git.kernel.org/pub/scm/linux/kernel/git/xiang/erofs-utils.git/snapshot/erofs-utils-${finalAttrs.version}.tar.gz";
+    hash = "sha256-BetO3r4R3szm7LNOmNL4DIzSg8Lyln2Lp+/VhBhXBRQ=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+  ];
+  buildInputs = [
+    util-linux
+    xxHash
+    lz4
+    zlib
+    xz
+    zstd
+    libdeflate
+  ]
+  ++ lib.optionals fuseSupport [ fuse ]
+  ++ lib.optionals selinuxSupport [ libselinux ];
+
+  configureFlags = [
+    "MAX_BLOCK_SIZE=4096"
+    "--enable-multithreading"
+    "--with-libdeflate"
+  ]
+  ++ lib.optional fuseSupport "--enable-fuse"
+  ++ lib.optional selinuxSupport "--with-selinux";
+
+  meta = {
+    homepage = "https://git.kernel.org/pub/scm/linux/kernel/git/xiang/erofs-utils.git/about/";
+    description = "Userspace utilities for linux-erofs file system";
+    changelog = "https://git.kernel.org/pub/scm/linux/kernel/git/xiang/erofs-utils.git/tree/ChangeLog?h=v${finalAttrs.version}";
+    license = with lib.licenses; [ gpl2Plus ];
+    maintainers = with lib.maintainers; [
+      nikstur
+      jmbaur
+    ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/er/erosmb/package.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  fetchFromGitHub,
+  python3,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "erosmb";
+  version = "0.1.5";
+  format = "pyproject";
+
+  src = fetchFromGitHub {
+    owner = "viktor02";
+    repo = "EroSmb";
+    tag = "v${version}";
+    hash = "sha256-9Zs5Z+3JiBiJkV9Ixl5pPmLv0dUT59CT0UkQDsmneWc=";
+  };
+
+  propagatedBuildInputs = with python3.pkgs; [
+    chardet
+    colorama
+    cryptography
+    impacket
+    ldap3
+    ldapdomaindump
+    pyasn1
+    setuptools
+    six
+  ];
+
+  # Project has no tests
+  doCheck = false;
+
+  doInstallCheck = true;
+
+  installCheckPhase = ''
+    runHook preInstallCheck
+    $out/bin/erosmb --help
+    runHook postInstallCheck
+  '';
+
+  meta = {
+    description = "SMB network scanner";
+    homepage = "https://github.com/viktor02/EroSmb";
+    changelog = "https://github.com/viktor02/EroSmb/releases/tag/v${version}";
+    license = with lib.licenses; [ mit ];
+    maintainers = with lib.maintainers; [ fab ];
+    mainProgram = "erosmb";
+  };
+}

pkgs/by-name/er/errands/package.nix

@@ -0,0 +1,79 @@
+{
+  lib,
+  fetchFromGitHub,
+  python3Packages,
+  gobject-introspection,
+  libadwaita,
+  wrapGAppsHook4,
+  meson,
+  ninja,
+  desktop-file-utils,
+  pkg-config,
+  appstream,
+  libsecret,
+  libportal,
+  gtk4,
+  gtksourceview5,
+  nix-update-script,
+}:
+python3Packages.buildPythonApplication rec {
+  pname = "errands";
+  version = "46.2.8";
+
+  pyproject = false;
+
+  src = fetchFromGitHub {
+    owner = "mrvladus";
+    repo = "Errands";
+    tag = version;
+    hash = "sha256-Gs3/DPMsoPTxH+fR7H3gPJr8ITrQDPlmw236vDnmBaA";
+  };
+
+  nativeBuildInputs = [
+    gobject-introspection
+    wrapGAppsHook4
+    desktop-file-utils
+    meson
+    ninja
+    pkg-config
+    appstream
+    gtk4
+  ];
+
+  buildInputs = [
+    libadwaita
+    libportal
+    libsecret
+    gtksourceview5
+  ];
+
+  propagatedBuildInputs = with python3Packages; [
+    pygobject3
+    lxml
+    caldav
+    pycryptodomex
+  ];
+
+  dontWrapGApps = true;
+
+  preFixup = ''
+    makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
+  '';
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Manage your tasks";
+    changelog = "https://github.com/mrvladus/Errands/releases/tag/${version}";
+    homepage = "https://github.com/mrvladus/Errands";
+    license = lib.licenses.mit;
+    mainProgram = "errands";
+    maintainers = with lib.maintainers; [
+      luftmensch-luftmensch
+      sund3RRR
+    ];
+    teams = [ lib.teams.gnome-circle ];
+  };
+}

pkgs/by-name/er/errbot/package.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  fetchFromGitHub,
+  python3,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "errbot";
+  version = "6.2.0";
+
+  format = "pyproject";
+
+  src = fetchFromGitHub {
+    owner = "errbotio";
+    repo = "errbot";
+    rev = version;
+    hash = "sha256-UdqzBrlcb9NkuVo8ChADJmaKevadoGLyZUrckStb5ko=";
+  };
+
+  build-system = with python3.pkgs; [
+    setuptools
+  ];
+
+  pythonRelaxDeps = true;
+
+  dependencies = with python3.pkgs; [
+    ansi
+    colorlog
+    daemonize
+    deepmerge
+    dulwich
+    flask
+    irc
+    jinja2
+    markdown
+    pyasn1
+    pyasn1-modules
+    pygments
+    pygments-markdown-lexer
+    pyopenssl
+    requests
+    setuptools
+    slixmpp
+    python-telegram-bot
+    webtest
+  ];
+
+  nativeCheckInputs = with python3.pkgs; [
+    mock
+    pytestCheckHook
+  ];
+
+  disabledTests = [
+    # require networking
+    "test_backup"
+    "test_broken_plugin"
+    "test_plugin_cycle"
+    "test_entrypoint_paths"
+  ];
+
+  pythonImportsCheck = [ "errbot" ];
+
+  meta = {
+    changelog = "https://github.com/errbotio/errbot/blob/${version}/CHANGES.rst";
+    description = "Chatbot designed to be simple to extend with plugins written in Python";
+    homepage = "http://errbot.io/";
+    maintainers = with lib.maintainers; [ hlad ];
+    license = lib.licenses.gpl3Plus;
+    platforms = lib.platforms.linux;
+    # flaky on darwin, "RuntimeError: can't start new thread"
+    mainProgram = "errbot";
+  };
+}

pkgs/by-name/er/errcheck/package.nix

@@ -0,0 +1,29 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildGoModule,
+}:
+
+buildGoModule rec {
+  pname = "errcheck";
+  version = "1.9.0";
+
+  src = fetchFromGitHub {
+    owner = "kisielk";
+    repo = "errcheck";
+    rev = "v${version}";
+    hash = "sha256-DhOoJL4InJHl4ImIrhV086a++srC5E4LF2VQb838+L8=";
+  };
+
+  vendorHash = "sha256-znkT0S13wCB47InP2QBCZqeWxDdEeIwQPoVWoxiAosQ=";
+
+  subPackages = [ "." ];
+
+  meta = with lib; {
+    description = "Checks for unchecked errors in go programs";
+    mainProgram = "errcheck";
+    homepage = "https://github.com/kisielk/errcheck";
+    license = licenses.mit;
+    maintainers = with maintainers; [ kalbasit ];
+  };
+}