push sheeet

pkgs/by-name/fc/fcron/package.nix

@@ -0,0 +1,68 @@
+# restart using 'killall -TERM fcron; fcron -b
+# use convert-fcrontab to update fcrontab files
+
+{
+  lib,
+  stdenv,
+  fetchurl,
+  perl,
+  busybox,
+  vim,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "fcron";
+  version = "3.4.0";
+
+  src = fetchurl {
+    url = "http://fcron.free.fr/archives/${pname}-${version}.src.tar.gz";
+    sha256 = "sha256-9Of8VTzdcP9LO2rJE4s7fP+rkZi4wmbZevCodQbg4bU=";
+  };
+
+  buildInputs = [ perl ];
+
+  patches = [ ./relative-fcronsighup.patch ];
+
+  configureFlags = [
+    "--with-sendmail=${busybox}/sbin/sendmail"
+    "--with-editor=${vim}/bin/vi" # TODO customizable
+    "--with-bootinstall=no"
+    "--localstatedir=/var"
+    "--sysconfdir=/etc"
+    "--with-rootname=root"
+    "--with-rootgroup=root"
+    "--disable-checks"
+  ];
+
+  installTargets = [ "install-staged" ]; # install does also try to change permissions of /etc/* files
+
+  # fcron tries to install pid into system directory on install
+  installFlags = [
+    "ETC=."
+    "PIDDIR=."
+    "PIDFILE=fcron.pid"
+    "REBOOT_LOCK=fcron.reboot"
+    "FIFODIR=."
+    "FIFOFILE=fcron.fifo"
+    "FCRONTABS=."
+  ];
+
+  preConfigure = ''
+    sed -i 's@/usr/bin/env perl@${perl}/bin/perl@g' configure script/*
+    # Don't let fcron create the group fcron, nix(os) should do this
+    sed -i '2s@.*@exit 0@' script/user-group
+
+    # --with-bootinstall=no shoud do this, didn't work. So just exit the script before doing anything
+    sed -i '2s@.*@exit 0@' script/boot-install
+
+    # also don't use chown or chgrp for documentation (or whatever) when installing
+    find -type f | xargs sed -i -e 's@^\(\s\)*chown@\1:@' -e 's@^\(\s\)*chgrp@\1:@'
+  '';
+
+  meta = with lib; {
+    description = "Command scheduler with extended capabilities over cron and anacron";
+    homepage = "http://fcron.free.fr";
+    license = licenses.gpl2Plus;
+    platforms = lib.platforms.all;
+  };
+}

pkgs/by-name/fc/fcron/relative-fcronsighup.patch

@@ -0,0 +1,16 @@
+Use relative fcronsighup to prefer setuid executable over package binary.
+--- fcron-3.2.1.orig/fcrontab.c	2016-06-26 17:02:48.000000000 +0200
++++ fcron-3.2.1/fcrontab.c	2017-03-05 21:54:24.676871335 +0100
+@@ -154,10 +154,10 @@
+                         fcrontab_gid);
+                 exit(ERR);
+             }
+-            execl(BINDIREX "/fcronsighup", BINDIREX "/fcronsighup", fcronconf,
++            execlp("fcronsighup",  "fcronsighup", fcronconf,
+                   NULL);
+ 
+-            error_e("Could not exec " BINDIREX " fcronsighup");
++            error_e("Could not exec fcronsighup");
+             exit(ERR);
+             break;
+