push sheeet

pkgs/by-name/eu/eudev/package.nix

@@ -0,0 +1,97 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  gperf,
+  kmod,
+  pkg-config,
+  util-linux,
+  testers,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "eudev";
+  version = "3.2.14";
+
+  src = fetchFromGitHub {
+    owner = "eudev-project";
+    repo = "eudev";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-v/szzqrBedQPRGYkZ0lV9rslCH//uqGp4PHEF0/51Lg=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    gperf
+    pkg-config
+  ];
+
+  buildInputs = [
+    kmod
+    util-linux
+  ];
+
+  configureFlags = [
+    "--localstatedir=/var"
+    "--sysconfdir=/etc"
+  ];
+
+  makeFlags = [
+    "hwdb_bin=/var/lib/udev/hwdb.bin"
+    "udevrulesdir=/etc/udev/rules.d"
+  ];
+
+  preInstall = ''
+    # Disable install-exec-hook target, as it conflicts with our move-sbin
+    # setup-hook
+
+    sed -i 's;$(MAKE) $(AM_MAKEFLAGS) install-exec-hook;$(MAKE) $(AM_MAKEFLAGS);g' src/udev/Makefile
+  '';
+
+  installFlags = [
+    "localstatedir=$(TMPDIR)/var"
+    "sysconfdir=$(out)/etc"
+    "udevconfdir=$(out)/etc/udev"
+    "udevhwdbbin=$(out)/var/lib/udev/hwdb.bin"
+    "udevhwdbdir=$(out)/var/lib/udev/hwdb.d"
+    "udevrulesdir=$(out)/var/lib/udev/rules.d"
+  ];
+
+  passthru.tests = {
+    pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = {
+    homepage = "https://github.com/eudev-project/eudev";
+    description = "Fork of udev with the aim of isolating it from init";
+    longDescription = ''
+      eudev is a standalone dynamic and persistent device naming support (aka
+      userspace devfs) daemon that runs independently from the init
+      system. eudev strives to remain init system and linux distribution
+      neutral. It is currently used as the devfs manager for more than a dozen
+      different linux distributions.
+
+      This git repo is a fork of systemd repository with the aim of isolating
+      udev from any particular flavor of system initialization. In this case,
+      the isolation is from systemd.
+
+      This is a project started by Gentoo developers and testing was initially
+      being done mostly on OpenRC. We welcome contribution from others using a
+      variety of system initializations to ensure eudev remains system
+      initialization and distribution neutral. On 2021-08-20 Gentoo decided to
+      abandon eudev and a new project was established on 2021-09-14 by Alpine,
+      Devuan and Gentoo contributors.
+    '';
+    changelog = "https://github.com/eudev-project/eudev/releases/tag/${finalAttrs.src.rev}";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      raskin
+    ];
+    pkgConfigModules = [
+      "libudev"
+      "udev"
+    ];
+    inherit (kmod.meta) platforms;
+  };
+})

pkgs/by-name/eu/eudic/package.nix

@@ -0,0 +1,91 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  autoPatchelfHook,
+  desktop-file-utils,
+  dpkg,
+  makeWrapper,
+  libnotify,
+  libX11,
+  libXScrnSaver,
+  libXext,
+  libXtst,
+  libuuid,
+  libsecret,
+  xdg-utils,
+  xdg-utils-cxx,
+  at-spi2-atk,
+  # additional dependencies autoPatchelfHook discovered
+  gtk3,
+  alsa-lib,
+  e2fsprogs,
+  nss,
+  libgpg-error,
+  libjack2,
+  libgbm,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "eudic";
+  version = "13.5.2";
+
+  src = fetchurl {
+    name = "eudic.deb";
+    url = "https://www.eudic.net/download/eudic.deb?v=${finalAttrs.version}";
+    hash = "sha256-UPkDRaqWF/oydH6AMo3t3PUT5VU961EPLcFb5XwOXVs=";
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+    desktop-file-utils
+    dpkg
+    makeWrapper
+  ];
+
+  buildInputs = [
+    libnotify
+    libX11
+    libXScrnSaver
+    libXext
+    libXtst
+    libuuid
+    libsecret
+    xdg-utils
+    xdg-utils-cxx
+    at-spi2-atk
+    # additional dependencies autoPatchelfHook discovered
+    gtk3
+    alsa-lib
+    e2fsprogs
+    nss
+    libgpg-error
+    libjack2
+    libgbm
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    rm -r usr/share/icons
+    desktop-file-edit usr/share/applications/eusoft-eudic.desktop \
+      --set-key="Exec" --set-value="eudic %F"
+    mkdir -p $out/bin
+    cp -r usr/share $out/share
+    makeWrapper $out/share/eusoft-eudic/eudic $out/bin/eudic \
+      --inherit-argv0 \
+      --set GST_PLUGIN_PATH $out/share/eusoft-eudic/gstreamer-1.0
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Authoritative English Dictionary Software Essential Tools for English Learners";
+    homepage = "https://www.eudic.net/v4/en/app/eudic";
+    platforms = [ "x86_64-linux" ];
+    license = lib.licenses.unfree;
+    maintainers = with lib.maintainers; [ onedragon ];
+    mainProgram = "eudic";
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+  };
+})

pkgs/by-name/eu/eukleides/gs-allowpstransparency.patch

@@ -0,0 +1,10 @@
+--- a/bash/euktopdf
++++ b/bash/euktopdf
+@@ -55,6 +55,6 @@ do
+     exit 1
+   fi
+   dvips -q -E -o $base.eps $base.dvi &&
+-  epstopdf $base.eps &&
++  epstopdf --gsopt=-dALLOWPSTRANSPARENCY $base.eps &&
+   rm -f $base.{tex,log,dvi,eps}
+ done

pkgs/by-name/eu/eukleides/package.nix

@@ -0,0 +1,121 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  bison,
+  flex,
+  makeWrapper,
+  getopt,
+  readline,
+  texinfo,
+  texlive,
+  versionCheckHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "eukleides";
+  version = "1.5.4";
+
+  src = fetchFromGitLab {
+    # official upstream www.eukleides.org is down
+    domain = "salsa.debian.org";
+    owner = "georgesk";
+    repo = "eukleides";
+    rev = "upstream/${finalAttrs.version}";
+    hash = "sha256-keX7k14X/97zHh87A/7vUsfGc/S6fByd+rewW+LkJeM=";
+  };
+
+  patches = [
+    # use $CC instead of hardcoded gcc
+    ./use-CC.patch
+    # allow PostScript transparency in epstopdf call
+    ./gs-allowpstransparency.patch
+    # fix curly brace escaping in eukleides.texi for newer texinfo compatiblity
+    ./texinfo-escape.patch
+  ];
+
+  nativeBuildInputs = [
+    bison
+    flex
+    texinfo
+    makeWrapper
+  ];
+
+  buildInputs = [
+    getopt
+    readline
+  ];
+
+  preConfigure = ''
+    substituteInPlace Makefile \
+      --replace-fail mktexlsr true
+
+    substituteInPlace doc/Makefile \
+      --replace-fail ginstall-info install-info
+
+    substituteInPlace Config \
+      --replace-fail '/usr/local' "$out" \
+      --replace-fail '$(SHARE_DIR)/texmf' "$tex"
+  '';
+
+  # Workaround build failure on -fno-common toolchains like upstream
+  # gcc-10. Otherwise build fails as:
+  #   ld: eukleides_build/triangle.o:(.bss+0x28): multiple definition of `A';
+  #     eukleides_build/quadrilateral.o:(.bss+0x18): first defined here
+  env.NIX_CFLAGS_COMPILE = "-fcommon";
+
+  preBuild = ''
+    mkdir build/eukleides_build
+    mkdir build/euktopst_build
+  '';
+
+  enableParallelBuilding = true;
+
+  preInstall = ''
+    mkdir -p $out/bin
+  '';
+
+  postInstall = ''
+    wrapProgram $out/bin/euktoeps \
+      --prefix PATH : ${lib.makeBinPath [ getopt ]}
+  '';
+
+  outputs = [
+    "out"
+    "doc"
+    "tex"
+  ];
+
+  passthru = {
+    tlType = "run";
+    # packages needed by euktoeps, euktopdf and eukleides.sty
+    tlDeps = with texlive; [
+      collection-pstricks
+      epstopdf
+      iftex
+      moreverb
+    ];
+    pkgs = [ finalAttrs.finalPackage.tex ];
+  };
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "--version";
+
+  meta = {
+    description = "Geometry Drawing Language";
+    homepage = "http://www.eukleides.org/";
+    license = lib.licenses.gpl3Plus;
+
+    longDescription = ''
+      Eukleides is a computer language devoted to elementary plane
+      geometry. It aims to be a fairly comprehensive system to create
+      geometric figures, either static or dynamic. Eukleides allows to
+      handle basic types of data: numbers and strings, as well as
+      geometric types of data: points, vectors, sets (of points), lines,
+      circles and conics.
+    '';
+
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/eu/eukleides/texinfo-escape.patch

@@ -0,0 +1,19 @@
+--- a/doc/eukleides.texi
++++ b/doc/eukleides.texi
+@@ -6,12 +6,12 @@
+ 
+ % ------------------------------------------------------------------------------
+ 
+-\def\LaTeX{L\kern-.34em\raise.49ex\hbox{\sevenrm A}\kern-.18em\TeX}
+-\def\mdeg{$^\circ$}
++\def\LaTeX@{L\kern-.34em\raise.49ex\hbox@{\sevenrm A@}\kern-.18em\TeX@}
++\def\mdeg@{$^\circ$@}
+ \font\degfont=cmtt8
+-\def\deg{\raise.7ex\hbox{\degfont o}}
+-\def\exm#1{\noindent{\textit Example:}\quad{\texttt #1}}
+-\def\exmp{\noindent{\textit Example:}}
++\def\deg@{\raise.7ex\hbox@{\degfont o@}@}
++\def\exm#1@{\noindent@{\textit Example:@}\quad@{\texttt #1@}@}
++\def\exmp@{\noindent@{\textit Example:@}@}
+ 
+ % ------------------------------------------------------------------------------

pkgs/by-name/eu/eukleides/use-CC.patch

@@ -0,0 +1,11 @@
+--- a/build/Makefile
++++ b/build/Makefile
+@@ -11,7 +11,7 @@ LEX = flex
+ LFLAGS = -8
+ YACC = bison
+ YFLAGS = -d
+-CC = gcc
++CC ?= gcc
+ IFLAGS = -I$(COMMON_DIR) -I$(MAIN_DIR) -I$(BUILD_DIR) 
+ ifneq ($(strip $(LOCALES)),)
+ MOFLAGS = -DMO_DIR=\"$(MO_DIR)\" 

pkgs/by-name/eu/eunomia/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchzip,
+}:
+
+let
+  majorVersion = "0";
+  minorVersion = "200";
+in
+stdenvNoCC.mkDerivation {
+  pname = "eunomia";
+  version = "${majorVersion}.${minorVersion}";
+
+  src = fetchzip {
+    url = "https://dotcolon.net/download/fonts/eunomia_${majorVersion}${minorVersion}.zip";
+    hash = "sha256-Rd2EakaTWjzoEV00tHTgg/bXgJUFfPjCyQUWi7QhFG4=";
+    stripRoot = false;
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    install -D -m444 -t $out/share/fonts/opentype $src/*.otf
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "http://dotcolon.net/font/eunomia/";
+    description = "Futuristic decorative font";
+    platforms = platforms.all;
+    maintainers = with maintainers; [
+      leenaars
+      minijackson
+    ];
+    license = licenses.ofl;
+  };
+}

pkgs/by-name/eu/euphonica/package.nix

@@ -0,0 +1,87 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nix-update-script,
+  cargo,
+  meson,
+  ninja,
+  pkg-config,
+  rustPlatform,
+  rustc,
+  wrapGAppsHook4,
+  cairo,
+  dbus,
+  gdk-pixbuf,
+  glib,
+  gtk4,
+  libadwaita,
+  openssl,
+  pango,
+  pipewire,
+  sqlite,
+  desktop-file-utils,
+  libxml2,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "euphonica";
+  version = "0.96.4-beta";
+
+  src = fetchFromGitHub {
+    owner = "htkhiem";
+    repo = "euphonica";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-iPkqTnC5Gg2hnzQ2Lul5aXF5QhYpHQ1MiilvNiKHFdc=";
+    fetchSubmodules = true;
+  };
+
+  passthru.updateScript = nix-update-script {
+    # to be dropped once there are stable releases
+    extraArgs = [
+      "--version=unstable"
+    ];
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit (finalAttrs) pname version src;
+    hash = "sha256-AISBkWJ0ZZy2HdZCwW6S5DcD09nVJOmglsoevCaD/3g=";
+  };
+
+  mesonBuildType = "release";
+
+  nativeBuildInputs = [
+    cargo
+    meson
+    ninja
+    pkg-config
+    rustPlatform.bindgenHook
+    rustPlatform.cargoSetupHook
+    rustc
+    wrapGAppsHook4
+    desktop-file-utils
+  ];
+
+  buildInputs = [
+    cairo
+    dbus
+    gdk-pixbuf
+    glib
+    gtk4
+    libadwaita
+    openssl
+    pango
+    pipewire
+    sqlite
+    libxml2
+  ];
+
+  meta = {
+    description = "MPD client with delusions of grandeur, made with Rust, GTK and Libadwaita";
+    homepage = "https://github.com/htkhiem/euphonica";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ paperdigits ];
+    mainProgram = "euphonica";
+    platforms = with lib.platforms; linux;
+  };
+})

pkgs/by-name/eu/eureka-editor/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+  fltk,
+  zlib,
+  xdg-utils,
+  xorg,
+  libjpeg,
+  libGLU,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "eureka-editor";
+  version = "1.27b";
+
+  src = fetchzip {
+    url = "mirror://sourceforge/eureka-editor/Eureka/${lib.versions.majorMinor version}/eureka-${version}-source.tar.gz";
+    sha256 = "075w7xxsgbgh6dhndc1pfxb2h1s5fhsw28yl1c025gmx9bb4v3bf";
+  };
+
+  buildInputs = [
+    fltk
+    zlib
+    xdg-utils
+    libjpeg
+    xorg.libXinerama
+    libGLU
+  ];
+
+  enableParallelBuilding = true;
+
+  postPatch = ''
+    substituteInPlace src/main.cc --replace /usr/local $out
+    substituteInPlace Makefile    --replace /usr/local $out
+  '';
+
+  preInstall = ''
+    mkdir -p $out/bin $out/share/applications $out/share/icons $out/man/man6
+    cp misc/eureka.desktop $out/share/applications
+    cp misc/eureka.ico $out/share/icons
+    cp misc/eureka.6 $out/man/man6
+  '';
+
+  meta = with lib; {
+    homepage = "https://eureka-editor.sourceforge.net";
+    description = "Map editor for the classic DOOM games, and a few related games such as Heretic and Hexen";
+    mainProgram = "eureka";
+    license = licenses.gpl2Plus;
+    platforms = platforms.all;
+    badPlatforms = platforms.darwin;
+  };
+}

pkgs/by-name/eu/eureka-ideas/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  libgit2,
+  openssl,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "eureka-ideas";
+  version = "2.0.0";
+
+  src = fetchFromGitHub {
+    owner = "simeg";
+    repo = "eureka";
+    rev = "v${version}";
+    sha256 = "sha256-NJ1O8+NBG0y39bMOZeah2jSZlvnPrtpCtXrgAYmVrAc=";
+  };
+
+  cargoHash = "sha256-nTYMKJ5OCApqooIF1dsDLriPfYjkZkTdtzpkJya/5ag=";
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    libgit2
+    openssl
+  ];
+
+  useNextest = true;
+
+  meta = {
+    description = "CLI tool to input and store your ideas without leaving the terminal";
+    homepage = "https://github.com/simeg/eureka";
+    changelog = "https://github.com/simeg/eureka/blob/v${version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ figsoda ];
+    mainProgram = "eureka";
+  };
+}

pkgs/by-name/eu/eurofurence/package.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchzip,
+}:
+
+stdenvNoCC.mkDerivation {
+  pname = "eurofurence";
+  version = "2000-04-21";
+
+  srcs =
+    map
+      (
+        { url, hash }:
+        fetchzip {
+          name = baseNameOf url;
+          stripRoot = false;
+          inherit url hash;
+        }
+      )
+      [
+        {
+          url = "https://web.archive.org/web/20200131023120/http://eurofurence.net/eurof_tt.zip";
+          hash = "sha256-Al4tT2/qV9/K5le/OctybxgPcNMVDJi0OPr2EUBk8cE=";
+        }
+        {
+          url = "https://web.archive.org/web/20200130083325/http://eurofurence.net/eurofctt.zip";
+          hash = "sha256-ZF0Neysp0+TQgNAN+2IrfR/7dn043rSq6S3NHJ3gLUI=";
+        }
+        {
+          url = "https://web.archive.org/web/20200206093756/http://eurofurence.net/monof_tt.zip";
+          hash = "sha256-Kvcsp/0LzHhwPudP1qWLxhaiJ5/su1k7FBuV9XPKIGs=";
+        }
+        {
+          url = "https://web.archive.org/web/20200206171841/http://eurofurence.net/pagebxtt.zip";
+          hash = "sha256-CvKhzvxSQqdEHihQBfCSu1QgjzKn38DWaONdz5BpM4M=";
+        }
+        {
+          url = "https://web.archive.org/web/20190812003003/http://eurofurence.net/unifurtt.zip";
+          hash = "sha256-n9xnzJi8wvK6oCVQUQnQ1X9jW6WgyMKKIiDsT4j2Aas=";
+        }
+      ];
+
+  dontUnpack = true;
+
+  installPhase = ''
+    runHook preInstall
+    for src in $srcs; do
+      install -D $src/*.ttf -t $out/share/fonts/truetype
+      install -D $src/*.txt -t $out/share/doc/$name
+    done
+    runHook postInstall
+  '';
+
+  meta = {
+    homepage = "https://web.archive.org/web/20200131023120/http://eurofurence.net/eurofurence.html";
+    description = "Family of geometric rounded sans serif fonts";
+    license = lib.licenses.free;
+  };
+}