push sheeet

pkgs/by-name/fz/fzf-git-sh/package.nix

@@ -0,0 +1,68 @@
+{
+  stdenv,
+  lib,
+  bash,
+  bat,
+  coreutils,
+  fetchFromGitHub,
+  findutils,
+  fzf,
+  gawk,
+  git,
+  gnugrep,
+  gnused,
+  util-linux,
+  xdg-utils,
+  zsh,
+  unstableGitUpdater,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "fzf-git-sh";
+  version = "0-unstable-2025-10-05";
+
+  src = fetchFromGitHub {
+    owner = "junegunn";
+    repo = "fzf-git.sh";
+    rev = "90d80420f679af6d120d34b6c9ceb2225dbd9649";
+    hash = "sha256-/9NhKkPdOtV3LbxPZ3FQEqpzqWZqlkh7La3ND+zZXyg=";
+  };
+
+  dontBuild = true;
+
+  postPatch = ''
+    sed -i \
+      -e "s,\bfzf\b,${fzf}/bin/fzf," \
+      -e "s,\bawk\b,${gawk}/bin/awk," \
+      -e "s,\bbash\b,${bash}/bin/bash," \
+      -e "s,\bbat\b,${bat}/bin/bat," \
+      -e "s,\bcat\b,${coreutils}/bin/cat," \
+      -e "s,\bcut\b,${coreutils}/bin/cut," \
+      -e "s,\bhead\b,${coreutils}/bin/head," \
+      -e "s,\buniq\b,${coreutils}/bin/uniq," \
+      -e "s,\bcolumn\b,${util-linux}/bin/column," \
+      -e "s,\bgrep\b,${gnugrep}/bin/grep," \
+      -e "s,\bsed\b,${gnused}/bin/sed," \
+      -e "s,\bxargs\b,${findutils}/bin/xargs," \
+      -e "s,\bxdg-open\b,${xdg-utils}/bin/xdg-open," \
+      -e "s,\bzsh\b,${zsh}/bin/zsh," \
+      -e "/display-message\|fzf-git-\$o-widget\|\burl=\|\$remote_url =~ /!s,\bgit\b,${git}/bin/git,g" \
+      -e "s,__fzf_git=.*BASH_SOURCE.*,__fzf_git=$out/share/${pname}/fzf-git.sh," \
+      -e "/__fzf_git=.*readlink.*/d" \
+      fzf-git.sh
+  '';
+
+  installPhase = ''
+    install -D fzf-git.sh $out/share/${pname}/fzf-git.sh
+  '';
+
+  passthru.updateScript = unstableGitUpdater { };
+
+  meta = with lib; {
+    homepage = "https://github.com/junegunn/fzf-git.sh";
+    description = "Bash and zsh key bindings for Git objects, powered by fzf";
+    license = licenses.mit;
+    maintainers = with maintainers; [ deejayem ];
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/fz/fzf-make/package.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  makeBinaryWrapper,
+  runtimeShell,
+  bat,
+  gnugrep,
+  gnumake,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "fzf-make";
+  version = "0.62.0";
+
+  src = fetchFromGitHub {
+    owner = "kyu08";
+    repo = "fzf-make";
+    rev = "v${version}";
+    hash = "sha256-WUQW3I/dFO510v5JzShydMO3N8QYrKqDAJUzDdUZg0U=";
+  };
+
+  cargoHash = "sha256-8V++82edFMJ8/B1aLAK2MhW2g1usg3eBt60SIUuKong=";
+
+  nativeBuildInputs = [ makeBinaryWrapper ];
+
+  postInstall = ''
+    wrapProgram $out/bin/fzf-make \
+      --set SHELL ${runtimeShell} \
+      --suffix PATH : ${
+        lib.makeBinPath [
+          bat
+          gnugrep
+          gnumake
+        ]
+      }
+  '';
+
+  meta = {
+    description = "Fuzzy finder for Makefile";
+    inherit (src.meta) homepage;
+    changelog = "https://github.com/kyu08/fzf-make/releases/tag/${src.rev}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      figsoda
+      sigmanificient
+    ];
+    mainProgram = "fzf-make";
+  };
+}

pkgs/by-name/fz/fzf-obc/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "fzf-obc";
+  version = "1.3.0";
+
+  src = fetchFromGitHub {
+    owner = "rockandska";
+    repo = "fzf-obc";
+    rev = version;
+    sha256 = "sha256-KIAlDpt1Udl+RLp3728utgQ9FCjZz/OyoG92MOJmgPI=";
+  };
+
+  dontBuild = true;
+
+  installPhase = ''
+    mkdir -p $out/share/fzf-obc/{bin,lib/fzf-obc,plugins/{kill,gradle}}
+    install -m644 bin/* $out/share/fzf-obc/bin
+    install -m644 lib/fzf-obc/* $out/share/fzf-obc/lib/fzf-obc
+    install -m644 plugins/kill/* $out/share/fzf-obc/plugins/kill
+    install -m644 plugins/gradle/* $out/share/fzf-obc/plugins/gradle
+  '';
+
+  meta = with lib; {
+    homepage = "https://fzf-obc.readthedocs.io";
+    description = "Completion script adding fzf over all know bash completion functions";
+    license = licenses.unfree;
+    maintainers = with maintainers; [ loicreynier ];
+  };
+}

pkgs/by-name/fz/fzf-preview/package.nix

@@ -0,0 +1,90 @@
+{
+  atool,
+  bat,
+  catdoc,
+  chafa,
+  exiftool,
+  eza,
+  fetchFromGitHub,
+  ffmpegthumbnailer,
+  file,
+  glow,
+  gnumeric,
+  jq,
+  lib,
+  libcdio,
+  makeWrapper,
+  mediainfo,
+  odt2txt,
+  openssl,
+  p7zip,
+  poppler-utils,
+  stdenv,
+  w3m,
+}:
+
+stdenv.mkDerivation {
+  pname = "fzf-preview";
+  version = "0-unstable-2025-06-26";
+
+  src = fetchFromGitHub {
+    owner = "niksingh710";
+    repo = "fzf-preview";
+    rev = "5f6e936d1c3943192f9bdade71cff8879bdab3a6";
+    hash = "sha256-vDgYv9PjQQYcMKG97ryncd30JPplnEqAKBp5hAE0E+o=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 -t $out/bin/ ./fzf-preview
+
+    wrapProgram $out/bin/fzf-preview \
+      --prefix PATH ":" ${
+        lib.makeBinPath [
+          atool
+          bat
+          catdoc
+          chafa
+          exiftool
+          eza
+          ffmpegthumbnailer
+          file
+          glow
+          gnumeric
+          jq
+          libcdio
+          mediainfo
+          odt2txt
+          openssl
+          p7zip
+          poppler-utils
+          w3m
+        ]
+      }
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Simple fzf preview script for previewing any filetype in fzf's preview window";
+
+    longDescription = ''
+      fzf-preview is a lightweight Bash script designed to enhance the user experience
+      with fzf (fuzzy finder) by providing instant previews of files directly in the
+      fzf preview pane. It supports a wide variety of filetypes—including images and
+      text—and delivers relevant file information in the terminal. The script aims to
+      be simple, fast, and highly compatible, making it a useful tool for anyone
+      leveraging fzf for file navigation or search.
+    '';
+    homepage = "https://github.com/niksingh710/fzf-preview";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [
+      niksingh710
+    ];
+    mainProgram = "fzf-preview";
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/fz/fzf-zsh/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fzf,
+}:
+
+stdenv.mkDerivation {
+  pname = "fzf-zsh-unstable";
+  version = "2019-09-09";
+
+  src = fetchFromGitHub {
+    owner = "Wyntau";
+    repo = "fzf-zsh";
+    rev = "829d7e40cc437dce8a6e234e259bbd4065e87124";
+    sha256 = "1irjmxhcg1fm4g8p3psjqk7sz5qhj5kw73pyhv91njvpdhn9l26z";
+  };
+
+  strictDeps = true;
+  postPatch = ''
+    substituteInPlace fzf-zsh.plugin.zsh \
+      --replace \
+        'fzf_path="$( cd "$fzf_zsh_path/../fzf/" && pwd )"' \
+        "fzf_path=${fzf}" \
+      --replace \
+        '$fzf_path/shell' \
+        '${fzf}/share/fzf'
+  '';
+
+  dontBuild = true;
+
+  installPhase = ''
+    install -Dm0644 fzf-zsh.plugin.zsh $out/share/zsh/plugins/fzf-zsh/fzf-zsh.plugin.zsh
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/wyntau/fzf-zsh";
+    description = "Wrap fzf to use in oh-my-zsh";
+    license = licenses.mit;
+    maintainers = [ ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/fz/fzf/package.nix

@@ -0,0 +1,95 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  runtimeShell,
+  installShellFiles,
+  bc,
+  ncurses,
+  testers,
+  fzf,
+}:
+
+buildGoModule rec {
+  pname = "fzf";
+  version = "0.65.2";
+
+  src = fetchFromGitHub {
+    owner = "junegunn";
+    repo = "fzf";
+    rev = "v${version}";
+    hash = "sha256-vIAkbZ3jx5B5+zdjT+4jMxhGPmiYUBIz5UjSP5HhQ9k=";
+  };
+
+  vendorHash = "sha256-1wxi+wfTSSgJQLNbCdoFTz9G4XLgEX7PpzqpuVjEYL8=";
+
+  env.CGO_ENABLED = 0;
+
+  outputs = [
+    "out"
+    "man"
+  ];
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  buildInputs = [ ncurses ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.version=${version} -X main.revision=${src.rev}"
+  ];
+
+  # The vim plugin expects a relative path to the binary; patch it to abspath.
+  postPatch = ''
+    sed -i -e "s|expand('<sfile>:h:h')|'$out'|" plugin/fzf.vim
+
+    if ! grep -q $out plugin/fzf.vim; then
+        echo "Failed to replace vim base_dir path with $out"
+        exit 1
+    fi
+
+    # fzf-tmux depends on bc
+    substituteInPlace bin/fzf-tmux \
+      --replace-fail "bc" "${lib.getExe bc}"
+  '';
+
+  postInstall = ''
+    install bin/fzf-tmux $out/bin
+
+    installManPage man/man1/fzf.1 man/man1/fzf-tmux.1
+
+    install -D plugin/* -t $out/share/vim-plugins/fzf/plugin
+    mkdir -p $out/share/nvim
+    ln -s $out/share/vim-plugins/fzf $out/share/nvim/site
+
+    # Install shell integrations
+    install -D shell/* -t $out/share/fzf/
+
+    cat <<SCRIPT > $out/bin/fzf-share
+    #!${runtimeShell}
+    # Run this script to find the fzf shared folder where all the shell
+    # integration scripts are living.
+    echo $out/share/fzf
+    SCRIPT
+    chmod +x $out/bin/fzf-share
+  '';
+
+  passthru.tests.version = testers.testVersion {
+    package = fzf;
+  };
+
+  meta = {
+    changelog = "https://github.com/junegunn/fzf/blob/${src.rev}/CHANGELOG.md";
+    description = "Command-line fuzzy finder written in Go";
+    homepage = "https://github.com/junegunn/fzf";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      Br1ght0ne
+      ma27
+      zowoq
+    ];
+    mainProgram = "fzf";
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/fz/fzy/package.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "fzy";
+  version = "1.1";
+
+  src = fetchFromGitHub {
+    owner = "jhawthorn";
+    repo = "fzy";
+    rev = version;
+    sha256 = "sha256-ZGAt8rW21WFGuf/nE44ZrL68L/RmTYCBzuXWhidqJB8=";
+  };
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "Better fuzzy finder";
+    homepage = "https://github.com/jhawthorn/fzy";
+    license = licenses.mit;
+    maintainers = with maintainers; [ dywedir ];
+    platforms = platforms.all;
+    mainProgram = "fzy";
+  };
+}