push sheeet

pkgs/by-name/fi/fider/0001-disable-etc-copy.patch

@@ -0,0 +1,12 @@
+diff --git a/app/cmd/server.go b/app/cmd/server.go
+index fcfbeec2..71f01c9d 100644
+--- a/app/cmd/server.go
++++ b/app/cmd/server.go
+@@ -46,7 +46,6 @@ func RunServer() int {
+ 		})
+ 	}
+ 
+-	copyEtcFiles(ctx)
+ 	startJobs(ctx)
+ 
+ 	e := routes(web.New())

pkgs/by-name/fi/fider/frontend.nix

@@ -0,0 +1,37 @@
+{
+  buildNpmPackage,
+
+  pname,
+  version,
+  src,
+  npmDepsHash,
+}:
+
+buildNpmPackage {
+  inherit version src npmDepsHash;
+  pname = "${pname}-frontend";
+
+  buildPhase = ''
+    runHook preBuild
+
+    npx lingui extract public/
+    npx lingui compile
+    NODE_ENV=production node esbuild.config.js
+    NODE_ENV=production npx webpack-cli
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+    cp -r dist ssr.js favicon.png robots.txt $out/
+
+    runHook postInstall
+  '';
+
+  env = {
+    PLAYWRIGHT_SKIP_BROWSER_DOWNLOAD = 1;
+  };
+}

pkgs/by-name/fi/fider/package.nix

@@ -0,0 +1,82 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  callPackage,
+  nixosTests,
+  nix-update-script,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "fider";
+  version = "0.27.0";
+
+  src = fetchFromGitHub {
+    owner = "getfider";
+    repo = "fider";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-2aV6f4cgO89hIqksT/kutR+ZRTGncuS04kJ5xZZC5Ds=";
+  };
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  # Allow easier version overrides, e.g.:
+  # pkgs.fider.overrideAttrs (prev: {
+  #   version = "...";
+  #   src = prev.src.override {
+  #     hash = "...";
+  #   };
+  #   vendorHash = "...";
+  #   npmDepsHash = "...";
+  # })
+  vendorHash = "sha256-4ilOdUblpwteY0ZInitSuzuB8mU1ltYgRJjla6LiziU=";
+  npmDepsHash = "sha256-c8CFMMmFcLZkJL50bfLlk2HP9B/rexNZ2WWJkV0x4Rk=";
+
+  server = callPackage ./server.nix {
+    inherit (finalAttrs)
+      pname
+      version
+      src
+      vendorHash
+      ;
+  };
+  frontend = callPackage ./frontend.nix {
+    inherit (finalAttrs)
+      pname
+      version
+      src
+      npmDepsHash
+      ;
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/etc
+    cp -r locale views migrations $out/
+    cp -r etc/*.md $out/etc/
+    ln -s ${finalAttrs.server}/* $out/
+    ln -s ${finalAttrs.frontend}/* $out/
+
+    runHook postInstall
+  '';
+
+  passthru = {
+    tests = {
+      inherit (nixosTests) fider;
+    };
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Open platform to collect and prioritize feedback";
+    homepage = "https://github.com/getfider/fider";
+    changelog = "https://github.com/getfider/fider/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.agpl3Only;
+    mainProgram = "fider";
+    maintainers = with lib.maintainers; [
+      niklaskorz
+    ];
+  };
+})

pkgs/by-name/fi/fider/server.nix

@@ -0,0 +1,30 @@
+{
+  buildGoModule,
+
+  pname,
+  version,
+  src,
+  vendorHash,
+}:
+
+buildGoModule {
+  inherit version src vendorHash;
+  pname = "${pname}-server";
+
+  patches = [
+    ./0001-disable-etc-copy.patch
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  doCheck = false; # requires a running PostgreSQL database
+
+  # preCheck = ''
+  #   set -o allexport
+  #   source ./.test.env
+  #   set +o allexport
+  # '';
+}