push sheeet

pkgs/by-name/fv/fverb/package.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+}:
+
+stdenv.mkDerivation {
+  pname = "fverb";
+  # no release yet: https://github.com/jpcima/fverb/issues/2
+  version = "unstable-2020-06-09";
+
+  src = fetchFromGitHub {
+    owner = "jpcima";
+    repo = "fverb";
+    rev = "462020e33e24c0204a375dc95e2c28654cc917b8";
+    sha256 = "12nl7qn7mnykk7v8q0j2n8kfq0xc46n0i45z6qcywspadwnncmd4";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+
+  makeFlags = [ "PREFIX=${placeholder "out"}" ];
+
+  postPatch = ''
+    patchShebangs ./dpf/utils/generate-ttl.sh
+  '';
+
+  meta = with lib; {
+    description = "Stereo variant of the reverberator by Jon Dattorro, for lv2";
+    homepage = "https://github.com/jpcima/fverb";
+    license = licenses.bsd2;
+    maintainers = [ maintainers.magnetophon ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/fv/fvm/package.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  buildDartApplication,
+  fetchFromGitHub,
+  runCommand,
+  yq-go,
+  _experimental-update-script-combinators,
+  gitUpdater,
+}:
+
+let
+  version = "4.0.0-beta.1";
+
+  src = fetchFromGitHub {
+    owner = "leoafarias";
+    repo = "fvm";
+    tag = version;
+    hash = "sha256-O2VU0cXgrm+Xf85e5l31kfnUOCUI9ZuVQCVRUppqCE4=";
+  };
+in
+buildDartApplication {
+  pname = "fvm";
+  inherit version src;
+
+  pubspecLock = lib.importJSON ./pubspec.lock.json;
+
+  passthru = {
+    pubspecSource =
+      runCommand "pubspec.lock.json"
+        {
+          inherit src;
+          nativeBuildInputs = [ yq-go ];
+        }
+        ''
+          yq eval --output-format=json --prettyPrint $src/pubspec.lock > "$out"
+        '';
+    updateScript = _experimental-update-script-combinators.sequence [
+      (gitUpdater { })
+      (_experimental-update-script-combinators.copyAttrOutputToFile "fvm.pubspecSource" ./pubspec.lock.json)
+    ];
+  };
+
+  meta = {
+    description = "Simple CLI to manage Flutter SDK versions";
+    homepage = "https://github.com/leoafarias/fvm";
+    license = lib.licenses.mit;
+    maintainers = [ ];
+  };
+}

pkgs/by-name/fv/fvwm2/package.nix

@@ -0,0 +1,89 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  cairo,
+  fontconfig,
+  freetype,
+  fribidi,
+  libXcursor,
+  libXft,
+  libXinerama,
+  libXpm,
+  libXt,
+  libpng,
+  librsvg,
+  libstroke,
+  libxslt,
+  perl,
+  pkg-config,
+  python3Packages,
+  readline,
+  enableGestures ? false,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "fvwm";
+  version = "2.7.0";
+
+  src = fetchFromGitHub {
+    owner = "fvwmorg";
+    repo = "fvwm";
+    tag = version;
+    hash = "sha256-KcuX8las1n8UUE/BOHj7WOeZjva5hxgpFHtATMUk3bg=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+    python3Packages.wrapPython
+  ];
+
+  buildInputs = [
+    cairo
+    fontconfig
+    freetype
+    fribidi
+    libXcursor
+    libXft
+    libXinerama
+    libXpm
+    libXt
+    libpng
+    librsvg
+    libxslt
+    perl
+    python3Packages.python
+    readline
+  ]
+  ++ lib.optional enableGestures libstroke;
+
+  pythonPath = [
+    python3Packages.pyxdg
+  ];
+
+  configureFlags = [
+    "--enable-mandoc"
+    "--disable-htmldoc"
+  ];
+
+  # Fix build on GCC 14 (see https://github.com/fvwmorg/fvwm/pull/100)
+  # Will never be accepted as an upstream patch as FVWM2 is EOL
+  env.NIX_CFLAGS_COMPILE = "-Wno-error=int-conversion -Wno-error=incompatible-pointer-types";
+
+  postFixup = ''
+    wrapPythonPrograms
+  '';
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    homepage = "http://fvwm.org";
+    changelog = "https://github.com/fvwmorg/fvwm/releases/tag/${src.rev}";
+    description = "Multiple large virtual desktop window manager";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ edanaher ];
+  };
+}

pkgs/by-name/fv/fvwm3/package.nix

@@ -0,0 +1,119 @@
+{
+  lib,
+  asciidoctor,
+  autoreconfHook,
+  cairo,
+  fetchFromGitHub,
+  fontconfig,
+  freetype,
+  fribidi,
+  libSM,
+  libX11,
+  libXcursor,
+  libXft,
+  libXi,
+  libXinerama,
+  libXpm,
+  libXrandr,
+  libXt,
+  libevent,
+  libintl,
+  libpng,
+  librsvg,
+  libxslt,
+  perl,
+  pkg-config,
+  python3Packages,
+  readline,
+  sharutils,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "fvwm3";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "fvwmorg";
+    repo = "fvwm3";
+    rev = finalAttrs.version;
+    hash = "sha256-y1buTWO1vHzloh2e4EK1dkD0uQa7lIFUbNMkEe5x6Vo=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    asciidoctor
+    pkg-config
+    python3Packages.wrapPython
+  ];
+
+  buildInputs = [
+    cairo
+    fontconfig
+    freetype
+    fribidi
+    libSM
+    libX11
+    libXcursor
+    libXft
+    libXi
+    libXinerama
+    libXpm
+    libXrandr
+    libXt
+    libevent
+    libintl
+    libpng
+    librsvg
+    libxslt
+    perl
+    python3Packages.python
+    readline
+    sharutils
+  ];
+
+  pythonPath = [
+    python3Packages.pyxdg
+  ];
+
+  configureFlags = [
+    (lib.enableFeature true "mandoc")
+  ];
+
+  postFixup = ''
+    wrapPythonPrograms
+  '';
+
+  enableParallelBuilding = true;
+
+  strictDeps = true;
+
+  meta = {
+    homepage = "http://fvwm.org";
+    description = "Multiple large virtual desktop window manager - Version 3";
+    longDescription = ''
+      Fvwm is a virtual window manager for the X windows system. It was
+      originally a feeble fork of TWM by Robert Nation in 1993 (fvwm history),
+      and has evolved into the fantastic, fabulous, famous, flexible, and so on,
+      window manager we have today.
+
+      Fvwm is a ICCCM/EWMH compliant and highly configurable floating window
+      manager built primarily using Xlib. Fvwm is configured using a
+      configuration file, which is used to configure most aspects of the window
+      manager including window looks, key bindings, menus, window behavior,
+      additional modules, and more. There is a default configuration file that
+      can be used as a starting point for writing one's own configuration file.
+
+      Fvwm is a light weight window manager and can be configured to be anything
+      from a small sleek window manager to a full featured desktop
+      environment. To get the most out of fvwm, one should be willing to read
+      the documents, and take the time to write a custom configuration file that
+      suites their needs. The manual pages and the fvwm wiki can be used to help
+      learn how to configure fvwm.
+    '';
+    changelog = "https://github.com/fvwmorg/fvwm3/blob/${finalAttrs.src.rev}/CHANGELOG.md";
+    license = lib.licenses.gpl2Plus;
+    maintainers = [ ];
+    inherit (libX11.meta) platforms;
+  };
+})