push sheeet

pkgs/by-name/f3/f3/package.nix

@@ -0,0 +1,64 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  parted,
+  systemd,
+  argp-standalone,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "f3";
+  version = "9.0";
+
+  src = fetchFromGitHub {
+    owner = "AltraMayor";
+    repo = "f3";
+    rev = "v${version}";
+    sha256 = "sha256-ZajlFGXJcYUVe/wUFfdPYVW8stOo1Aqe8uD2Bm9KIk0=";
+  };
+
+  postPatch = ''
+    sed -i 's/-oroot -groot//' Makefile
+
+    for f in f3write.h2w log-f3wr; do
+     substituteInPlace $f \
+       --replace '$(dirname $0)' $out/bin
+    done
+  '';
+
+  buildInputs =
+    lib.optionals stdenv.hostPlatform.isLinux [
+      systemd
+      parted
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isDarwin [ argp-standalone ];
+
+  buildFlags = [
+    "all" # f3read, f3write
+  ]
+  ++ lib.optional stdenv.hostPlatform.isLinux "extra"; # f3brew, f3fix, f3probe
+
+  installFlags = [
+    "PREFIX=${placeholder "out"}"
+  ];
+
+  installTargets = [
+    "install"
+  ]
+  ++ lib.optional stdenv.hostPlatform.isLinux "install-extra";
+
+  postInstall = ''
+    install -Dm555 -t $out/bin f3write.h2w log-f3wr
+    install -Dm444 -t $out/share/doc/f3 LICENSE README.rst
+  '';
+
+  meta = with lib; {
+    description = "Fight Flash Fraud";
+    homepage = "https://fight-flash-fraud.readthedocs.io/en/stable/";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [
+      makefu
+    ];
+  };
+}

pkgs/by-name/f3/f3d/package.nix

@@ -0,0 +1,98 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  cmake,
+  help2man,
+  gzip,
+  libXt,
+  openusd,
+  onetbb,
+  vtk,
+  autoPatchelfHook,
+  python3Packages,
+  opencascade-occt,
+  assimp,
+  fontconfig,
+  withManual ? !stdenv.hostPlatform.isDarwin,
+  withPythonBinding ? false,
+  withUsd ? openusd.meta.available,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "f3d";
+  version = "3.2.0";
+
+  outputs = [ "out" ] ++ lib.optionals withManual [ "man" ];
+
+  src = fetchFromGitHub {
+    owner = "f3d-app";
+    repo = "f3d";
+    tag = "v${version}";
+    hash = "sha256-p1Cqam3sYDXJCU1A2sC/fV1ohxS3FGiVrxeGooNXVBQ=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ]
+  ++ lib.optionals withManual [
+    # manpage
+    help2man
+    gzip
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isElf [
+    # https://github.com/f3d-app/f3d/pull/1217
+    autoPatchelfHook
+  ];
+
+  buildInputs = [
+    vtk
+    opencascade-occt
+    assimp
+    fontconfig
+  ]
+  ++ lib.optionals withPythonBinding [
+    python3Packages.python
+    # Using C++ header files, not Python import
+    python3Packages.pybind11
+  ]
+  ++ lib.optionals withUsd [
+    libXt
+    openusd
+    onetbb
+  ];
+
+  cmakeFlags = [
+    # conflict between VTK and Nixpkgs;
+    # see https://github.com/NixOS/nixpkgs/issues/89167
+    "-DCMAKE_INSTALL_LIBDIR=lib"
+    "-DCMAKE_INSTALL_INCLUDEDIR=include"
+    "-DCMAKE_INSTALL_BINDIR=bin"
+    "-DF3D_MODULE_EXTERNAL_RENDERING=ON"
+    "-DF3D_PLUGIN_BUILD_ASSIMP=ON"
+    "-DF3D_PLUGIN_BUILD_OCCT=ON"
+  ]
+  ++ lib.optionals withManual [
+    "-DF3D_LINUX_GENERATE_MAN=ON"
+  ]
+  ++ lib.optionals withPythonBinding [
+    "-DF3D_BINDINGS_PYTHON=ON"
+  ]
+  ++ lib.optionals withUsd [
+    "-DF3D_PLUGIN_BUILD_USD=ON"
+  ];
+
+  meta = {
+    description = "Fast and minimalist 3D viewer using VTK";
+    homepage = "https://f3d-app.github.io/f3d";
+    changelog = "https://github.com/f3d-app/f3d/releases/tag/v${version}";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [
+      bcdarwin
+      pbsds
+    ];
+    platforms = with lib.platforms; unix;
+    mainProgram = "f3d";
+  };
+}