push sheeet

pkgs/by-name/gi/gitlab-elasticsearch-indexer/code-parser.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  fetchFromGitLab,
+  rustPlatform,
+  pkg-config,
+  openssl,
+  clang,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "gitlab-code-parser";
+  version = "0.16.1";
+
+  src = fetchFromGitLab {
+    owner = "gitlab-org";
+    repo = "rust/gitlab-code-parser";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-GskOPKv1Jp3eqd+a9nEwZPfHfOw6luyglPXzJZAPvBc=";
+  };
+
+  cargoHash = "sha256-g6FV8kX3/9wk692FJLNyGNzv3ffE8RWmMYmvmUIqzVs=";
+
+  nativeBuildInputs = [
+    pkg-config
+    rustPlatform.bindgenHook
+    clang
+  ];
+  buildInputs = [
+    openssl.dev
+  ];
+
+  preInstall = ''
+    mkdir -p $out/include
+    cp crates/parser-c-bindings/target/include/parser-c-bindings.h $out/include
+  '';
+
+  meta = {
+    description = "A single, efficient and extensible static code‑analysis library";
+    changelog = "https://gitlab.com/gitlab-org/rust/gitlab-code-parser/-/blob/v${finalAttrs.version}/CHANGELOG.md?ref_type=tags";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ leona ];
+  };
+})

pkgs/by-name/gi/gitlab-elasticsearch-indexer/package.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  callPackage,
+  buildGoModule,
+  fetchFromGitLab,
+  pkg-config,
+  icu,
+}:
+let
+  codeParserBindings = callPackage ./code-parser.nix { };
+in
+buildGoModule rec {
+  pname = "gitlab-elasticsearch-indexer";
+  version = "5.9.1";
+
+  # nixpkgs-update: no auto update
+  src = fetchFromGitLab {
+    owner = "gitlab-org";
+    repo = "gitlab-elasticsearch-indexer";
+    rev = "v${version}";
+    hash = "sha256-Xt22fyTM4rfqUpNE6Q3yfT9r4vqME3KmqxYCqUKmnLQ=";
+  };
+
+  vendorHash = "sha256-pY8hHFy0AxMwol00BN85jPR0ZnHVgno10Tp+Opz65tQ=";
+
+  buildInputs = [ icu ];
+  nativeBuildInputs = [ pkg-config ];
+
+  env = {
+    CGO_LDFLAGS = "-L${codeParserBindings}/lib";
+    CGO_CFLAGS = "-I${codeParserBindings}/include";
+  };
+
+  passthru = {
+    inherit codeParserBindings;
+  };
+
+  meta = with lib; {
+    description = "Indexes Git repositories into Elasticsearch for GitLab";
+    mainProgram = "gitlab-elasticsearch-indexer";
+    license = licenses.mit;
+    maintainers = with maintainers; [ yayayayaka ];
+    teams = [ teams.cyberus ];
+  };
+}