push sheeet

pkgs/by-name/fr/frog/package.nix

@@ -0,0 +1,82 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  gitUpdater,
+  callPackage,
+  autoreconfHook,
+  bzip2,
+  libtar,
+  libtool,
+  pkg-config,
+  autoconf-archive,
+  libxml2,
+  icu60,
+  ticcutils,
+  timbl,
+  mbt,
+  libfolia,
+  ucto,
+  frogdata,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "frog";
+  version = "0.13.7";
+
+  src = fetchFromGitHub {
+    owner = "LanguageMachines";
+    repo = "frog";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-khc2uZ/dOtWPTnt/ZD6ILxD386MaZt6fsvNTWTCbs+c=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    autoreconfHook
+  ];
+  buildInputs = [
+    bzip2
+    libtar
+    libtool
+    autoconf-archive
+    libxml2
+    icu60
+    ticcutils
+    timbl
+    mbt
+    libfolia
+    ucto
+    frogdata
+  ];
+
+  postInstall = ''
+    # frog expects the data files installed in the same prefix
+    mkdir -p $out/share/frog/;
+    for f in ${frogdata}/share/frog/*; do
+      ln -s $f $out/share/frog/;
+    done;
+
+    make check
+  '';
+
+  passthru = {
+    updateScript = gitUpdater { rev-prefix = "v"; };
+    tests.simple = callPackage ./test.nix { frog = finalAttrs.finalPackage; };
+  };
+
+  meta = with lib; {
+    description = "Tagger-Lemmatizer-Morphological-Analyzer-Dependency-Parser for Dutch";
+    homepage = "https://languagemachines.github.io/frog";
+    license = licenses.gpl3;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ roberth ];
+
+    longDescription = ''
+      Frog is an integration of memory-based natural language processing (NLP) modules developed for Dutch. All NLP modules are based on Timbl, the Tilburg memory-based learning software package. Most modules were created in the 1990s at the ILK Research Group (Tilburg University, the Netherlands) and the CLiPS Research Centre (University of Antwerp, Belgium). Over the years they have been integrated into a single text processing tool, which is currently maintained and developed by the Language Machines Research Group and the Centre for Language and Speech Technology at Radboud University Nijmegen. A dependency parser, a base phrase chunker, and a named-entity recognizer module were added more recently. Where possible, Frog makes use of multi-processor support to run subtasks in parallel.
+
+      Various (re)programming rounds have been made possible through funding by NWO, the Netherlands Organisation for Scientific Research, particularly under the CGN project, the IMIX programme, the Implicit Linguistics project, the CLARIN-NL programme and the CLARIAH programme.
+    '';
+  };
+
+})

pkgs/by-name/fr/frog/test.nix

@@ -0,0 +1,26 @@
+{
+  runCommand,
+  frog,
+}:
+
+runCommand "frog-test" { } ''
+  ${frog}/bin/frog >$out <<EOF
+  Dit is een test
+
+  EOF
+  echo "Frog output:"
+  cat $out
+
+  expected () {
+    echo "Test expectation failed: $@"
+    exit 1
+  }
+
+  lines="$(wc -l $out | awk '{print $1}')"
+  test 5 = $lines || expected "Five lines of output"
+  grep "is" $out | grep "zijn" >/dev/null || expected "Stemming works"
+  grep "een" $out | grep "onbep" >/dev/null || expected "Tagging works"
+
+  deps="$(echo $(awk 'BEGIN { FS = "\t*" } ; {print $1 " -> " $9 "; "}' <$out))"
+  test "1 -> 2; 2 -> 0; 3 -> 4; 4 -> 2; -> ;" = "$deps" || expected "Dependency parsing works"
+''