push sheeet

pkgs/by-name/fg/fg-virgil/package.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  woff2,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "fg-virgil";
+  version = "0.18.0";
+
+  src = fetchFromGitHub {
+    owner = "excalidraw";
+    repo = "excalidraw";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Nfzh5rNvHP7R418PP44FXD7xNenzmzMHu7RLAdJsE/c=";
+  };
+
+  nativeBuildInputs = [
+    woff2
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+
+    for file in packages/excalidraw/fonts/Virgil/*.woff2; do
+      woff2_decompress $file
+    done
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -D -m 444 packages/excalidraw/fonts/Virgil/*.ttf -t $out/share/fonts/ttf
+    install -D -m 444 packages/excalidraw/fonts/Virgil/*.woff2 -t $out/share/fonts/woff2
+
+    runHook postInstall
+  '';
+
+  meta = {
+    homepage = "https://github.com/excalidraw/virgil";
+    description = "Font that powers Excalidraw";
+    platforms = lib.platforms.all;
+    maintainers = [ ];
+    license = lib.licenses.ofl;
+  };
+})

pkgs/by-name/fg/fgallery/package.nix

@@ -0,0 +1,85 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  unzip,
+  makeWrapper,
+  perlPackages,
+  coreutils,
+  zip,
+  imagemagick,
+  pngcrush,
+  lcms2,
+  facedetect,
+  fbida,
+}:
+
+# TODO: add optional dependencies (snippet from fgallery source):
+#
+# if(system("jpegoptim -V >/dev/null 2>&1")) {
+#   $jpegoptim = 0;
+# }
+
+stdenv.mkDerivation rec {
+  pname = "fgallery";
+  version = "1.9.1";
+
+  src = fetchurl {
+    url = "https://www.thregr.org/~wavexx/software/fgallery/releases/fgallery-${version}.zip";
+    hash = "sha256-FvF0wkRe3wTPUG9/GEBxkaxvZ1B4wEd9kI9rURHKxn0=";
+  };
+
+  nativeBuildInputs = [
+    makeWrapper
+    unzip
+  ];
+  buildInputs = (
+    with perlPackages;
+    [
+      perl
+      ImageExifTool
+      CpanelJSONXS
+    ]
+  );
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace "/usr" $out
+  '';
+
+  installPhase = ''
+    mkdir -p "$out/bin"
+    mkdir -p "$out/share/fgallery"
+
+    cp -r * "$out/share/fgallery"
+    ln -s -r "$out/share/fgallery/fgallery" "$out/bin/fgallery"
+
+    # Don't preserve file attributes when copying files to output directories.
+    # (fgallery copies parts of itself to each output directory, and without
+    # this change the read-only nix store causes some bumps in the workflow.)
+    sed -i -e "s|'cp'|'cp', '--no-preserve=all'|g" "$out/share/fgallery/fgallery"
+
+    wrapProgram "$out/share/fgallery/fgallery" \
+        --set PERL5LIB "$PERL5LIB" \
+        --set PATH "${
+          lib.makeBinPath [
+            coreutils
+            zip
+            imagemagick
+            pngcrush
+            lcms2
+            facedetect
+            fbida
+          ]
+        }"
+  '';
+
+  meta = with lib; {
+    description = "Static photo gallery generator";
+    homepage = "https://www.thregr.org/~wavexx/software/fgallery/";
+    license = licenses.gpl2Only;
+    platforms = platforms.all;
+    maintainers = [ maintainers.bjornfor ];
+    mainProgram = "fgallery";
+  };
+}

pkgs/by-name/fg/fgqcanvas/package.nix

@@ -0,0 +1,54 @@
+{
+  fetchgit,
+  pkg-config,
+  stdenv,
+  lib,
+  # Package dependencies
+  qt5,
+}:
+
+stdenv.mkDerivation {
+  pname = "fgqcanvas";
+  version = "0-unstable-2024-02-11";
+
+  src = fetchgit {
+    url = "https://git.code.sf.net/p/flightgear/flightgear";
+    rev = "3168828949d6b42959ccee6c202b8895493edb2b";
+    hash = "sha256-QiIMkrzaB/ljVf6c+RJNFWKLZa84cIjYPO5nxEFDqjg=";
+  };
+
+  nativeBuildInputs = [
+    qt5.wrapQtAppsHook
+    qt5.qmake
+    pkg-config
+    qt5.qttools
+  ];
+  buildInputs = [
+    qt5.qtwebsockets
+  ];
+
+  configurePhase = ''
+    runHook preConfigure
+    cd utils/fgqcanvas/
+    mkdir -p build
+    cd build
+    qmake -makefile ../fgcanvas.pro CONFIG+="release" QMAKE_CXXFLAGS+=' -Wno-deprecated-copy -Wno-deprecated -Wno-deprecated-declarations'
+    runHook postConfigure
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    mv fgqcanvas $out/bin/
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://sourceforge.net/p/flightgear/flightgear/ci/next/tree/utils/fgqcanvas/README.md";
+    description = "Qt-based remote canvas application for FlightGear";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = [ ];
+    mainProgram = "fgqcanvas";
+  };
+}