push sheeet

pkgs/by-name/gd/gdevelop/darwin.nix

@@ -0,0 +1,39 @@
+{
+  stdenvNoCC,
+  fetchurl,
+  unzip,
+
+  pname,
+  version,
+  meta,
+  passthru,
+}:
+stdenvNoCC.mkDerivation (finalAttrs: {
+  inherit
+    pname
+    version
+    meta
+    passthru
+    ;
+
+  src = fetchurl {
+    url = "https://github.com/4ian/GDevelop/releases/download/v${version}/GDevelop-5-${version}-universal-mac.zip";
+    hash = "sha256-XSDzvh8zjrmKOP7YXjXG5+3qCzGQEJp1+RmwmRd4oOs=";
+  };
+
+  sourceRoot = ".";
+  nativeBuildInputs = [ unzip ];
+
+  dontPatch = true;
+  dontConfigure = true;
+  dontBuild = true;
+  dontFixup = true;
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/Applications
+    cp -r "GDevelop 5.app" $out/Applications/
+    runHook postInstall
+  '';
+
+})

pkgs/by-name/gd/gdevelop/linux.nix

@@ -0,0 +1,43 @@
+{
+  stdenv,
+  fetchurl,
+  appimageTools,
+
+  version,
+  pname,
+  meta,
+  passthru,
+}:
+let
+  src =
+    if stdenv.hostPlatform.system == "x86_64-linux" then
+      fetchurl {
+        url = "https://github.com/4ian/GDevelop/releases/download/v${version}/GDevelop-5-${version}.AppImage";
+        hash = "sha256-TkJyq6WyHTXoCvGSiV6w/IYoLCxAvbrS1oFdsgbfl5s=";
+      }
+    else
+      throw "${pname}-${version} is not supported on ${stdenv.hostPlatform.system}";
+  appimageContents = appimageTools.extractType2 {
+    inherit pname version src;
+    postExtract = ''
+      substituteInPlace $out/gdevelop.desktop --replace-fail 'Exec=AppRun --no-sandbox %U' 'Exec=gdevelop'
+    '';
+  };
+in
+appimageTools.wrapType2 {
+  inherit
+    pname
+    version
+    src
+    meta
+    passthru
+    ;
+
+  extraInstallCommands = ''
+    mkdir -p $out/share/applications
+    cp ${appimageContents}/gdevelop.desktop $out/share/applications
+    mkdir -p $out/share/icons
+    cp -r ${appimageContents}/usr/share/icons/hicolor $out/share/icons
+  '';
+
+}

pkgs/by-name/gd/gdevelop/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenv,
+  callPackage,
+}:
+let
+  version = "5.5.242";
+  pname = "gdevelop";
+  meta = {
+    description = "Graphical Game Development Studio";
+    homepage = "https://gdevelop.io/";
+    downloadPage = "https://github.com/4ian/GDevelop/releases";
+    license = lib.licenses.mit;
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    maintainers = with lib.maintainers; [
+      tombert
+      matteopacini
+    ];
+    mainProgram = "gdevelop";
+    platforms = [ "x86_64-linux" ] ++ lib.platforms.darwin;
+  };
+  passthru.updateScript = ./update.sh;
+in
+if stdenv.hostPlatform.isDarwin then
+  callPackage ./darwin.nix {
+    inherit
+      pname
+      version
+      meta
+      passthru
+      ;
+  }
+else
+  callPackage ./linux.nix {
+    inherit
+      pname
+      version
+      meta
+      passthru
+      ;
+  }

pkgs/by-name/gd/gdevelop/update.sh

@@ -0,0 +1,33 @@
+#!/usr/bin/env nix-shell
+#!nix-shell -i bash -p curl jq gnused
+
+set -euo pipefail
+
+cd "$(dirname "$0")" || exit 1
+
+# Grab latest version from the GitHub repository
+LATEST_VER="$(curl --fail -s ${GITHUB_TOKEN:+-u ":$GITHUB_TOKEN"} "https://api.github.com/repos/4ian/GDevelop/releases" | jq -r '.[0].tag_name' | sed 's/^v//')"
+CURRENT_VER="$(grep -oP 'version = "\K[^"]+' package.nix)"
+
+if [[ "$LATEST_VER" == "$CURRENT_VER" ]]; then
+    echo "gdevelop is up-to-date"
+    exit 0
+fi
+
+echo "Updating gdevelop from $CURRENT_VER to $LATEST_VER"
+
+# Update the version
+sed -i "s#version = \".*\";#version = \"$LATEST_VER\";#g" package.nix
+
+# Update hashes
+# - Linux
+
+LINUX_HASH="$(nix-hash --to-sri --type sha256 "$(nix-prefetch-url --type sha256 "https://github.com/4ian/GDevelop/releases/download/v${LATEST_VER}/GDevelop-5-${LATEST_VER}.AppImage")")"
+sed -i "s#hash = \".*\"#hash = \"$LINUX_HASH\"#g" linux.nix
+
+# - Darwin
+
+DARWIN_HASH="$(nix-hash --to-sri --type sha256 "$(nix-prefetch-url --type sha256 "https://github.com/4ian/GDevelop/releases/download/v${LATEST_VER}/GDevelop-5-${LATEST_VER}-universal-mac.zip")")"
+sed -i "s#hash = \".*\"#hash = \"$DARWIN_HASH\"#g" darwin.nix
+
+echo "Updated gdevelop to $LATEST_VER"